001:       SUBROUTINE DSYGST( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          UPLO
009:       INTEGER            INFO, ITYPE, LDA, LDB, N
010: *     ..
011: *     .. Array Arguments ..
012:       DOUBLE PRECISION   A( LDA, * ), B( LDB, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  DSYGST reduces a real symmetric-definite generalized eigenproblem
019: *  to standard form.
020: *
021: *  If ITYPE = 1, the problem is A*x = lambda*B*x,
022: *  and A is overwritten by inv(U**T)*A*inv(U) or inv(L)*A*inv(L**T)
023: *
024: *  If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
025: *  B*A*x = lambda*x, and A is overwritten by U*A*U**T or L**T*A*L.
026: *
027: *  B must have been previously factorized as U**T*U or L*L**T by DPOTRF.
028: *
029: *  Arguments
030: *  =========
031: *
032: *  ITYPE   (input) INTEGER
033: *          = 1: compute inv(U**T)*A*inv(U) or inv(L)*A*inv(L**T);
034: *          = 2 or 3: compute U*A*U**T or L**T*A*L.
035: *
036: *  UPLO    (input) CHARACTER*1
037: *          = 'U':  Upper triangle of A is stored and B is factored as
038: *                  U**T*U;
039: *          = 'L':  Lower triangle of A is stored and B is factored as
040: *                  L*L**T.
041: *
042: *  N       (input) INTEGER
043: *          The order of the matrices A and B.  N >= 0.
044: *
045: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
046: *          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
047: *          N-by-N upper triangular part of A contains the upper
048: *          triangular part of the matrix A, and the strictly lower
049: *          triangular part of A is not referenced.  If UPLO = 'L', the
050: *          leading N-by-N lower triangular part of A contains the lower
051: *          triangular part of the matrix A, and the strictly upper
052: *          triangular part of A is not referenced.
053: *
054: *          On exit, if INFO = 0, the transformed matrix, stored in the
055: *          same format as A.
056: *
057: *  LDA     (input) INTEGER
058: *          The leading dimension of the array A.  LDA >= max(1,N).
059: *
060: *  B       (input) DOUBLE PRECISION array, dimension (LDB,N)
061: *          The triangular factor from the Cholesky factorization of B,
062: *          as returned by DPOTRF.
063: *
064: *  LDB     (input) INTEGER
065: *          The leading dimension of the array B.  LDB >= max(1,N).
066: *
067: *  INFO    (output) INTEGER
068: *          = 0:  successful exit
069: *          < 0:  if INFO = -i, the i-th argument had an illegal value
070: *
071: *  =====================================================================
072: *
073: *     .. Parameters ..
074:       DOUBLE PRECISION   ONE, HALF
075:       PARAMETER          ( ONE = 1.0D0, HALF = 0.5D0 )
076: *     ..
077: *     .. Local Scalars ..
078:       LOGICAL            UPPER
079:       INTEGER            K, KB, NB
080: *     ..
081: *     .. External Subroutines ..
082:       EXTERNAL           DSYGS2, DSYMM, DSYR2K, DTRMM, DTRSM, XERBLA
083: *     ..
084: *     .. Intrinsic Functions ..
085:       INTRINSIC          MAX, MIN
086: *     ..
087: *     .. External Functions ..
088:       LOGICAL            LSAME
089:       INTEGER            ILAENV
090:       EXTERNAL           LSAME, ILAENV
091: *     ..
092: *     .. Executable Statements ..
093: *
094: *     Test the input parameters.
095: *
096:       INFO = 0
097:       UPPER = LSAME( UPLO, 'U' )
098:       IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
099:          INFO = -1
100:       ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
101:          INFO = -2
102:       ELSE IF( N.LT.0 ) THEN
103:          INFO = -3
104:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
105:          INFO = -5
106:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
107:          INFO = -7
108:       END IF
109:       IF( INFO.NE.0 ) THEN
110:          CALL XERBLA( 'DSYGST', -INFO )
111:          RETURN
112:       END IF
113: *
114: *     Quick return if possible
115: *
116:       IF( N.EQ.0 )
117:      $   RETURN
118: *
119: *     Determine the block size for this environment.
120: *
121:       NB = ILAENV( 1, 'DSYGST', UPLO, N, -1, -1, -1 )
122: *
123:       IF( NB.LE.1 .OR. NB.GE.N ) THEN
124: *
125: *        Use unblocked code
126: *
127:          CALL DSYGS2( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
128:       ELSE
129: *
130: *        Use blocked code
131: *
132:          IF( ITYPE.EQ.1 ) THEN
133:             IF( UPPER ) THEN
134: *
135: *              Compute inv(U')*A*inv(U)
136: *
137:                DO 10 K = 1, N, NB
138:                   KB = MIN( N-K+1, NB )
139: *
140: *                 Update the upper triangle of A(k:n,k:n)
141: *
142:                   CALL DSYGS2( ITYPE, UPLO, KB, A( K, K ), LDA,
143:      $                         B( K, K ), LDB, INFO )
144:                   IF( K+KB.LE.N ) THEN
145:                      CALL DTRSM( 'Left', UPLO, 'Transpose', 'Non-unit',
146:      $                           KB, N-K-KB+1, ONE, B( K, K ), LDB,
147:      $                           A( K, K+KB ), LDA )
148:                      CALL DSYMM( 'Left', UPLO, KB, N-K-KB+1, -HALF,
149:      $                           A( K, K ), LDA, B( K, K+KB ), LDB, ONE,
150:      $                           A( K, K+KB ), LDA )
151:                      CALL DSYR2K( UPLO, 'Transpose', N-K-KB+1, KB, -ONE,
152:      $                            A( K, K+KB ), LDA, B( K, K+KB ), LDB,
153:      $                            ONE, A( K+KB, K+KB ), LDA )
154:                      CALL DSYMM( 'Left', UPLO, KB, N-K-KB+1, -HALF,
155:      $                           A( K, K ), LDA, B( K, K+KB ), LDB, ONE,
156:      $                           A( K, K+KB ), LDA )
157:                      CALL DTRSM( 'Right', UPLO, 'No transpose',
158:      $                           'Non-unit', KB, N-K-KB+1, ONE,
159:      $                           B( K+KB, K+KB ), LDB, A( K, K+KB ),
160:      $                           LDA )
161:                   END IF
162:    10          CONTINUE
163:             ELSE
164: *
165: *              Compute inv(L)*A*inv(L')
166: *
167:                DO 20 K = 1, N, NB
168:                   KB = MIN( N-K+1, NB )
169: *
170: *                 Update the lower triangle of A(k:n,k:n)
171: *
172:                   CALL DSYGS2( ITYPE, UPLO, KB, A( K, K ), LDA,
173:      $                         B( K, K ), LDB, INFO )
174:                   IF( K+KB.LE.N ) THEN
175:                      CALL DTRSM( 'Right', UPLO, 'Transpose', 'Non-unit',
176:      $                           N-K-KB+1, KB, ONE, B( K, K ), LDB,
177:      $                           A( K+KB, K ), LDA )
178:                      CALL DSYMM( 'Right', UPLO, N-K-KB+1, KB, -HALF,
179:      $                           A( K, K ), LDA, B( K+KB, K ), LDB, ONE,
180:      $                           A( K+KB, K ), LDA )
181:                      CALL DSYR2K( UPLO, 'No transpose', N-K-KB+1, KB,
182:      $                            -ONE, A( K+KB, K ), LDA, B( K+KB, K ),
183:      $                            LDB, ONE, A( K+KB, K+KB ), LDA )
184:                      CALL DSYMM( 'Right', UPLO, N-K-KB+1, KB, -HALF,
185:      $                           A( K, K ), LDA, B( K+KB, K ), LDB, ONE,
186:      $                           A( K+KB, K ), LDA )
187:                      CALL DTRSM( 'Left', UPLO, 'No transpose',
188:      $                           'Non-unit', N-K-KB+1, KB, ONE,
189:      $                           B( K+KB, K+KB ), LDB, A( K+KB, K ),
190:      $                           LDA )
191:                   END IF
192:    20          CONTINUE
193:             END IF
194:          ELSE
195:             IF( UPPER ) THEN
196: *
197: *              Compute U*A*U'
198: *
199:                DO 30 K = 1, N, NB
200:                   KB = MIN( N-K+1, NB )
201: *
202: *                 Update the upper triangle of A(1:k+kb-1,1:k+kb-1)
203: *
204:                   CALL DTRMM( 'Left', UPLO, 'No transpose', 'Non-unit',
205:      $                        K-1, KB, ONE, B, LDB, A( 1, K ), LDA )
206:                   CALL DSYMM( 'Right', UPLO, K-1, KB, HALF, A( K, K ),
207:      $                        LDA, B( 1, K ), LDB, ONE, A( 1, K ), LDA )
208:                   CALL DSYR2K( UPLO, 'No transpose', K-1, KB, ONE,
209:      $                         A( 1, K ), LDA, B( 1, K ), LDB, ONE, A,
210:      $                         LDA )
211:                   CALL DSYMM( 'Right', UPLO, K-1, KB, HALF, A( K, K ),
212:      $                        LDA, B( 1, K ), LDB, ONE, A( 1, K ), LDA )
213:                   CALL DTRMM( 'Right', UPLO, 'Transpose', 'Non-unit',
214:      $                        K-1, KB, ONE, B( K, K ), LDB, A( 1, K ),
215:      $                        LDA )
216:                   CALL DSYGS2( ITYPE, UPLO, KB, A( K, K ), LDA,
217:      $                         B( K, K ), LDB, INFO )
218:    30          CONTINUE
219:             ELSE
220: *
221: *              Compute L'*A*L
222: *
223:                DO 40 K = 1, N, NB
224:                   KB = MIN( N-K+1, NB )
225: *
226: *                 Update the lower triangle of A(1:k+kb-1,1:k+kb-1)
227: *
228:                   CALL DTRMM( 'Right', UPLO, 'No transpose', 'Non-unit',
229:      $                        KB, K-1, ONE, B, LDB, A( K, 1 ), LDA )
230:                   CALL DSYMM( 'Left', UPLO, KB, K-1, HALF, A( K, K ),
231:      $                        LDA, B( K, 1 ), LDB, ONE, A( K, 1 ), LDA )
232:                   CALL DSYR2K( UPLO, 'Transpose', K-1, KB, ONE,
233:      $                         A( K, 1 ), LDA, B( K, 1 ), LDB, ONE, A,
234:      $                         LDA )
235:                   CALL DSYMM( 'Left', UPLO, KB, K-1, HALF, A( K, K ),
236:      $                        LDA, B( K, 1 ), LDB, ONE, A( K, 1 ), LDA )
237:                   CALL DTRMM( 'Left', UPLO, 'Transpose', 'Non-unit', KB,
238:      $                        K-1, ONE, B( K, K ), LDB, A( K, 1 ), LDA )
239:                   CALL DSYGS2( ITYPE, UPLO, KB, A( K, K ), LDA,
240:      $                         B( K, K ), LDB, INFO )
241:    40          CONTINUE
242:             END IF
243:          END IF
244:       END IF
245:       RETURN
246: *
247: *     End of DSYGST
248: *
249:       END
250: