001:       SUBROUTINE CLA_GERFSX_EXTENDED( PREC_TYPE, TRANS_TYPE, N, NRHS, A,
002:      $                                LDA, AF, LDAF, IPIV, COLEQU, C, B,
003:      $                                LDB, Y, LDY, BERR_OUT, N_NORMS,
004:      $                                ERRS_N, ERRS_C, RES, AYB, DY,
005:      $                                Y_TAIL, RCOND, ITHRESH, RTHRESH,
006:      $                                DZ_UB, IGNORE_CWISE, INFO )
007: *
008: *     -- LAPACK routine (version 3.2)                                 --
009: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
010: *     -- Jason Riedy of Univ. of California Berkeley.                 --
011: *     -- November 2008                                                --
012: *
013: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
014: *     -- Univ. of California Berkeley and NAG Ltd.                    --
015: *
016:       IMPLICIT NONE
017: *     ..
018: *     .. Scalar Arguments ..
019:       INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
020:      $                   TRANS_TYPE, N_NORMS
021:       LOGICAL            COLEQU, IGNORE_CWISE
022:       INTEGER            ITHRESH
023:       REAL               RTHRESH, DZ_UB
024: *     ..
025: *     .. Array Arguments
026:       INTEGER            IPIV( * )
027:       COMPLEX            A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
028:      $                   Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
029:       REAL               C( * ), AYB( * ), RCOND, BERR_OUT( * ),
030:      $                   ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
031: *     ..
032: *     .. Local Scalars ..
033:       CHARACTER          TRANS
034:       INTEGER            CNT, I, J,  X_STATE, Z_STATE, Y_PREC_STATE
035:       REAL               YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
036:      $                   DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
037:      $                   DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
038:      $                   EPS, HUGEVAL, INCR_THRESH
039:       LOGICAL            INCR_PREC
040:       COMPLEX            ZDUM
041: *     ..
042: *     .. Parameters ..
043:       INTEGER            UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
044:      $                   NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
045:      $                   EXTRA_Y
046:       PARAMETER          ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
047:      $                   CONV_STATE = 2,
048:      $                   NOPROG_STATE = 3 )
049:       PARAMETER          ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
050:      $                   EXTRA_Y = 2 )
051:       INTEGER            FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
052:       INTEGER            RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
053:       INTEGER            CMP_ERR_I, PIV_GROWTH_I
054:       PARAMETER          ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
055:      $                   BERR_I = 3 )
056:       PARAMETER          ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
057:       PARAMETER          ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
058:      $                   PIV_GROWTH_I = 9 )
059:       INTEGER            LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
060:      $                   LA_LINRX_CWISE_I
061:       PARAMETER          ( LA_LINRX_ITREF_I = 1,
062:      $                   LA_LINRX_ITHRESH_I = 2 )
063:       PARAMETER          ( LA_LINRX_CWISE_I = 3 )
064:       INTEGER            LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
065:      $                   LA_LINRX_RCOND_I
066:       PARAMETER          ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
067:       PARAMETER          ( LA_LINRX_RCOND_I = 3 )
068:       INTEGER            LA_LINRX_MAX_N_ERRS
069:       PARAMETER          ( LA_LINRX_MAX_N_ERRS = 3 )
070: *     ..
071: *     .. External Subroutines ..
072:       EXTERNAL           CAXPY, CCOPY, CGETRS, CGEMV, BLAS_CGEMV_X,
073:      $                   BLAS_CGEMV2_X, CLA_GEAMV, CLA_WWADDW, SLAMCH,
074:      $                   CHLA_TRANSTYPE, CLA_LIN_BERR
075:       REAL               SLAMCH
076:       CHARACTER          CHLA_TRANSTYPE
077: *     ..
078: *     .. Intrinsic Functions ..
079:       INTRINSIC          ABS, MAX, MIN
080: *     ..
081: *     .. Statement Functions ..
082:       REAL               CABS1
083: *     ..
084: *     .. Statement Function Definitions ..
085:       CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
086: *     ..
087: *     .. Executable Statements ..
088: *
089:       IF ( INFO.NE.0 ) RETURN
090:       TRANS = CHLA_TRANSTYPE(TRANS_TYPE)
091:       EPS = SLAMCH( 'Epsilon' )
092:       HUGEVAL = SLAMCH( 'Overflow' )
093: *     Force HUGEVAL to Inf
094:       HUGEVAL = HUGEVAL * HUGEVAL
095: *     Using HUGEVAL may lead to spurious underflows.
096:       INCR_THRESH = REAL( N ) * EPS
097: *
098:       DO J = 1, NRHS
099:          Y_PREC_STATE = EXTRA_RESIDUAL
100:          IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
101:             DO I = 1, N
102:                Y_TAIL( I ) = 0.0
103:             END DO
104:          END IF
105: 
106:          DXRAT = 0.0
107:          DXRATMAX = 0.0
108:          DZRAT = 0.0
109:          DZRATMAX = 0.0
110:          FINAL_DX_X = HUGEVAL
111:          FINAL_DZ_Z = HUGEVAL
112:          PREVNORMDX = HUGEVAL
113:          PREV_DZ_Z = HUGEVAL
114:          DZ_Z = HUGEVAL
115:          DX_X = HUGEVAL
116: 
117:          X_STATE = WORKING_STATE
118:          Z_STATE = UNSTABLE_STATE
119:          INCR_PREC = .FALSE.
120: 
121:          DO CNT = 1, ITHRESH
122: *
123: *         Compute residual RES = B_s - op(A_s) * Y,
124: *             op(A) = A, A**T, or A**H depending on TRANS (and type).
125: *
126:             CALL CCOPY( N, B( 1, J ), 1, RES, 1 )
127:             IF ( Y_PREC_STATE .EQ. BASE_RESIDUAL ) THEN
128:                CALL CGEMV( TRANS, N, N, (-1.0E+0,0.0E+0), A, LDA,
129:      $              Y( 1, J ), 1, (1.0E+0,0.0E+0), RES, 1)
130:             ELSE IF (Y_PREC_STATE .EQ. EXTRA_RESIDUAL) THEN
131:                CALL BLAS_CGEMV_X( TRANS_TYPE, N, N, (-1.0E+0,0.0E+0), A,
132:      $              LDA, Y( 1, J ), 1, (1.0E+0,0.0E+0),
133:      $              RES, 1, PREC_TYPE )
134:             ELSE
135:                CALL BLAS_CGEMV2_X( TRANS_TYPE, N, N, (-1.0E+0,0.0E+0),
136:      $              A, LDA, Y(1, J), Y_TAIL, 1, (1.0E+0,0.0E+0), RES, 1,
137:      $              PREC_TYPE)
138:             END IF
139: 
140: !         XXX: RES is no longer needed.
141:             CALL CCOPY( N, RES, 1, DY, 1 )
142:             CALL CGETRS( TRANS, N, 1, AF, LDAF, IPIV, DY, N, INFO )
143: *
144: *         Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
145: *
146:             NORMX = 0.0E+0
147:             NORMY = 0.0E+0
148:             NORMDX = 0.0E+0
149:             DZ_Z = 0.0E+0
150:             YMIN = HUGEVAL
151: *
152:             DO I = 1, N
153:                YK = CABS1( Y( I, J ) )
154:                DYK = CABS1( DY( I ) )
155: 
156:                IF ( YK .NE. 0.0E+0 ) THEN
157:                   DZ_Z = MAX( DZ_Z, DYK / YK )
158:                ELSE IF ( DYK .NE. 0.0 ) THEN
159:                   DZ_Z = HUGEVAL
160:                END IF
161: 
162:                YMIN = MIN( YMIN, YK )
163: 
164:                NORMY = MAX( NORMY, YK )
165: 
166:                IF ( COLEQU ) THEN
167:                   NORMX = MAX( NORMX, YK * C( I ) )
168:                   NORMDX = MAX( NORMDX, DYK * C( I ) )
169:                ELSE
170:                   NORMX = NORMY
171:                   NORMDX = MAX(NORMDX, DYK)
172:                END IF
173:             END DO
174: 
175:             IF ( NORMX .NE. 0.0 ) THEN
176:                DX_X = NORMDX / NORMX
177:             ELSE IF ( NORMDX .EQ. 0.0 ) THEN
178:                DX_X = 0.0
179:             ELSE
180:                DX_X = HUGEVAL
181:             END IF
182: 
183:             DXRAT = NORMDX / PREVNORMDX
184:             DZRAT = DZ_Z / PREV_DZ_Z
185: *
186: *         Check termination criteria
187: *
188:             IF (.NOT.IGNORE_CWISE
189:      $           .AND. YMIN*RCOND .LT. INCR_THRESH*NORMY
190:      $           .AND. Y_PREC_STATE .LT. EXTRA_Y )
191:      $           INCR_PREC = .TRUE.
192: 
193:             IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
194:      $           X_STATE = WORKING_STATE
195:             IF ( X_STATE .EQ. WORKING_STATE ) THEN
196:                IF (DX_X .LE. EPS) THEN
197:                   X_STATE = CONV_STATE
198:                ELSE IF ( DXRAT .GT. RTHRESH ) THEN
199:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
200:                      INCR_PREC = .TRUE.
201:                   ELSE
202:                      X_STATE = NOPROG_STATE
203:                   END IF
204:                ELSE
205:                   IF ( DXRAT .GT. DXRATMAX ) DXRATMAX = DXRAT
206:                END IF
207:                IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
208:             END IF
209: 
210:             IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
211:      $           Z_STATE = WORKING_STATE
212:             IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
213:      $           Z_STATE = WORKING_STATE
214:             IF ( Z_STATE .EQ. WORKING_STATE ) THEN
215:                IF ( DZ_Z .LE. EPS ) THEN
216:                   Z_STATE = CONV_STATE
217:                ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
218:                   Z_STATE = UNSTABLE_STATE
219:                   DZRATMAX = 0.0
220:                   FINAL_DZ_Z = HUGEVAL
221:                ELSE IF ( DZRAT .GT. RTHRESH ) THEN
222:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
223:                      INCR_PREC = .TRUE.
224:                   ELSE
225:                      Z_STATE = NOPROG_STATE
226:                   END IF
227:                ELSE
228:                   IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
229:                END IF
230:                IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
231:             END IF
232: *
233: *           Exit if both normwise and componentwise stopped working,
234: *           but if componentwise is unstable, let it go at least two
235: *           iterations.
236: *
237:             IF ( X_STATE.NE.WORKING_STATE ) THEN
238:                IF ( IGNORE_CWISE ) GOTO 666
239:                IF ( Z_STATE.EQ.NOPROG_STATE .OR. Z_STATE.EQ.CONV_STATE )
240:      $              GOTO 666
241:                IF ( Z_STATE.EQ.UNSTABLE_STATE .AND. CNT.GT.1 ) GOTO 666
242:             END IF
243: 
244:             IF ( INCR_PREC ) THEN
245:                INCR_PREC = .FALSE.
246:                Y_PREC_STATE = Y_PREC_STATE + 1
247:                DO I = 1, N
248:                   Y_TAIL( I ) = 0.0
249:                END DO
250:             END IF
251: 
252:             PREVNORMDX = NORMDX
253:             PREV_DZ_Z = DZ_Z
254: *
255: *           Update soluton.
256: *
257:             IF ( Y_PREC_STATE .LT. EXTRA_Y ) THEN
258:                CALL CAXPY( N, (1.0E+0,0.0E+0), DY, 1, Y(1,J), 1 )
259:             ELSE
260:                CALL CLA_WWADDW( N, Y( 1, J ), Y_TAIL, DY )
261:             END IF
262: 
263:          END DO
264: *        Target of "IF (Z_STOP .AND. X_STOP)".  Sun's f77 won't EXIT.
265:  666     CONTINUE
266: *
267: *     Set final_* when cnt hits ithresh
268: *
269:          IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
270:          IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
271: *
272: *     Compute error bounds
273: *
274:          IF (N_NORMS .GE. 1) THEN
275:             ERRS_N( J, LA_LINRX_ERR_I ) = FINAL_DX_X / (1 - DXRATMAX)
276: 
277:          END IF
278:          IF ( N_NORMS .GE. 2 ) THEN
279:             ERRS_C( J, LA_LINRX_ERR_I ) = FINAL_DZ_Z / (1 - DZRATMAX)
280:          END IF
281: *
282: *     Compute componentwise relative backward error from formula
283: *         max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
284: *     where abs(Z) is the componentwise absolute value of the matrix
285: *     or vector Z.
286: *
287: *        Compute residual RES = B_s - op(A_s) * Y,
288: *            op(A) = A, A**T, or A**H depending on TRANS (and type).
289: *
290:          CALL CCOPY( N, B( 1, J ), 1, RES, 1 )
291:          CALL CGEMV( TRANS, N, N, (-1.0E+0,0.0E+0), A, LDA, Y(1,J), 1,
292:      $        (1.0E+0,0.0E+0), RES, 1 )
293: 
294:          DO I = 1, N
295:             AYB( I ) = CABS1( B( I, J ) )
296:          END DO
297: *
298: *     Compute abs(op(A_s))*abs(Y) + abs(B_s).
299: *
300:          CALL CLA_GEAMV ( TRANS_TYPE, N, N, 1.0E+0,
301:      $        A, LDA, Y(1, J), 1, 1.0E+0, AYB, 1 )
302: 
303:          CALL CLA_LIN_BERR ( N, N, 1, RES, AYB, BERR_OUT( J ) )
304: *
305: *     End of loop for each RHS.
306: *
307:       END DO
308: *
309:       RETURN
310:       END
311: