001:       SUBROUTINE DTPRFS( UPLO, TRANS, DIAG, N, NRHS, AP, B, LDB, X, LDX,
002:      $                   FERR, BERR, WORK, IWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     Modified to call DLACN2 in place of DLACON, 5 Feb 03, SJH.
009: *
010: *     .. Scalar Arguments ..
011:       CHARACTER          DIAG, TRANS, UPLO
012:       INTEGER            INFO, LDB, LDX, N, NRHS
013: *     ..
014: *     .. Array Arguments ..
015:       INTEGER            IWORK( * )
016:       DOUBLE PRECISION   AP( * ), B( LDB, * ), BERR( * ), FERR( * ),
017:      $                   WORK( * ), X( LDX, * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  DTPRFS provides error bounds and backward error estimates for the
024: *  solution to a system of linear equations with a triangular packed
025: *  coefficient matrix.
026: *
027: *  The solution matrix X must be computed by DTPTRS or some other
028: *  means before entering this routine.  DTPRFS does not do iterative
029: *  refinement because doing so cannot improve the backward error.
030: *
031: *  Arguments
032: *  =========
033: *
034: *  UPLO    (input) CHARACTER*1
035: *          = 'U':  A is upper triangular;
036: *          = 'L':  A is lower triangular.
037: *
038: *  TRANS   (input) CHARACTER*1
039: *          Specifies the form of the system of equations:
040: *          = 'N':  A * X = B  (No transpose)
041: *          = 'T':  A**T * X = B  (Transpose)
042: *          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
043: *
044: *  DIAG    (input) CHARACTER*1
045: *          = 'N':  A is non-unit triangular;
046: *          = 'U':  A is unit triangular.
047: *
048: *  N       (input) INTEGER
049: *          The order of the matrix A.  N >= 0.
050: *
051: *  NRHS    (input) INTEGER
052: *          The number of right hand sides, i.e., the number of columns
053: *          of the matrices B and X.  NRHS >= 0.
054: *
055: *  AP      (input) DOUBLE PRECISION array, dimension (N*(N+1)/2)
056: *          The upper or lower triangular matrix A, packed columnwise in
057: *          a linear array.  The j-th column of A is stored in the array
058: *          AP as follows:
059: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
060: *          if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
061: *          If DIAG = 'U', the diagonal elements of A are not referenced
062: *          and are assumed to be 1.
063: *
064: *  B       (input) DOUBLE PRECISION array, dimension (LDB,NRHS)
065: *          The right hand side matrix B.
066: *
067: *  LDB     (input) INTEGER
068: *          The leading dimension of the array B.  LDB >= max(1,N).
069: *
070: *  X       (input) DOUBLE PRECISION array, dimension (LDX,NRHS)
071: *          The solution matrix X.
072: *
073: *  LDX     (input) INTEGER
074: *          The leading dimension of the array X.  LDX >= max(1,N).
075: *
076: *  FERR    (output) DOUBLE PRECISION array, dimension (NRHS)
077: *          The estimated forward error bound for each solution vector
078: *          X(j) (the j-th column of the solution matrix X).
079: *          If XTRUE is the true solution corresponding to X(j), FERR(j)
080: *          is an estimated upper bound for the magnitude of the largest
081: *          element in (X(j) - XTRUE) divided by the magnitude of the
082: *          largest element in X(j).  The estimate is as reliable as
083: *          the estimate for RCOND, and is almost always a slight
084: *          overestimate of the true error.
085: *
086: *  BERR    (output) DOUBLE PRECISION array, dimension (NRHS)
087: *          The componentwise relative backward error of each solution
088: *          vector X(j) (i.e., the smallest relative change in
089: *          any element of A or B that makes X(j) an exact solution).
090: *
091: *  WORK    (workspace) DOUBLE PRECISION array, dimension (3*N)
092: *
093: *  IWORK   (workspace) INTEGER array, dimension (N)
094: *
095: *  INFO    (output) INTEGER
096: *          = 0:  successful exit
097: *          < 0:  if INFO = -i, the i-th argument had an illegal value
098: *
099: *  =====================================================================
100: *
101: *     .. Parameters ..
102:       DOUBLE PRECISION   ZERO
103:       PARAMETER          ( ZERO = 0.0D+0 )
104:       DOUBLE PRECISION   ONE
105:       PARAMETER          ( ONE = 1.0D+0 )
106: *     ..
107: *     .. Local Scalars ..
108:       LOGICAL            NOTRAN, NOUNIT, UPPER
109:       CHARACTER          TRANST
110:       INTEGER            I, J, K, KASE, KC, NZ
111:       DOUBLE PRECISION   EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
112: *     ..
113: *     .. Local Arrays ..
114:       INTEGER            ISAVE( 3 )
115: *     ..
116: *     .. External Subroutines ..
117:       EXTERNAL           DAXPY, DCOPY, DLACN2, DTPMV, DTPSV, XERBLA
118: *     ..
119: *     .. Intrinsic Functions ..
120:       INTRINSIC          ABS, MAX
121: *     ..
122: *     .. External Functions ..
123:       LOGICAL            LSAME
124:       DOUBLE PRECISION   DLAMCH
125:       EXTERNAL           LSAME, DLAMCH
126: *     ..
127: *     .. Executable Statements ..
128: *
129: *     Test the input parameters.
130: *
131:       INFO = 0
132:       UPPER = LSAME( UPLO, 'U' )
133:       NOTRAN = LSAME( TRANS, 'N' )
134:       NOUNIT = LSAME( DIAG, 'N' )
135: *
136:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
137:          INFO = -1
138:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
139:      $         LSAME( TRANS, 'C' ) ) THEN
140:          INFO = -2
141:       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
142:          INFO = -3
143:       ELSE IF( N.LT.0 ) THEN
144:          INFO = -4
145:       ELSE IF( NRHS.LT.0 ) THEN
146:          INFO = -5
147:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
148:          INFO = -8
149:       ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
150:          INFO = -10
151:       END IF
152:       IF( INFO.NE.0 ) THEN
153:          CALL XERBLA( 'DTPRFS', -INFO )
154:          RETURN
155:       END IF
156: *
157: *     Quick return if possible
158: *
159:       IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
160:          DO 10 J = 1, NRHS
161:             FERR( J ) = ZERO
162:             BERR( J ) = ZERO
163:    10    CONTINUE
164:          RETURN
165:       END IF
166: *
167:       IF( NOTRAN ) THEN
168:          TRANST = 'T'
169:       ELSE
170:          TRANST = 'N'
171:       END IF
172: *
173: *     NZ = maximum number of nonzero elements in each row of A, plus 1
174: *
175:       NZ = N + 1
176:       EPS = DLAMCH( 'Epsilon' )
177:       SAFMIN = DLAMCH( 'Safe minimum' )
178:       SAFE1 = NZ*SAFMIN
179:       SAFE2 = SAFE1 / EPS
180: *
181: *     Do for each right hand side
182: *
183:       DO 250 J = 1, NRHS
184: *
185: *        Compute residual R = B - op(A) * X,
186: *        where op(A) = A or A', depending on TRANS.
187: *
188:          CALL DCOPY( N, X( 1, J ), 1, WORK( N+1 ), 1 )
189:          CALL DTPMV( UPLO, TRANS, DIAG, N, AP, WORK( N+1 ), 1 )
190:          CALL DAXPY( N, -ONE, B( 1, J ), 1, WORK( N+1 ), 1 )
191: *
192: *        Compute componentwise relative backward error from formula
193: *
194: *        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
195: *
196: *        where abs(Z) is the componentwise absolute value of the matrix
197: *        or vector Z.  If the i-th component of the denominator is less
198: *        than SAFE2, then SAFE1 is added to the i-th components of the
199: *        numerator and denominator before dividing.
200: *
201:          DO 20 I = 1, N
202:             WORK( I ) = ABS( B( I, J ) )
203:    20    CONTINUE
204: *
205:          IF( NOTRAN ) THEN
206: *
207: *           Compute abs(A)*abs(X) + abs(B).
208: *
209:             IF( UPPER ) THEN
210:                KC = 1
211:                IF( NOUNIT ) THEN
212:                   DO 40 K = 1, N
213:                      XK = ABS( X( K, J ) )
214:                      DO 30 I = 1, K
215:                         WORK( I ) = WORK( I ) + ABS( AP( KC+I-1 ) )*XK
216:    30                CONTINUE
217:                      KC = KC + K
218:    40             CONTINUE
219:                ELSE
220:                   DO 60 K = 1, N
221:                      XK = ABS( X( K, J ) )
222:                      DO 50 I = 1, K - 1
223:                         WORK( I ) = WORK( I ) + ABS( AP( KC+I-1 ) )*XK
224:    50                CONTINUE
225:                      WORK( K ) = WORK( K ) + XK
226:                      KC = KC + K
227:    60             CONTINUE
228:                END IF
229:             ELSE
230:                KC = 1
231:                IF( NOUNIT ) THEN
232:                   DO 80 K = 1, N
233:                      XK = ABS( X( K, J ) )
234:                      DO 70 I = K, N
235:                         WORK( I ) = WORK( I ) + ABS( AP( KC+I-K ) )*XK
236:    70                CONTINUE
237:                      KC = KC + N - K + 1
238:    80             CONTINUE
239:                ELSE
240:                   DO 100 K = 1, N
241:                      XK = ABS( X( K, J ) )
242:                      DO 90 I = K + 1, N
243:                         WORK( I ) = WORK( I ) + ABS( AP( KC+I-K ) )*XK
244:    90                CONTINUE
245:                      WORK( K ) = WORK( K ) + XK
246:                      KC = KC + N - K + 1
247:   100             CONTINUE
248:                END IF
249:             END IF
250:          ELSE
251: *
252: *           Compute abs(A')*abs(X) + abs(B).
253: *
254:             IF( UPPER ) THEN
255:                KC = 1
256:                IF( NOUNIT ) THEN
257:                   DO 120 K = 1, N
258:                      S = ZERO
259:                      DO 110 I = 1, K
260:                         S = S + ABS( AP( KC+I-1 ) )*ABS( X( I, J ) )
261:   110                CONTINUE
262:                      WORK( K ) = WORK( K ) + S
263:                      KC = KC + K
264:   120             CONTINUE
265:                ELSE
266:                   DO 140 K = 1, N
267:                      S = ABS( X( K, J ) )
268:                      DO 130 I = 1, K - 1
269:                         S = S + ABS( AP( KC+I-1 ) )*ABS( X( I, J ) )
270:   130                CONTINUE
271:                      WORK( K ) = WORK( K ) + S
272:                      KC = KC + K
273:   140             CONTINUE
274:                END IF
275:             ELSE
276:                KC = 1
277:                IF( NOUNIT ) THEN
278:                   DO 160 K = 1, N
279:                      S = ZERO
280:                      DO 150 I = K, N
281:                         S = S + ABS( AP( KC+I-K ) )*ABS( X( I, J ) )
282:   150                CONTINUE
283:                      WORK( K ) = WORK( K ) + S
284:                      KC = KC + N - K + 1
285:   160             CONTINUE
286:                ELSE
287:                   DO 180 K = 1, N
288:                      S = ABS( X( K, J ) )
289:                      DO 170 I = K + 1, N
290:                         S = S + ABS( AP( KC+I-K ) )*ABS( X( I, J ) )
291:   170                CONTINUE
292:                      WORK( K ) = WORK( K ) + S
293:                      KC = KC + N - K + 1
294:   180             CONTINUE
295:                END IF
296:             END IF
297:          END IF
298:          S = ZERO
299:          DO 190 I = 1, N
300:             IF( WORK( I ).GT.SAFE2 ) THEN
301:                S = MAX( S, ABS( WORK( N+I ) ) / WORK( I ) )
302:             ELSE
303:                S = MAX( S, ( ABS( WORK( N+I ) )+SAFE1 ) /
304:      $             ( WORK( I )+SAFE1 ) )
305:             END IF
306:   190    CONTINUE
307:          BERR( J ) = S
308: *
309: *        Bound error from formula
310: *
311: *        norm(X - XTRUE) / norm(X) .le. FERR =
312: *        norm( abs(inv(op(A)))*
313: *           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
314: *
315: *        where
316: *          norm(Z) is the magnitude of the largest component of Z
317: *          inv(op(A)) is the inverse of op(A)
318: *          abs(Z) is the componentwise absolute value of the matrix or
319: *             vector Z
320: *          NZ is the maximum number of nonzeros in any row of A, plus 1
321: *          EPS is machine epsilon
322: *
323: *        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
324: *        is incremented by SAFE1 if the i-th component of
325: *        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
326: *
327: *        Use DLACN2 to estimate the infinity-norm of the matrix
328: *           inv(op(A)) * diag(W),
329: *        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
330: *
331:          DO 200 I = 1, N
332:             IF( WORK( I ).GT.SAFE2 ) THEN
333:                WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I )
334:             ELSE
335:                WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I ) + SAFE1
336:             END IF
337:   200    CONTINUE
338: *
339:          KASE = 0
340:   210    CONTINUE
341:          CALL DLACN2( N, WORK( 2*N+1 ), WORK( N+1 ), IWORK, FERR( J ),
342:      $                KASE, ISAVE )
343:          IF( KASE.NE.0 ) THEN
344:             IF( KASE.EQ.1 ) THEN
345: *
346: *              Multiply by diag(W)*inv(op(A)').
347: *
348:                CALL DTPSV( UPLO, TRANST, DIAG, N, AP, WORK( N+1 ), 1 )
349:                DO 220 I = 1, N
350:                   WORK( N+I ) = WORK( I )*WORK( N+I )
351:   220          CONTINUE
352:             ELSE
353: *
354: *              Multiply by inv(op(A))*diag(W).
355: *
356:                DO 230 I = 1, N
357:                   WORK( N+I ) = WORK( I )*WORK( N+I )
358:   230          CONTINUE
359:                CALL DTPSV( UPLO, TRANS, DIAG, N, AP, WORK( N+1 ), 1 )
360:             END IF
361:             GO TO 210
362:          END IF
363: *
364: *        Normalize error.
365: *
366:          LSTRES = ZERO
367:          DO 240 I = 1, N
368:             LSTRES = MAX( LSTRES, ABS( X( I, J ) ) )
369:   240    CONTINUE
370:          IF( LSTRES.NE.ZERO )
371:      $      FERR( J ) = FERR( J ) / LSTRES
372: *
373:   250 CONTINUE
374: *
375:       RETURN
376: *
377: *     End of DTPRFS
378: *
379:       END
380: