001:       SUBROUTINE CUNMHR( SIDE, TRANS, M, N, ILO, IHI, A, LDA, TAU, C,
002:      $                   LDC, WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            IHI, ILO, INFO, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ),
014:      $                   WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  CUNMHR overwrites the general complex M-by-N matrix C with
021: *
022: *                  SIDE = 'L'     SIDE = 'R'
023: *  TRANS = 'N':      Q * C          C * Q
024: *  TRANS = 'C':      Q**H * C       C * Q**H
025: *
026: *  where Q is a complex unitary matrix of order nq, with nq = m if
027: *  SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
028: *  IHI-ILO elementary reflectors, as returned by CGEHRD:
029: *
030: *  Q = H(ilo) H(ilo+1) . . . H(ihi-1).
031: *
032: *  Arguments
033: *  =========
034: *
035: *  SIDE    (input) CHARACTER*1
036: *          = 'L': apply Q or Q**H from the Left;
037: *          = 'R': apply Q or Q**H from the Right.
038: *
039: *  TRANS   (input) CHARACTER*1
040: *          = 'N': apply Q  (No transpose)
041: *          = 'C': apply Q**H (Conjugate transpose)
042: *
043: *  M       (input) INTEGER
044: *          The number of rows of the matrix C. M >= 0.
045: *
046: *  N       (input) INTEGER
047: *          The number of columns of the matrix C. N >= 0.
048: *
049: *  ILO     (input) INTEGER
050: *  IHI     (input) INTEGER
051: *          ILO and IHI must have the same values as in the previous call
052: *          of CGEHRD. Q is equal to the unit matrix except in the
053: *          submatrix Q(ilo+1:ihi,ilo+1:ihi).
054: *          If SIDE = 'L', then 1 <= ILO <= IHI <= M, if M > 0, and
055: *          ILO = 1 and IHI = 0, if M = 0;
056: *          if SIDE = 'R', then 1 <= ILO <= IHI <= N, if N > 0, and
057: *          ILO = 1 and IHI = 0, if N = 0.
058: *
059: *  A       (input) COMPLEX array, dimension
060: *                               (LDA,M) if SIDE = 'L'
061: *                               (LDA,N) if SIDE = 'R'
062: *          The vectors which define the elementary reflectors, as
063: *          returned by CGEHRD.
064: *
065: *  LDA     (input) INTEGER
066: *          The leading dimension of the array A.
067: *          LDA >= max(1,M) if SIDE = 'L'; LDA >= max(1,N) if SIDE = 'R'.
068: *
069: *  TAU     (input) COMPLEX array, dimension
070: *                               (M-1) if SIDE = 'L'
071: *                               (N-1) if SIDE = 'R'
072: *          TAU(i) must contain the scalar factor of the elementary
073: *          reflector H(i), as returned by CGEHRD.
074: *
075: *  C       (input/output) COMPLEX array, dimension (LDC,N)
076: *          On entry, the M-by-N matrix C.
077: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
078: *
079: *  LDC     (input) INTEGER
080: *          The leading dimension of the array C. LDC >= max(1,M).
081: *
082: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
083: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
084: *
085: *  LWORK   (input) INTEGER
086: *          The dimension of the array WORK.
087: *          If SIDE = 'L', LWORK >= max(1,N);
088: *          if SIDE = 'R', LWORK >= max(1,M).
089: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
090: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
091: *          blocksize.
092: *
093: *          If LWORK = -1, then a workspace query is assumed; the routine
094: *          only calculates the optimal size of the WORK array, returns
095: *          this value as the first entry of the WORK array, and no error
096: *          message related to LWORK is issued by XERBLA.
097: *
098: *  INFO    (output) INTEGER
099: *          = 0:  successful exit
100: *          < 0:  if INFO = -i, the i-th argument had an illegal value
101: *
102: *  =====================================================================
103: *
104: *     .. Local Scalars ..
105:       LOGICAL            LEFT, LQUERY
106:       INTEGER            I1, I2, IINFO, LWKOPT, MI, NB, NH, NI, NQ, NW
107: *     ..
108: *     .. External Functions ..
109:       LOGICAL            LSAME
110:       INTEGER            ILAENV
111:       EXTERNAL           ILAENV, LSAME
112: *     ..
113: *     .. External Subroutines ..
114:       EXTERNAL           CUNMQR, XERBLA
115: *     ..
116: *     .. Intrinsic Functions ..
117:       INTRINSIC          MAX, MIN
118: *     ..
119: *     .. Executable Statements ..
120: *
121: *     Test the input arguments
122: *
123:       INFO = 0
124:       NH = IHI - ILO
125:       LEFT = LSAME( SIDE, 'L' )
126:       LQUERY = ( LWORK.EQ.-1 )
127: *
128: *     NQ is the order of Q and NW is the minimum dimension of WORK
129: *
130:       IF( LEFT ) THEN
131:          NQ = M
132:          NW = N
133:       ELSE
134:          NQ = N
135:          NW = M
136:       END IF
137:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
138:          INFO = -1
139:       ELSE IF( .NOT.LSAME( TRANS, 'N' ) .AND. .NOT.LSAME( TRANS, 'C' ) )
140:      $          THEN
141:          INFO = -2
142:       ELSE IF( M.LT.0 ) THEN
143:          INFO = -3
144:       ELSE IF( N.LT.0 ) THEN
145:          INFO = -4
146:       ELSE IF( ILO.LT.1 .OR. ILO.GT.MAX( 1, NQ ) ) THEN
147:          INFO = -5
148:       ELSE IF( IHI.LT.MIN( ILO, NQ ) .OR. IHI.GT.NQ ) THEN
149:          INFO = -6
150:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
151:          INFO = -8
152:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
153:          INFO = -11
154:       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
155:          INFO = -13
156:       END IF
157: *
158:       IF( INFO.EQ.0 ) THEN
159:          IF( LEFT ) THEN
160:             NB = ILAENV( 1, 'CUNMQR', SIDE // TRANS, NH, N, NH, -1 )
161:          ELSE
162:             NB = ILAENV( 1, 'CUNMQR', SIDE // TRANS, M, NH, NH, -1 )
163:          END IF
164:          LWKOPT = MAX( 1, NW )*NB
165:          WORK( 1 ) = LWKOPT
166:       END IF
167: *
168:       IF( INFO.NE.0 ) THEN
169:          CALL XERBLA( 'CUNMHR', -INFO )
170:          RETURN
171:       ELSE IF( LQUERY ) THEN
172:          RETURN
173:       END IF
174: *
175: *     Quick return if possible
176: *
177:       IF( M.EQ.0 .OR. N.EQ.0 .OR. NH.EQ.0 ) THEN
178:          WORK( 1 ) = 1
179:          RETURN
180:       END IF
181: *
182:       IF( LEFT ) THEN
183:          MI = NH
184:          NI = N
185:          I1 = ILO + 1
186:          I2 = 1
187:       ELSE
188:          MI = M
189:          NI = NH
190:          I1 = 1
191:          I2 = ILO + 1
192:       END IF
193: *
194:       CALL CUNMQR( SIDE, TRANS, MI, NI, NH, A( ILO+1, ILO ), LDA,
195:      $             TAU( ILO ), C( I1, I2 ), LDC, WORK, LWORK, IINFO )
196: *
197:       WORK( 1 ) = LWKOPT
198:       RETURN
199: *
200: *     End of CUNMHR
201: *
202:       END
203: