001:       DOUBLE PRECISION FUNCTION DLA_GBRCOND( TRANS, N, KL, KU, AB, LDAB,
002:      $                            AFB, LDAFB, IPIV, CMODE, C, INFO, 
003:      $     WORK, IWORK )
004: *
005: *     -- LAPACK routine (version 3.2)                                 --
006: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
007: *     -- Jason Riedy of Univ. of California Berkeley.                 --
008: *     -- November 2008                                                --
009: *
010: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
011: *     -- Univ. of California Berkeley and NAG Ltd.                    --
012: *
013:       IMPLICIT NONE
014: *     ..
015: *     .. Scalar Arguments ..
016:       CHARACTER          TRANS
017:       INTEGER            N, LDAB, LDAFB, INFO, KL, KU, CMODE
018: *     ..
019: *     .. Array Arguments ..
020:       INTEGER            IWORK( * ), IPIV( * )
021:       DOUBLE PRECISION   AB( LDAB, * ), AFB( LDAFB, * ), WORK( * ),
022:      $                   C( * )
023: *
024: *     DLA_GERCOND Estimates the Skeel condition number of  op(A) * op2(C)
025: *     where op2 is determined by CMODE as follows
026: *     CMODE =  1    op2(C) = C
027: *     CMODE =  0    op2(C) = I
028: *     CMODE = -1    op2(C) = inv(C)
029: *     The Skeel condition number  cond(A) = norminf( |inv(A)||A| )
030: *     is computed by computing scaling factors R such that
031: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
032: *     infinity-norm condition number.
033: *     WORK is a double precision workspace of size 5*N, and
034: *     IWORK is an integer workspace of size N.
035: *     ..
036: *     .. Local Scalars ..
037:       LOGICAL            NOTRANS
038:       INTEGER            KASE, I, J, KD
039:       DOUBLE PRECISION   AINVNM, TMP
040: *     ..
041: *     .. Local Arrays ..
042:       INTEGER            ISAVE( 3 )
043: *     ..
044: *     .. External Functions ..
045:       LOGICAL            LSAME
046:       EXTERNAL           LSAME
047: *     ..
048: *     .. External Subroutines ..
049:       EXTERNAL           DLACN2, DGBTRS, XERBLA
050: *     ..
051: *     .. Intrinsic Functions ..
052:       INTRINSIC          ABS, MAX
053: *     ..
054: *     .. Executable Statements ..
055: *
056:       DLA_GBRCOND = 0.0D+0
057: *
058:       INFO = 0
059:       NOTRANS = LSAME( TRANS, 'N' )
060:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T')
061:      $     .AND. .NOT. LSAME(TRANS, 'C') ) THEN
062:          INFO = -1
063:       ELSE IF( N.LT.0 ) THEN
064:          INFO = -2
065:       ELSE IF( KL.LT.0 ) THEN
066:          INFO = -4
067:       ELSE IF( KU.LT.0 ) THEN
068:          INFO = -5
069:       ELSE IF( LDAB.LT.KL+KU+1 ) THEN
070:          INFO = -8
071:       ELSE IF( LDAFB.LT.2*KL+KU+1 ) THEN
072:          INFO = -10
073:       END IF
074:       IF( INFO.NE.0 ) THEN
075:          CALL XERBLA( 'DLA_GBRCOND', -INFO )
076:          RETURN
077:       END IF
078:       IF( N.EQ.0 ) THEN
079:          DLA_GBRCOND = 1.0D+0
080:          RETURN
081:       END IF
082: *
083: *     Compute the equilibration matrix R such that
084: *     inv(R)*A*C has unit 1-norm.
085: *
086:       KD = KU + 1
087:       IF ( NOTRANS ) THEN
088:          DO I = 1, N
089:             TMP = 0.0D+0
090:                IF ( CMODE .EQ. 1 ) THEN
091:                   DO J = 1, N
092:                      IF ( I.GE.MAX( 1, J-KU )
093:      $                    .AND. I.LE.MIN( N, J+KL ) ) THEN
094:                         TMP = TMP + ABS( AB( KD+I-J, J ) * C( J ) )
095:                      END IF
096:                   END DO
097:                ELSE IF ( CMODE .EQ. 0 ) THEN
098:                   DO J = 1, N
099:                      IF ( I.GE.MAX( 1, J-KU )
100:      $                    .AND. I.LE.MIN( N, J+KL ) ) THEN
101:                         TMP = TMP + ABS( AB( KD+I-J, J ) )
102:                      END IF
103:                   END DO
104:                ELSE
105:                   DO J = 1, N
106:                      IF ( I.GE.MAX( 1, J-KU )
107:      $                    .AND. I.LE.MIN( N, J+KL ) ) THEN
108:                         TMP = TMP + ABS( AB( KD+I-J, J ) / C( J ) )
109:                      END IF
110:                   END DO
111:                END IF
112:             WORK( 2*N+I ) = TMP
113:          END DO
114:       ELSE
115:          DO I = 1, N
116:             TMP = 0.0D+0
117:             IF ( CMODE .EQ. 1 ) THEN
118:                DO J = 1, N
119:                   IF ( I.GE.MAX( 1, J-KU )
120:      $                 .AND. I.LE.MIN( N, J+KL ) ) THEN
121:                      TMP = TMP + ABS( AB( J, KD+I-J ) * C( J ) )
122:                   END IF
123:                END DO
124:             ELSE IF ( CMODE .EQ. 0 ) THEN
125:                DO J = 1, N
126:                   IF ( I.GE.MAX( 1, J-KU )
127:      $                 .AND. I.LE.MIN( N, J+KL ) ) THEN
128:                      TMP = TMP + ABS(AB(J,KD+I-J))
129:                   END IF
130:                END DO
131:             ELSE
132:                DO J = 1, N
133:                   IF ( I.GE.MAX( 1, J-KU )
134:      $                 .AND. I.LE.MIN( N, J+KL ) ) THEN
135:                      TMP = TMP + ABS( AB( J, KD+I-J ) / C( J ) )
136:                   END IF
137:                END DO
138:             END IF
139:             WORK( 2*N+I ) = TMP
140:          END DO
141:       END IF
142: *
143: *     Estimate the norm of inv(op(A)).
144: *
145:       AINVNM = 0.0D+0
146: 
147:       KASE = 0
148:    10 CONTINUE
149:       CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
150:       IF( KASE.NE.0 ) THEN
151:          IF( KASE.EQ.2 ) THEN
152: *
153: *           Multiply by R.
154: *
155:             DO I = 1, N
156:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
157:             END DO
158: 
159:             IF ( NOTRANS ) THEN
160:                CALL DGBTRS( 'No transpose', N, KL, KU, 1, AFB, LDAFB,
161:      $              IPIV, WORK, N, INFO )
162:             ELSE
163:                CALL DGBTRS( 'Transpose', N, KL, KU, 1, AFB, LDAFB, IPIV,
164:      $              WORK, N, INFO )
165:             END IF
166: *
167: *           Multiply by inv(C).
168: *
169:             IF ( CMODE .EQ. 1 ) THEN
170:                DO I = 1, N
171:                   WORK( I ) = WORK( I ) / C( I )
172:                END DO
173:             ELSE IF ( CMODE .EQ. -1 ) THEN
174:                DO I = 1, N
175:                   WORK( I ) = WORK( I ) * C( I )
176:                END DO
177:             END IF
178:          ELSE
179: *
180: *           Multiply by inv(C').
181: *
182:             IF ( CMODE .EQ. 1 ) THEN
183:                DO I = 1, N
184:                   WORK( I ) = WORK( I ) / C( I )
185:                END DO
186:             ELSE IF ( CMODE .EQ. -1 ) THEN
187:                DO I = 1, N
188:                   WORK( I ) = WORK( I ) * C( I )
189:                END DO
190:             END IF
191: 
192:             IF ( NOTRANS ) THEN
193:                CALL DGBTRS( 'Transpose', N, KL, KU, 1, AFB, LDAFB, IPIV,
194:      $              WORK, N, INFO )
195:             ELSE
196:                CALL DGBTRS( 'No transpose', N, KL, KU, 1, AFB, LDAFB,
197:      $              IPIV, WORK, N, INFO )
198:             END IF
199: *
200: *           Multiply by R.
201: *
202:             DO I = 1, N
203:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
204:             END DO
205:          END IF
206:          GO TO 10
207:       END IF
208: *
209: *     Compute the estimate of the reciprocal condition number.
210: *
211:       IF( AINVNM .NE. 0.0D+0 )
212:      $   DLA_GBRCOND = ( 1.0D+0 / AINVNM )
213: *
214:       RETURN
215: *
216:       END
217: