001:       DOUBLE PRECISION FUNCTION DLANTP( NORM, UPLO, DIAG, N, AP, WORK )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          DIAG, NORM, UPLO
009:       INTEGER            N
010: *     ..
011: *     .. Array Arguments ..
012:       DOUBLE PRECISION   AP( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  DLANTP  returns the value of the one norm,  or the Frobenius norm, or
019: *  the  infinity norm,  or the  element of  largest absolute value  of a
020: *  triangular matrix A, supplied in packed form.
021: *
022: *  Description
023: *  ===========
024: *
025: *  DLANTP returns the value
026: *
027: *     DLANTP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
028: *              (
029: *              ( norm1(A),         NORM = '1', 'O' or 'o'
030: *              (
031: *              ( normI(A),         NORM = 'I' or 'i'
032: *              (
033: *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
034: *
035: *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
036: *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
037: *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
038: *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
039: *
040: *  Arguments
041: *  =========
042: *
043: *  NORM    (input) CHARACTER*1
044: *          Specifies the value to be returned in DLANTP as described
045: *          above.
046: *
047: *  UPLO    (input) CHARACTER*1
048: *          Specifies whether the matrix A is upper or lower triangular.
049: *          = 'U':  Upper triangular
050: *          = 'L':  Lower triangular
051: *
052: *  DIAG    (input) CHARACTER*1
053: *          Specifies whether or not the matrix A is unit triangular.
054: *          = 'N':  Non-unit triangular
055: *          = 'U':  Unit triangular
056: *
057: *  N       (input) INTEGER
058: *          The order of the matrix A.  N >= 0.  When N = 0, DLANTP is
059: *          set to zero.
060: *
061: *  AP      (input) DOUBLE PRECISION array, dimension (N*(N+1)/2)
062: *          The upper or lower triangular matrix A, packed columnwise in
063: *          a linear array.  The j-th column of A is stored in the array
064: *          AP as follows:
065: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
066: *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
067: *          Note that when DIAG = 'U', the elements of the array AP
068: *          corresponding to the diagonal elements of the matrix A are
069: *          not referenced, but are assumed to be one.
070: *
071: *  WORK    (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
072: *          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
073: *          referenced.
074: *
075: * =====================================================================
076: *
077: *     .. Parameters ..
078:       DOUBLE PRECISION   ONE, ZERO
079:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
080: *     ..
081: *     .. Local Scalars ..
082:       LOGICAL            UDIAG
083:       INTEGER            I, J, K
084:       DOUBLE PRECISION   SCALE, SUM, VALUE
085: *     ..
086: *     .. External Subroutines ..
087:       EXTERNAL           DLASSQ
088: *     ..
089: *     .. External Functions ..
090:       LOGICAL            LSAME
091:       EXTERNAL           LSAME
092: *     ..
093: *     .. Intrinsic Functions ..
094:       INTRINSIC          ABS, MAX, SQRT
095: *     ..
096: *     .. Executable Statements ..
097: *
098:       IF( N.EQ.0 ) THEN
099:          VALUE = ZERO
100:       ELSE IF( LSAME( NORM, 'M' ) ) THEN
101: *
102: *        Find max(abs(A(i,j))).
103: *
104:          K = 1
105:          IF( LSAME( DIAG, 'U' ) ) THEN
106:             VALUE = ONE
107:             IF( LSAME( UPLO, 'U' ) ) THEN
108:                DO 20 J = 1, N
109:                   DO 10 I = K, K + J - 2
110:                      VALUE = MAX( VALUE, ABS( AP( I ) ) )
111:    10             CONTINUE
112:                   K = K + J
113:    20          CONTINUE
114:             ELSE
115:                DO 40 J = 1, N
116:                   DO 30 I = K + 1, K + N - J
117:                      VALUE = MAX( VALUE, ABS( AP( I ) ) )
118:    30             CONTINUE
119:                   K = K + N - J + 1
120:    40          CONTINUE
121:             END IF
122:          ELSE
123:             VALUE = ZERO
124:             IF( LSAME( UPLO, 'U' ) ) THEN
125:                DO 60 J = 1, N
126:                   DO 50 I = K, K + J - 1
127:                      VALUE = MAX( VALUE, ABS( AP( I ) ) )
128:    50             CONTINUE
129:                   K = K + J
130:    60          CONTINUE
131:             ELSE
132:                DO 80 J = 1, N
133:                   DO 70 I = K, K + N - J
134:                      VALUE = MAX( VALUE, ABS( AP( I ) ) )
135:    70             CONTINUE
136:                   K = K + N - J + 1
137:    80          CONTINUE
138:             END IF
139:          END IF
140:       ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
141: *
142: *        Find norm1(A).
143: *
144:          VALUE = ZERO
145:          K = 1
146:          UDIAG = LSAME( DIAG, 'U' )
147:          IF( LSAME( UPLO, 'U' ) ) THEN
148:             DO 110 J = 1, N
149:                IF( UDIAG ) THEN
150:                   SUM = ONE
151:                   DO 90 I = K, K + J - 2
152:                      SUM = SUM + ABS( AP( I ) )
153:    90             CONTINUE
154:                ELSE
155:                   SUM = ZERO
156:                   DO 100 I = K, K + J - 1
157:                      SUM = SUM + ABS( AP( I ) )
158:   100             CONTINUE
159:                END IF
160:                K = K + J
161:                VALUE = MAX( VALUE, SUM )
162:   110       CONTINUE
163:          ELSE
164:             DO 140 J = 1, N
165:                IF( UDIAG ) THEN
166:                   SUM = ONE
167:                   DO 120 I = K + 1, K + N - J
168:                      SUM = SUM + ABS( AP( I ) )
169:   120             CONTINUE
170:                ELSE
171:                   SUM = ZERO
172:                   DO 130 I = K, K + N - J
173:                      SUM = SUM + ABS( AP( I ) )
174:   130             CONTINUE
175:                END IF
176:                K = K + N - J + 1
177:                VALUE = MAX( VALUE, SUM )
178:   140       CONTINUE
179:          END IF
180:       ELSE IF( LSAME( NORM, 'I' ) ) THEN
181: *
182: *        Find normI(A).
183: *
184:          K = 1
185:          IF( LSAME( UPLO, 'U' ) ) THEN
186:             IF( LSAME( DIAG, 'U' ) ) THEN
187:                DO 150 I = 1, N
188:                   WORK( I ) = ONE
189:   150          CONTINUE
190:                DO 170 J = 1, N
191:                   DO 160 I = 1, J - 1
192:                      WORK( I ) = WORK( I ) + ABS( AP( K ) )
193:                      K = K + 1
194:   160             CONTINUE
195:                   K = K + 1
196:   170          CONTINUE
197:             ELSE
198:                DO 180 I = 1, N
199:                   WORK( I ) = ZERO
200:   180          CONTINUE
201:                DO 200 J = 1, N
202:                   DO 190 I = 1, J
203:                      WORK( I ) = WORK( I ) + ABS( AP( K ) )
204:                      K = K + 1
205:   190             CONTINUE
206:   200          CONTINUE
207:             END IF
208:          ELSE
209:             IF( LSAME( DIAG, 'U' ) ) THEN
210:                DO 210 I = 1, N
211:                   WORK( I ) = ONE
212:   210          CONTINUE
213:                DO 230 J = 1, N
214:                   K = K + 1
215:                   DO 220 I = J + 1, N
216:                      WORK( I ) = WORK( I ) + ABS( AP( K ) )
217:                      K = K + 1
218:   220             CONTINUE
219:   230          CONTINUE
220:             ELSE
221:                DO 240 I = 1, N
222:                   WORK( I ) = ZERO
223:   240          CONTINUE
224:                DO 260 J = 1, N
225:                   DO 250 I = J, N
226:                      WORK( I ) = WORK( I ) + ABS( AP( K ) )
227:                      K = K + 1
228:   250             CONTINUE
229:   260          CONTINUE
230:             END IF
231:          END IF
232:          VALUE = ZERO
233:          DO 270 I = 1, N
234:             VALUE = MAX( VALUE, WORK( I ) )
235:   270    CONTINUE
236:       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
237: *
238: *        Find normF(A).
239: *
240:          IF( LSAME( UPLO, 'U' ) ) THEN
241:             IF( LSAME( DIAG, 'U' ) ) THEN
242:                SCALE = ONE
243:                SUM = N
244:                K = 2
245:                DO 280 J = 2, N
246:                   CALL DLASSQ( J-1, AP( K ), 1, SCALE, SUM )
247:                   K = K + J
248:   280          CONTINUE
249:             ELSE
250:                SCALE = ZERO
251:                SUM = ONE
252:                K = 1
253:                DO 290 J = 1, N
254:                   CALL DLASSQ( J, AP( K ), 1, SCALE, SUM )
255:                   K = K + J
256:   290          CONTINUE
257:             END IF
258:          ELSE
259:             IF( LSAME( DIAG, 'U' ) ) THEN
260:                SCALE = ONE
261:                SUM = N
262:                K = 2
263:                DO 300 J = 1, N - 1
264:                   CALL DLASSQ( N-J, AP( K ), 1, SCALE, SUM )
265:                   K = K + N - J + 1
266:   300          CONTINUE
267:             ELSE
268:                SCALE = ZERO
269:                SUM = ONE
270:                K = 1
271:                DO 310 J = 1, N
272:                   CALL DLASSQ( N-J+1, AP( K ), 1, SCALE, SUM )
273:                   K = K + N - J + 1
274:   310          CONTINUE
275:             END IF
276:          END IF
277:          VALUE = SCALE*SQRT( SUM )
278:       END IF
279: *
280:       DLANTP = VALUE
281:       RETURN
282: *
283: *     End of DLANTP
284: *
285:       END
286: