001:       SUBROUTINE DORMTR( SIDE, UPLO, TRANS, M, N, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS, UPLO
010:       INTEGER            INFO, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  DORMTR overwrites the general real M-by-N matrix C with
020: *
021: *                  SIDE = 'L'     SIDE = 'R'
022: *  TRANS = 'N':      Q * C          C * Q
023: *  TRANS = 'T':      Q**T * C       C * Q**T
024: *
025: *  where Q is a real orthogonal matrix of order nq, with nq = m if
026: *  SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
027: *  nq-1 elementary reflectors, as returned by DSYTRD:
028: *
029: *  if UPLO = 'U', Q = H(nq-1) . . . H(2) H(1);
030: *
031: *  if UPLO = 'L', Q = H(1) H(2) . . . H(nq-1).
032: *
033: *  Arguments
034: *  =========
035: *
036: *  SIDE    (input) CHARACTER*1
037: *          = 'L': apply Q or Q**T from the Left;
038: *          = 'R': apply Q or Q**T from the Right.
039: *
040: *  UPLO    (input) CHARACTER*1
041: *          = 'U': Upper triangle of A contains elementary reflectors
042: *                 from DSYTRD;
043: *          = 'L': Lower triangle of A contains elementary reflectors
044: *                 from DSYTRD.
045: *
046: *  TRANS   (input) CHARACTER*1
047: *          = 'N':  No transpose, apply Q;
048: *          = 'T':  Transpose, apply Q**T.
049: *
050: *  M       (input) INTEGER
051: *          The number of rows of the matrix C. M >= 0.
052: *
053: *  N       (input) INTEGER
054: *          The number of columns of the matrix C. N >= 0.
055: *
056: *  A       (input) DOUBLE PRECISION array, dimension
057: *                               (LDA,M) if SIDE = 'L'
058: *                               (LDA,N) if SIDE = 'R'
059: *          The vectors which define the elementary reflectors, as
060: *          returned by DSYTRD.
061: *
062: *  LDA     (input) INTEGER
063: *          The leading dimension of the array A.
064: *          LDA >= max(1,M) if SIDE = 'L'; LDA >= max(1,N) if SIDE = 'R'.
065: *
066: *  TAU     (input) DOUBLE PRECISION array, dimension
067: *                               (M-1) if SIDE = 'L'
068: *                               (N-1) if SIDE = 'R'
069: *          TAU(i) must contain the scalar factor of the elementary
070: *          reflector H(i), as returned by DSYTRD.
071: *
072: *  C       (input/output) DOUBLE PRECISION array, dimension (LDC,N)
073: *          On entry, the M-by-N matrix C.
074: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
075: *
076: *  LDC     (input) INTEGER
077: *          The leading dimension of the array C. LDC >= max(1,M).
078: *
079: *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
080: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
081: *
082: *  LWORK   (input) INTEGER
083: *          The dimension of the array WORK.
084: *          If SIDE = 'L', LWORK >= max(1,N);
085: *          if SIDE = 'R', LWORK >= max(1,M).
086: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
087: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
088: *          blocksize.
089: *
090: *          If LWORK = -1, then a workspace query is assumed; the routine
091: *          only calculates the optimal size of the WORK array, returns
092: *          this value as the first entry of the WORK array, and no error
093: *          message related to LWORK is issued by XERBLA.
094: *
095: *  INFO    (output) INTEGER
096: *          = 0:  successful exit
097: *          < 0:  if INFO = -i, the i-th argument had an illegal value
098: *
099: *  =====================================================================
100: *
101: *     .. Local Scalars ..
102:       LOGICAL            LEFT, LQUERY, UPPER
103:       INTEGER            I1, I2, IINFO, LWKOPT, MI, NB, NI, NQ, NW
104: *     ..
105: *     .. External Functions ..
106:       LOGICAL            LSAME
107:       INTEGER            ILAENV
108:       EXTERNAL           LSAME, ILAENV
109: *     ..
110: *     .. External Subroutines ..
111:       EXTERNAL           DORMQL, DORMQR, XERBLA
112: *     ..
113: *     .. Intrinsic Functions ..
114:       INTRINSIC          MAX
115: *     ..
116: *     .. Executable Statements ..
117: *
118: *     Test the input arguments
119: *
120:       INFO = 0
121:       LEFT = LSAME( SIDE, 'L' )
122:       UPPER = LSAME( UPLO, 'U' )
123:       LQUERY = ( LWORK.EQ.-1 )
124: *
125: *     NQ is the order of Q and NW is the minimum dimension of WORK
126: *
127:       IF( LEFT ) THEN
128:          NQ = M
129:          NW = N
130:       ELSE
131:          NQ = N
132:          NW = M
133:       END IF
134:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
135:          INFO = -1
136:       ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
137:          INFO = -2
138:       ELSE IF( .NOT.LSAME( TRANS, 'N' ) .AND. .NOT.LSAME( TRANS, 'T' ) )
139:      $          THEN
140:          INFO = -3
141:       ELSE IF( M.LT.0 ) THEN
142:          INFO = -4
143:       ELSE IF( N.LT.0 ) THEN
144:          INFO = -5
145:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
146:          INFO = -7
147:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
148:          INFO = -10
149:       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
150:          INFO = -12
151:       END IF
152: *
153:       IF( INFO.EQ.0 ) THEN
154:          IF( UPPER ) THEN
155:             IF( LEFT ) THEN
156:                NB = ILAENV( 1, 'DORMQL', SIDE // TRANS, M-1, N, M-1,
157:      $              -1 )
158:             ELSE
159:                NB = ILAENV( 1, 'DORMQL', SIDE // TRANS, M, N-1, N-1,
160:      $              -1 )
161:             END IF
162:          ELSE
163:             IF( LEFT ) THEN
164:                NB = ILAENV( 1, 'DORMQR', SIDE // TRANS, M-1, N, M-1,
165:      $              -1 )
166:             ELSE
167:                NB = ILAENV( 1, 'DORMQR', SIDE // TRANS, M, N-1, N-1,
168:      $              -1 )
169:             END IF
170:          END IF
171:          LWKOPT = MAX( 1, NW )*NB
172:          WORK( 1 ) = LWKOPT
173:       END IF
174: *
175:       IF( INFO.NE.0 ) THEN
176:          CALL XERBLA( 'DORMTR', -INFO )
177:          RETURN
178:       ELSE IF( LQUERY ) THEN
179:          RETURN
180:       END IF
181: *
182: *     Quick return if possible
183: *
184:       IF( M.EQ.0 .OR. N.EQ.0 .OR. NQ.EQ.1 ) THEN
185:          WORK( 1 ) = 1
186:          RETURN
187:       END IF
188: *
189:       IF( LEFT ) THEN
190:          MI = M - 1
191:          NI = N
192:       ELSE
193:          MI = M
194:          NI = N - 1
195:       END IF
196: *
197:       IF( UPPER ) THEN
198: *
199: *        Q was determined by a call to DSYTRD with UPLO = 'U'
200: *
201:          CALL DORMQL( SIDE, TRANS, MI, NI, NQ-1, A( 1, 2 ), LDA, TAU, C,
202:      $                LDC, WORK, LWORK, IINFO )
203:       ELSE
204: *
205: *        Q was determined by a call to DSYTRD with UPLO = 'L'
206: *
207:          IF( LEFT ) THEN
208:             I1 = 2
209:             I2 = 1
210:          ELSE
211:             I1 = 1
212:             I2 = 2
213:          END IF
214:          CALL DORMQR( SIDE, TRANS, MI, NI, NQ-1, A( 2, 1 ), LDA, TAU,
215:      $                C( I1, I2 ), LDC, WORK, LWORK, IINFO )
216:       END IF
217:       WORK( 1 ) = LWKOPT
218:       RETURN
219: *
220: *     End of DORMTR
221: *
222:       END
223: