001:       SUBROUTINE DORGHR( N, ILO, IHI, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            IHI, ILO, INFO, LDA, LWORK, N
009: *     ..
010: *     .. Array Arguments ..
011:       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
012: *     ..
013: *
014: *  Purpose
015: *  =======
016: *
017: *  DORGHR generates a real orthogonal matrix Q which is defined as the
018: *  product of IHI-ILO elementary reflectors of order N, as returned by
019: *  DGEHRD:
020: *
021: *  Q = H(ilo) H(ilo+1) . . . H(ihi-1).
022: *
023: *  Arguments
024: *  =========
025: *
026: *  N       (input) INTEGER
027: *          The order of the matrix Q. N >= 0.
028: *
029: *  ILO     (input) INTEGER
030: *  IHI     (input) INTEGER
031: *          ILO and IHI must have the same values as in the previous call
032: *          of DGEHRD. Q is equal to the unit matrix except in the
033: *          submatrix Q(ilo+1:ihi,ilo+1:ihi).
034: *          1 <= ILO <= IHI <= N, if N > 0; ILO=1 and IHI=0, if N=0.
035: *
036: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
037: *          On entry, the vectors which define the elementary reflectors,
038: *          as returned by DGEHRD.
039: *          On exit, the N-by-N orthogonal matrix Q.
040: *
041: *  LDA     (input) INTEGER
042: *          The leading dimension of the array A. LDA >= max(1,N).
043: *
044: *  TAU     (input) DOUBLE PRECISION array, dimension (N-1)
045: *          TAU(i) must contain the scalar factor of the elementary
046: *          reflector H(i), as returned by DGEHRD.
047: *
048: *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
049: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
050: *
051: *  LWORK   (input) INTEGER
052: *          The dimension of the array WORK. LWORK >= IHI-ILO.
053: *          For optimum performance LWORK >= (IHI-ILO)*NB, where NB is
054: *          the optimal blocksize.
055: *
056: *          If LWORK = -1, then a workspace query is assumed; the routine
057: *          only calculates the optimal size of the WORK array, returns
058: *          this value as the first entry of the WORK array, and no error
059: *          message related to LWORK is issued by XERBLA.
060: *
061: *  INFO    (output) INTEGER
062: *          = 0:  successful exit
063: *          < 0:  if INFO = -i, the i-th argument had an illegal value
064: *
065: *  =====================================================================
066: *
067: *     .. Parameters ..
068:       DOUBLE PRECISION   ZERO, ONE
069:       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
070: *     ..
071: *     .. Local Scalars ..
072:       LOGICAL            LQUERY
073:       INTEGER            I, IINFO, J, LWKOPT, NB, NH
074: *     ..
075: *     .. External Subroutines ..
076:       EXTERNAL           DORGQR, XERBLA
077: *     ..
078: *     .. External Functions ..
079:       INTEGER            ILAENV
080:       EXTERNAL           ILAENV
081: *     ..
082: *     .. Intrinsic Functions ..
083:       INTRINSIC          MAX, MIN
084: *     ..
085: *     .. Executable Statements ..
086: *
087: *     Test the input arguments
088: *
089:       INFO = 0
090:       NH = IHI - ILO
091:       LQUERY = ( LWORK.EQ.-1 )
092:       IF( N.LT.0 ) THEN
093:          INFO = -1
094:       ELSE IF( ILO.LT.1 .OR. ILO.GT.MAX( 1, N ) ) THEN
095:          INFO = -2
096:       ELSE IF( IHI.LT.MIN( ILO, N ) .OR. IHI.GT.N ) THEN
097:          INFO = -3
098:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
099:          INFO = -5
100:       ELSE IF( LWORK.LT.MAX( 1, NH ) .AND. .NOT.LQUERY ) THEN
101:          INFO = -8
102:       END IF
103: *
104:       IF( INFO.EQ.0 ) THEN
105:          NB = ILAENV( 1, 'DORGQR', ' ', NH, NH, NH, -1 )
106:          LWKOPT = MAX( 1, NH )*NB
107:          WORK( 1 ) = LWKOPT
108:       END IF
109: *
110:       IF( INFO.NE.0 ) THEN
111:          CALL XERBLA( 'DORGHR', -INFO )
112:          RETURN
113:       ELSE IF( LQUERY ) THEN
114:          RETURN
115:       END IF
116: *
117: *     Quick return if possible
118: *
119:       IF( N.EQ.0 ) THEN
120:          WORK( 1 ) = 1
121:          RETURN
122:       END IF
123: *
124: *     Shift the vectors which define the elementary reflectors one
125: *     column to the right, and set the first ilo and the last n-ihi
126: *     rows and columns to those of the unit matrix
127: *
128:       DO 40 J = IHI, ILO + 1, -1
129:          DO 10 I = 1, J - 1
130:             A( I, J ) = ZERO
131:    10    CONTINUE
132:          DO 20 I = J + 1, IHI
133:             A( I, J ) = A( I, J-1 )
134:    20    CONTINUE
135:          DO 30 I = IHI + 1, N
136:             A( I, J ) = ZERO
137:    30    CONTINUE
138:    40 CONTINUE
139:       DO 60 J = 1, ILO
140:          DO 50 I = 1, N
141:             A( I, J ) = ZERO
142:    50    CONTINUE
143:          A( J, J ) = ONE
144:    60 CONTINUE
145:       DO 80 J = IHI + 1, N
146:          DO 70 I = 1, N
147:             A( I, J ) = ZERO
148:    70    CONTINUE
149:          A( J, J ) = ONE
150:    80 CONTINUE
151: *
152:       IF( NH.GT.0 ) THEN
153: *
154: *        Generate Q(ilo+1:ihi,ilo+1:ihi)
155: *
156:          CALL DORGQR( NH, NH, NH, A( ILO+1, ILO+1 ), LDA, TAU( ILO ),
157:      $                WORK, LWORK, IINFO )
158:       END IF
159:       WORK( 1 ) = LWKOPT
160:       RETURN
161: *
162: *     End of DORGHR
163: *
164:       END
165: