001:       SUBROUTINE CPOCON( UPLO, N, A, LDA, ANORM, RCOND, WORK, RWORK,
002:      $                   INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     Modified to call CLACN2 in place of CLACON, 10 Feb 03, SJH.
009: *
010: *     .. Scalar Arguments ..
011:       CHARACTER          UPLO
012:       INTEGER            INFO, LDA, N
013:       REAL               ANORM, RCOND
014: *     ..
015: *     .. Array Arguments ..
016:       REAL               RWORK( * )
017:       COMPLEX            A( LDA, * ), WORK( * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  CPOCON estimates the reciprocal of the condition number (in the
024: *  1-norm) of a complex Hermitian positive definite matrix using the
025: *  Cholesky factorization A = U**H*U or A = L*L**H computed by CPOTRF.
026: *
027: *  An estimate is obtained for norm(inv(A)), and the reciprocal of the
028: *  condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
029: *
030: *  Arguments
031: *  =========
032: *
033: *  UPLO    (input) CHARACTER*1
034: *          = 'U':  Upper triangle of A is stored;
035: *          = 'L':  Lower triangle of A is stored.
036: *
037: *  N       (input) INTEGER
038: *          The order of the matrix A.  N >= 0.
039: *
040: *  A       (input) COMPLEX array, dimension (LDA,N)
041: *          The triangular factor U or L from the Cholesky factorization
042: *          A = U**H*U or A = L*L**H, as computed by CPOTRF.
043: *
044: *  LDA     (input) INTEGER
045: *          The leading dimension of the array A.  LDA >= max(1,N).
046: *
047: *  ANORM   (input) REAL
048: *          The 1-norm (or infinity-norm) of the Hermitian matrix A.
049: *
050: *  RCOND   (output) REAL
051: *          The reciprocal of the condition number of the matrix A,
052: *          computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
053: *          estimate of the 1-norm of inv(A) computed in this routine.
054: *
055: *  WORK    (workspace) COMPLEX array, dimension (2*N)
056: *
057: *  RWORK   (workspace) REAL array, dimension (N)
058: *
059: *  INFO    (output) INTEGER
060: *          = 0:  successful exit
061: *          < 0:  if INFO = -i, the i-th argument had an illegal value
062: *
063: *  =====================================================================
064: *
065: *     .. Parameters ..
066:       REAL               ONE, ZERO
067:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
068: *     ..
069: *     .. Local Scalars ..
070:       LOGICAL            UPPER
071:       CHARACTER          NORMIN
072:       INTEGER            IX, KASE
073:       REAL               AINVNM, SCALE, SCALEL, SCALEU, SMLNUM
074:       COMPLEX            ZDUM
075: *     ..
076: *     .. Local Arrays ..
077:       INTEGER            ISAVE( 3 )
078: *     ..
079: *     .. External Functions ..
080:       LOGICAL            LSAME
081:       INTEGER            ICAMAX
082:       REAL               SLAMCH
083:       EXTERNAL           LSAME, ICAMAX, SLAMCH
084: *     ..
085: *     .. External Subroutines ..
086:       EXTERNAL           CLACN2, CLATRS, CSRSCL, XERBLA
087: *     ..
088: *     .. Intrinsic Functions ..
089:       INTRINSIC          ABS, AIMAG, MAX, REAL
090: *     ..
091: *     .. Statement Functions ..
092:       REAL               CABS1
093: *     ..
094: *     .. Statement Function definitions ..
095:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
096: *     ..
097: *     .. Executable Statements ..
098: *
099: *     Test the input parameters.
100: *
101:       INFO = 0
102:       UPPER = LSAME( UPLO, 'U' )
103:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
104:          INFO = -1
105:       ELSE IF( N.LT.0 ) THEN
106:          INFO = -2
107:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
108:          INFO = -4
109:       ELSE IF( ANORM.LT.ZERO ) THEN
110:          INFO = -5
111:       END IF
112:       IF( INFO.NE.0 ) THEN
113:          CALL XERBLA( 'CPOCON', -INFO )
114:          RETURN
115:       END IF
116: *
117: *     Quick return if possible
118: *
119:       RCOND = ZERO
120:       IF( N.EQ.0 ) THEN
121:          RCOND = ONE
122:          RETURN
123:       ELSE IF( ANORM.EQ.ZERO ) THEN
124:          RETURN
125:       END IF
126: *
127:       SMLNUM = SLAMCH( 'Safe minimum' )
128: *
129: *     Estimate the 1-norm of inv(A).
130: *
131:       KASE = 0
132:       NORMIN = 'N'
133:    10 CONTINUE
134:       CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
135:       IF( KASE.NE.0 ) THEN
136:          IF( UPPER ) THEN
137: *
138: *           Multiply by inv(U').
139: *
140:             CALL CLATRS( 'Upper', 'Conjugate transpose', 'Non-unit',
141:      $                   NORMIN, N, A, LDA, WORK, SCALEL, RWORK, INFO )
142:             NORMIN = 'Y'
143: *
144: *           Multiply by inv(U).
145: *
146:             CALL CLATRS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
147:      $                   A, LDA, WORK, SCALEU, RWORK, INFO )
148:          ELSE
149: *
150: *           Multiply by inv(L).
151: *
152:             CALL CLATRS( 'Lower', 'No transpose', 'Non-unit', NORMIN, N,
153:      $                   A, LDA, WORK, SCALEL, RWORK, INFO )
154:             NORMIN = 'Y'
155: *
156: *           Multiply by inv(L').
157: *
158:             CALL CLATRS( 'Lower', 'Conjugate transpose', 'Non-unit',
159:      $                   NORMIN, N, A, LDA, WORK, SCALEU, RWORK, INFO )
160:          END IF
161: *
162: *        Multiply by 1/SCALE if doing so will not cause overflow.
163: *
164:          SCALE = SCALEL*SCALEU
165:          IF( SCALE.NE.ONE ) THEN
166:             IX = ICAMAX( N, WORK, 1 )
167:             IF( SCALE.LT.CABS1( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
168:      $         GO TO 20
169:             CALL CSRSCL( N, SCALE, WORK, 1 )
170:          END IF
171:          GO TO 10
172:       END IF
173: *
174: *     Compute the estimate of the reciprocal condition number.
175: *
176:       IF( AINVNM.NE.ZERO )
177:      $   RCOND = ( ONE / AINVNM ) / ANORM
178: *
179:    20 CONTINUE
180:       RETURN
181: *
182: *     End of CPOCON
183: *
184:       END
185: