001:       SUBROUTINE CLA_PORFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
002:      $                                AF, LDAF, COLEQU, C, B, LDB, Y,
003:      $                                LDY, BERR_OUT, N_NORMS, ERRS_N,
004:      $                                ERRS_C, RES, AYB, DY, Y_TAIL,
005:      $                                RCOND, ITHRESH, RTHRESH, DZ_UB,
006:      $                                IGNORE_CWISE, INFO )
007: *
008: *     -- LAPACK routine (version 3.2)                                 --
009: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
010: *     -- Jason Riedy of Univ. of California Berkeley.                 --
011: *     -- November 2008                                                --
012: *
013: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
014: *     -- Univ. of California Berkeley and NAG Ltd.                    --
015: *
016:       IMPLICIT NONE
017: *     ..
018: *     .. Scalar Arguments ..
019:       INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
020:      $                   N_NORMS, ITHRESH
021:       CHARACTER          UPLO
022:       LOGICAL            COLEQU, IGNORE_CWISE
023:       REAL               RTHRESH, DZ_UB
024: *     ..
025: *     .. Array Arguments ..
026:       COMPLEX            A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
027:      $                   Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
028:       REAL               C( * ), AYB( * ), RCOND, BERR_OUT( * ),
029:      $                   ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
030: *     ..
031: *     .. Local Scalars ..
032:       INTEGER            UPLO2, CNT, I, J, X_STATE, Z_STATE,
033:      $                   Y_PREC_STATE
034:       REAL               YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
035:      $                   DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
036:      $                   DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
037:      $                   EPS, HUGEVAL, INCR_THRESH
038:       LOGICAL            INCR_PREC
039:       COMPLEX            ZDUM
040: *     ..
041: *     .. Parameters ..
042:       INTEGER            UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
043:      $                   NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
044:      $                   EXTRA_Y
045:       PARAMETER          ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
046:      $                   CONV_STATE = 2, NOPROG_STATE = 3 )
047:       PARAMETER          ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
048:      $                   EXTRA_Y = 2 )
049:       INTEGER            FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
050:       INTEGER            RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
051:       INTEGER            CMP_ERR_I, PIV_GROWTH_I
052:       PARAMETER          ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
053:      $                   BERR_I = 3 )
054:       PARAMETER          ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
055:       PARAMETER          ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
056:      $                   PIV_GROWTH_I = 9 )
057:       INTEGER            LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
058:      $                   LA_LINRX_CWISE_I
059:       PARAMETER          ( LA_LINRX_ITREF_I = 1,
060:      $                   LA_LINRX_ITHRESH_I = 2 )
061:       PARAMETER          ( LA_LINRX_CWISE_I = 3 )
062:       INTEGER            LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
063:      $                   LA_LINRX_RCOND_I
064:       PARAMETER          ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
065:       PARAMETER          ( LA_LINRX_RCOND_I = 3 )
066:       INTEGER            LA_LINRX_MAX_N_ERRS
067:       PARAMETER          ( LA_LINRX_MAX_N_ERRS = 3 )
068: *     ..
069: *     .. External Functions ..
070:       LOGICAL            LSAME
071:       EXTERNAL           ILAUPLO
072:       INTEGER            ILAUPLO
073: *     ..
074: *     .. External Subroutines ..
075:       EXTERNAL           CAXPY, CCOPY, CPOTRS, CHEMV, BLAS_CHEMV_X,
076:      $                   BLAS_CHEMV2_X, CLA_SYAMV, CLA_WWADDW,
077:      $                   CLA_LIN_BERR, SLAMCH
078:       REAL               SLAMCH
079: *     ..
080: *     .. Intrinsic Functions ..
081:       INTRINSIC          ABS, REAL, AIMAG, MAX, MIN
082: *     ..
083: *     .. Statement Functions ..
084:       REAL               CABS1
085: *     ..
086: *     .. Statement Function Definitions ..
087:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
088: *     ..
089: *     .. Executable Statements ..
090: *
091:       IF (INFO.NE.0) RETURN
092:       EPS = SLAMCH( 'Epsilon' )
093:       HUGEVAL = SLAMCH( 'Overflow' )
094: *     Force HUGEVAL to Inf
095:       HUGEVAL = HUGEVAL * HUGEVAL
096: *     Using HUGEVAL may lead to spurious underflows.
097:       INCR_THRESH = REAL(N) * EPS
098: 
099:       IF (LSAME (UPLO, 'L')) THEN
100:          UPLO2 = ILAUPLO( 'L' )
101:       ELSE
102:          UPLO2 = ILAUPLO( 'U' )
103:       ENDIF
104: 
105:       DO J = 1, NRHS
106:          Y_PREC_STATE = EXTRA_RESIDUAL
107:          IF (Y_PREC_STATE .EQ. EXTRA_Y) THEN
108:             DO I = 1, N
109:                Y_TAIL( I ) = 0.0
110:             END DO
111:          END IF
112: 
113:          DXRAT = 0.0
114:          DXRATMAX = 0.0
115:          DZRAT = 0.0
116:          DZRATMAX = 0.0
117:          FINAL_DX_X = HUGEVAL
118:          FINAL_DZ_Z = HUGEVAL
119:          PREVNORMDX = HUGEVAL
120:          PREV_DZ_Z = HUGEVAL
121:          DZ_Z = HUGEVAL
122:          DX_X = HUGEVAL
123: 
124:          X_STATE = WORKING_STATE
125:          Z_STATE = UNSTABLE_STATE
126:          INCR_PREC = .FALSE.
127: 
128:          DO CNT = 1, ITHRESH
129: *
130: *         Compute residual RES = B_s - op(A_s) * Y,
131: *             op(A) = A, A**T, or A**H depending on TRANS (and type).
132: *
133:             CALL CCOPY( N, B( 1, J ), 1, RES, 1 )
134:             IF (Y_PREC_STATE .EQ. BASE_RESIDUAL) THEN
135:                CALL CHEMV(UPLO, N, CMPLX(-1.0), A, LDA, Y(1,J), 1,
136:      $              CMPLX(1.0), RES, 1)
137:             ELSE IF (Y_PREC_STATE .EQ. EXTRA_RESIDUAL) THEN
138:                CALL BLAS_CHEMV_X(UPLO2, N, CMPLX(-1.0), A, LDA,
139:      $              Y( 1, J ), 1, CMPLX(1.0), RES, 1, PREC_TYPE)
140:             ELSE
141:                CALL BLAS_CHEMV2_X(UPLO2, N, CMPLX(-1.0), A, LDA,
142:      $              Y(1, J), Y_TAIL, 1, CMPLX(1.0), RES, 1, PREC_TYPE)
143:             END IF
144: 
145: !         XXX: RES is no longer needed.
146:             CALL CCOPY( N, RES, 1, DY, 1 )
147:             CALL CPOTRS( UPLO, N, NRHS, AF, LDAF, DY, N, INFO)
148: *
149: *         Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
150: *
151:             NORMX = 0.0
152:             NORMY = 0.0
153:             NORMDX = 0.0
154:             DZ_Z = 0.0
155:             YMIN = HUGEVAL
156: 
157:             DO I = 1, N
158:                YK = CABS1(Y(I, J))
159:                DYK = CABS1(DY(I))
160: 
161:                IF (YK .NE. 0.0) THEN
162:                   DZ_Z = MAX( DZ_Z, DYK / YK )
163:                ELSE IF (DYK .NE. 0.0) THEN
164:                   DZ_Z = HUGEVAL
165:                END IF
166: 
167:                YMIN = MIN( YMIN, YK )
168: 
169:                NORMY = MAX( NORMY, YK )
170: 
171:                IF ( COLEQU ) THEN
172:                   NORMX = MAX(NORMX, YK * C(I))
173:                   NORMDX = MAX(NORMDX, DYK * C(I))
174:                ELSE
175:                   NORMX = NORMY
176:                   NORMDX = MAX(NORMDX, DYK)
177:                END IF
178:             END DO
179: 
180:             IF (NORMX .NE. 0.0) THEN
181:                DX_X = NORMDX / NORMX
182:             ELSE IF (NORMDX .EQ. 0.0) THEN
183:                DX_X = 0.0
184:             ELSE
185:                DX_X = HUGEVAL
186:             END IF
187: 
188:             DXRAT = NORMDX / PREVNORMDX
189:             DZRAT = DZ_Z / PREV_DZ_Z
190: *
191: *         Check termination criteria.
192: *
193:             IF (YMIN*RCOND .LT. INCR_THRESH*NORMY
194:      $           .AND. Y_PREC_STATE .LT. EXTRA_Y)
195:      $           INCR_PREC = .TRUE.
196: 
197:             IF (X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH)
198:      $           X_STATE = WORKING_STATE
199:             IF (X_STATE .EQ. WORKING_STATE) THEN
200:                IF (DX_X .LE. EPS) THEN
201:                   X_STATE = CONV_STATE
202:                ELSE IF (DXRAT .GT. RTHRESH) THEN
203:                   IF (Y_PREC_STATE .NE. EXTRA_Y) THEN
204:                      INCR_PREC = .TRUE.
205:                   ELSE
206:                      X_STATE = NOPROG_STATE
207:                   END IF
208:                ELSE
209:                   IF (DXRAT .GT. DXRATMAX) DXRATMAX = DXRAT
210:                END IF
211:                IF (X_STATE .GT. WORKING_STATE) FINAL_DX_X = DX_X
212:             END IF
213: 
214:             IF (Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB)
215:      $           Z_STATE = WORKING_STATE
216:             IF (Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH)
217:      $           Z_STATE = WORKING_STATE
218:             IF (Z_STATE .EQ. WORKING_STATE) THEN
219:                IF (DZ_Z .LE. EPS) THEN
220:                   Z_STATE = CONV_STATE
221:                ELSE IF (DZ_Z .GT. DZ_UB) THEN
222:                   Z_STATE = UNSTABLE_STATE
223:                   DZRATMAX = 0.0
224:                   FINAL_DZ_Z = HUGEVAL
225:                ELSE IF (DZRAT .GT. RTHRESH) THEN
226:                   IF (Y_PREC_STATE .NE. EXTRA_Y) THEN
227:                      INCR_PREC = .TRUE.
228:                   ELSE
229:                      Z_STATE = NOPROG_STATE
230:                   END IF
231:                ELSE
232:                   IF (DZRAT .GT. DZRATMAX) DZRATMAX = DZRAT
233:                END IF
234:                IF (Z_STATE .GT. WORKING_STATE) FINAL_DZ_Z = DZ_Z
235:             END IF
236: 
237:             IF ( X_STATE.NE.WORKING_STATE.AND.
238:      $           (IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE) )
239:      $           GOTO 666
240: 
241:             IF (INCR_PREC) THEN
242:                INCR_PREC = .FALSE.
243:                Y_PREC_STATE = Y_PREC_STATE + 1
244:                DO I = 1, N
245:                   Y_TAIL( I ) = 0.0
246:                END DO
247:             END IF
248: 
249:             PREVNORMDX = NORMDX
250:             PREV_DZ_Z = DZ_Z
251: *
252: *           Update soluton.
253: *
254:             IF (Y_PREC_STATE .LT. EXTRA_Y) THEN
255:                CALL CAXPY( N, CMPLX(1.0), DY, 1, Y(1,J), 1 )
256:             ELSE
257:                CALL CLA_WWADDW(N, Y(1,J), Y_TAIL, DY)
258:             END IF
259: 
260:          END DO
261: *        Target of "IF (Z_STOP .AND. X_STOP)".  Sun's f77 won't EXIT.
262:  666     CONTINUE
263: *
264: *     Set final_* when cnt hits ithresh.
265: *
266:          IF (X_STATE .EQ. WORKING_STATE) FINAL_DX_X = DX_X
267:          IF (Z_STATE .EQ. WORKING_STATE) FINAL_DZ_Z = DZ_Z
268: *
269: *     Compute error bounds.
270: *
271:          IF (N_NORMS .GE. 1) THEN
272:             ERRS_N( J, LA_LINRX_ERR_I ) = FINAL_DX_X / (1 - DXRATMAX)
273:          END IF
274:          IF (N_NORMS .GE. 2) THEN
275:             ERRS_C( J, LA_LINRX_ERR_I ) = FINAL_DZ_Z / (1 - DZRATMAX)
276:          END IF
277: *
278: *     Compute componentwise relative backward error from formula
279: *         max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
280: *     where abs(Z) is the componentwise absolute value of the matrix
281: *     or vector Z.
282: *
283: *        Compute residual RES = B_s - op(A_s) * Y,
284: *            op(A) = A, A**T, or A**H depending on TRANS (and type).
285: *
286:          CALL CCOPY( N, B( 1, J ), 1, RES, 1 )
287:          CALL CHEMV(UPLO, N, CMPLX(-1.0), A, LDA, Y(1,J), 1, CMPLX(1.0),
288:      $        RES, 1)
289: 
290:          DO I = 1, N
291:             AYB( I ) = CABS1( B( I, J ) )
292:          END DO
293: *
294: *     Compute abs(op(A_s))*abs(Y) + abs(B_s).
295: *
296:          CALL CLA_SYAMV (UPLO2, N, 1.0,
297:      $        A, LDA, Y(1, J), 1, 1.0, AYB, 1)
298: 
299:          CALL CLA_LIN_BERR (N, N, 1, RES, AYB, BERR_OUT(J))
300: *
301: *     End of loop for each RHS.
302: *
303:       END DO
304: *
305:       RETURN
306:       END
307: