001:       SUBROUTINE DLA_GBAMV( TRANS, M, N, KL, KU, ALPHA, AB, LDAB, X,
002:      $                      INCX, BETA, Y, INCY )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       DOUBLE PRECISION   ALPHA, BETA
016:       INTEGER            INCX, INCY, LDAB, M, N, KL, KU, TRANS
017: *     ..
018: *     .. Array Arguments ..
019:       DOUBLE PRECISION   AB( LDAB, * ), X( * ), Y( * )
020: *     ..
021: *
022: *  Purpose
023: *  =======
024: *
025: *  DLA_GEAMV  performs one of the matrix-vector operations
026: *
027: *          y := alpha*abs(A)*abs(x) + beta*abs(y),
028: *     or   y := alpha*abs(A)'*abs(x) + beta*abs(y),
029: *
030: *  where alpha and beta are scalars, x and y are vectors and A is an
031: *  m by n matrix.
032: *
033: *  This function is primarily used in calculating error bounds.
034: *  To protect against underflow during evaluation, components in
035: *  the resulting vector are perturbed away from zero by (N+1)
036: *  times the underflow threshold.  To prevent unnecessarily large
037: *  errors for block-structure embedded in general matrices,
038: *  "symbolically" zero components are not perturbed.  A zero
039: *  entry is considered "symbolic" if all multiplications involved
040: *  in computing that entry have at least one zero multiplicand.
041: *
042: *  Parameters
043: *  ==========
044: *
045: *  TRANS  - INTEGER
046: *           On entry, TRANS specifies the operation to be performed as
047: *           follows:
048: *
049: *             BLAS_NO_TRANS      y := alpha*abs(A)*abs(x) + beta*abs(y)
050: *             BLAS_TRANS         y := alpha*abs(A')*abs(x) + beta*abs(y)
051: *             BLAS_CONJ_TRANS    y := alpha*abs(A')*abs(x) + beta*abs(y)
052: *
053: *           Unchanged on exit.
054: *
055: *  M      - INTEGER
056: *           On entry, M specifies the number of rows of the matrix A.
057: *           M must be at least zero.
058: *           Unchanged on exit.
059: *
060: *  N      - INTEGER
061: *           On entry, N specifies the number of columns of the matrix A.
062: *           N must be at least zero.
063: *           Unchanged on exit.
064: *
065: *  KL     - INTEGER
066: *           The number of subdiagonals within the band of A.  KL >= 0.
067: *
068: *  KU     - INTEGER
069: *           The number of superdiagonals within the band of A.  KU >= 0.
070: *
071: *  ALPHA  - DOUBLE PRECISION
072: *           On entry, ALPHA specifies the scalar alpha.
073: *           Unchanged on exit.
074: *
075: *  A      - DOUBLE PRECISION   array of DIMENSION ( LDA, n )
076: *           Before entry, the leading m by n part of the array A must
077: *           contain the matrix of coefficients.
078: *           Unchanged on exit.
079: *
080: *  LDA    - INTEGER
081: *           On entry, LDA specifies the first dimension of A as declared
082: *           in the calling (sub) program. LDA must be at least
083: *           max( 1, m ).
084: *           Unchanged on exit.
085: *
086: *  X      - DOUBLE PRECISION   array of DIMENSION at least
087: *           ( 1 + ( n - 1 )*abs( INCX ) ) when TRANS = 'N' or 'n'
088: *           and at least
089: *           ( 1 + ( m - 1 )*abs( INCX ) ) otherwise.
090: *           Before entry, the incremented array X must contain the
091: *           vector x.
092: *           Unchanged on exit.
093: *
094: *  INCX   - INTEGER
095: *           On entry, INCX specifies the increment for the elements of
096: *           X. INCX must not be zero.
097: *           Unchanged on exit.
098: *
099: *  BETA   - DOUBLE PRECISION
100: *           On entry, BETA specifies the scalar beta. When BETA is
101: *           supplied as zero then Y need not be set on input.
102: *           Unchanged on exit.
103: *
104: *  Y      - DOUBLE PRECISION   array of DIMENSION at least
105: *           ( 1 + ( m - 1 )*abs( INCY ) ) when TRANS = 'N' or 'n'
106: *           and at least
107: *           ( 1 + ( n - 1 )*abs( INCY ) ) otherwise.
108: *           Before entry with BETA non-zero, the incremented array Y
109: *           must contain the vector y. On exit, Y is overwritten by the
110: *           updated vector y.
111: *
112: *  INCY   - INTEGER
113: *           On entry, INCY specifies the increment for the elements of
114: *           Y. INCY must not be zero.
115: *           Unchanged on exit.
116: *
117: *
118: *  Level 2 Blas routine.
119: *     ..
120: *     .. Parameters ..
121:       DOUBLE PRECISION   ONE, ZERO
122:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
123: *     ..
124: *     .. Local Scalars ..
125:       LOGICAL            SYMB_ZERO
126:       DOUBLE PRECISION   TEMP, SAFE1
127:       INTEGER            I, INFO, IY, J, JX, KX, KY, LENX, LENY, KD
128: *     ..
129: *     .. External Subroutines ..
130:       EXTERNAL           XERBLA, DLAMCH
131:       DOUBLE PRECISION   DLAMCH
132: *     ..
133: *     .. External Functions ..
134:       EXTERNAL           ILATRANS
135:       INTEGER            ILATRANS
136: *     ..
137: *     .. Intrinsic Functions ..
138:       INTRINSIC          MAX, ABS, SIGN
139: *     ..
140: *     .. Executable Statements ..
141: *
142: *     Test the input parameters.
143: *
144:       INFO = 0
145:       IF     ( .NOT.( ( TRANS.EQ.ILATRANS( 'N' ) )
146:      $           .OR. ( TRANS.EQ.ILATRANS( 'T' ) )
147:      $           .OR. ( TRANS.EQ.ILATRANS( 'C' ) ) ) ) THEN
148:          INFO = 1
149:       ELSE IF( M.LT.0 )THEN
150:          INFO = 2
151:       ELSE IF( N.LT.0 )THEN
152:          INFO = 3
153:       ELSE IF( KL.LT.0 ) THEN
154:          INFO = 4
155:       ELSE IF( KU.LT.0 ) THEN
156:          INFO = 5
157:       ELSE IF( LDAB.LT.KL+KU+1 )THEN
158:          INFO = 6
159:       ELSE IF( INCX.EQ.0 )THEN
160:          INFO = 8
161:       ELSE IF( INCY.EQ.0 )THEN
162:          INFO = 11
163:       END IF
164:       IF( INFO.NE.0 )THEN
165:          CALL XERBLA( 'DLA_GBAMV ', INFO )
166:          RETURN
167:       END IF
168: *
169: *     Quick return if possible.
170: *
171:       IF( ( M.EQ.0 ).OR.( N.EQ.0 ).OR.
172:      $    ( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
173:      $   RETURN
174: *
175: *     Set  LENX  and  LENY, the lengths of the vectors x and y, and set
176: *     up the start points in  X  and  Y.
177: *
178:       IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
179:          LENX = N
180:          LENY = M
181:       ELSE
182:          LENX = M
183:          LENY = N
184:       END IF
185:       IF( INCX.GT.0 )THEN
186:          KX = 1
187:       ELSE
188:          KX = 1 - ( LENX - 1 )*INCX
189:       END IF
190:       IF( INCY.GT.0 )THEN
191:          KY = 1
192:       ELSE
193:          KY = 1 - ( LENY - 1 )*INCY
194:       END IF
195: *
196: *     Set SAFE1 essentially to be the underflow threshold times the
197: *     number of additions in each row.
198: *
199:       SAFE1 = DLAMCH( 'Safe minimum' )
200:       SAFE1 = (N+1)*SAFE1
201: *
202: *     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
203: *
204: *     The O(M*N) SYMB_ZERO tests could be replaced by O(N) queries to
205: *     the inexact flag.  Still doesn't help change the iteration order
206: *     to per-column.
207: *
208:       KD = KU + 1
209:       IY = KY
210:       IF ( INCX.EQ.1 ) THEN
211:          DO I = 1, LENY
212:             IF ( BETA .EQ. ZERO ) THEN
213:                SYMB_ZERO = .TRUE.
214:                Y( IY ) = 0.0D+0
215:             ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
216:                SYMB_ZERO = .TRUE.
217:             ELSE
218:                SYMB_ZERO = .FALSE.
219:                Y( IY ) = BETA * ABS( Y( IY ) )
220:             END IF
221:             IF ( ALPHA .NE. ZERO ) THEN
222:                DO J = MAX( I-KU, 1 ), MIN( I+KL, LENX )
223:                   IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
224:                      TEMP = ABS( AB( KD+I-J, J ) )
225:                   ELSE
226:                      TEMP = ABS( AB( J, KD+I-J ) )
227:                   END IF
228: 
229:                   SYMB_ZERO = SYMB_ZERO .AND.
230:      $                 ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
231: 
232:                   Y( IY ) = Y( IY ) + ALPHA*ABS( X( J ) )*TEMP
233:                END DO
234:             END IF
235: 
236:             IF ( .NOT.SYMB_ZERO )
237:      $           Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
238:             IY = IY + INCY
239:          END DO
240:       ELSE
241:          DO I = 1, LENY
242:             IF ( BETA .EQ. ZERO ) THEN
243:                SYMB_ZERO = .TRUE.
244:                Y( IY ) = 0.0D+0
245:             ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
246:                SYMB_ZERO = .TRUE.
247:             ELSE
248:                SYMB_ZERO = .FALSE.
249:                Y( IY ) = BETA * ABS( Y( IY ) )
250:             END IF
251:             IF ( ALPHA .NE. ZERO ) THEN
252:                JX = KX
253:                DO J = MAX( I-KU, 1 ), MIN( I+KL, LENX )
254: 
255:                   IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
256:                      TEMP = ABS( AB( KD+I-J, J ) )
257:                   ELSE
258:                      TEMP = ABS( AB( J, KD+I-J ) )
259:                   END IF
260: 
261:                   SYMB_ZERO = SYMB_ZERO .AND.
262:      $                 ( X( JX ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
263: 
264:                   Y( IY ) = Y( IY ) + ALPHA*ABS( X( JX ) )*TEMP
265:                   JX = JX + INCX
266:                END DO
267:             END IF
268: 
269:             IF ( .NOT.SYMB_ZERO )
270:      $           Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
271: 
272:             IY = IY + INCY
273:          END DO
274:       END IF
275: *
276:       RETURN
277: *
278: *     End of DLA_GBAMV
279: *
280:       END
281: