001:       SUBROUTINE CGEQLF( M, N, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            INFO, LDA, LWORK, M, N
009: *     ..
010: *     .. Array Arguments ..
011:       COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
012: *     ..
013: *
014: *  Purpose
015: *  =======
016: *
017: *  CGEQLF computes a QL factorization of a complex M-by-N matrix A:
018: *  A = Q * L.
019: *
020: *  Arguments
021: *  =========
022: *
023: *  M       (input) INTEGER
024: *          The number of rows of the matrix A.  M >= 0.
025: *
026: *  N       (input) INTEGER
027: *          The number of columns of the matrix A.  N >= 0.
028: *
029: *  A       (input/output) COMPLEX array, dimension (LDA,N)
030: *          On entry, the M-by-N matrix A.
031: *          On exit,
032: *          if m >= n, the lower triangle of the subarray
033: *          A(m-n+1:m,1:n) contains the N-by-N lower triangular matrix L;
034: *          if m <= n, the elements on and below the (n-m)-th
035: *          superdiagonal contain the M-by-N lower trapezoidal matrix L;
036: *          the remaining elements, with the array TAU, represent the
037: *          unitary matrix Q as a product of elementary reflectors
038: *          (see Further Details).
039: *
040: *  LDA     (input) INTEGER
041: *          The leading dimension of the array A.  LDA >= max(1,M).
042: *
043: *  TAU     (output) COMPLEX array, dimension (min(M,N))
044: *          The scalar factors of the elementary reflectors (see Further
045: *          Details).
046: *
047: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
048: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
049: *
050: *  LWORK   (input) INTEGER
051: *          The dimension of the array WORK.  LWORK >= max(1,N).
052: *          For optimum performance LWORK >= N*NB, where NB is
053: *          the optimal blocksize.
054: *
055: *          If LWORK = -1, then a workspace query is assumed; the routine
056: *          only calculates the optimal size of the WORK array, returns
057: *          this value as the first entry of the WORK array, and no error
058: *          message related to LWORK is issued by XERBLA.
059: *
060: *  INFO    (output) INTEGER
061: *          = 0:  successful exit
062: *          < 0:  if INFO = -i, the i-th argument had an illegal value
063: *
064: *  Further Details
065: *  ===============
066: *
067: *  The matrix Q is represented as a product of elementary reflectors
068: *
069: *     Q = H(k) . . . H(2) H(1), where k = min(m,n).
070: *
071: *  Each H(i) has the form
072: *
073: *     H(i) = I - tau * v * v'
074: *
075: *  where tau is a complex scalar, and v is a complex vector with
076: *  v(m-k+i+1:m) = 0 and v(m-k+i) = 1; v(1:m-k+i-1) is stored on exit in
077: *  A(1:m-k+i-1,n-k+i), and tau in TAU(i).
078: *
079: *  =====================================================================
080: *
081: *     .. Local Scalars ..
082:       LOGICAL            LQUERY
083:       INTEGER            I, IB, IINFO, IWS, K, KI, KK, LDWORK, LWKOPT,
084:      $                   MU, NB, NBMIN, NU, NX
085: *     ..
086: *     .. External Subroutines ..
087:       EXTERNAL           CGEQL2, CLARFB, CLARFT, XERBLA
088: *     ..
089: *     .. Intrinsic Functions ..
090:       INTRINSIC          MAX, MIN
091: *     ..
092: *     .. External Functions ..
093:       INTEGER            ILAENV
094:       EXTERNAL           ILAENV
095: *     ..
096: *     .. Executable Statements ..
097: *
098: *     Test the input arguments
099: *
100:       INFO = 0
101:       LQUERY = ( LWORK.EQ.-1 )
102:       IF( M.LT.0 ) THEN
103:          INFO = -1
104:       ELSE IF( N.LT.0 ) THEN
105:          INFO = -2
106:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
107:          INFO = -4
108:       END IF
109: *
110:       IF( INFO.EQ.0 ) THEN
111:          K = MIN( M, N )
112:          IF( K.EQ.0 ) THEN
113:             LWKOPT = 1
114:          ELSE
115:             NB = ILAENV( 1, 'CGEQLF', ' ', M, N, -1, -1 )
116:             LWKOPT = N*NB
117:          END IF
118:          WORK( 1 ) = LWKOPT
119: *
120:          IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN
121:             INFO = -7
122:          END IF
123:       END IF
124: *
125:       IF( INFO.NE.0 ) THEN
126:          CALL XERBLA( 'CGEQLF', -INFO )
127:          RETURN
128:       ELSE IF( LQUERY ) THEN
129:          RETURN
130:       END IF
131: *
132: *     Quick return if possible
133: *
134:       IF( K.EQ.0 ) THEN
135:          RETURN
136:       END IF
137: *
138:       NBMIN = 2
139:       NX = 1
140:       IWS = N
141:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
142: *
143: *        Determine when to cross over from blocked to unblocked code.
144: *
145:          NX = MAX( 0, ILAENV( 3, 'CGEQLF', ' ', M, N, -1, -1 ) )
146:          IF( NX.LT.K ) THEN
147: *
148: *           Determine if workspace is large enough for blocked code.
149: *
150:             LDWORK = N
151:             IWS = LDWORK*NB
152:             IF( LWORK.LT.IWS ) THEN
153: *
154: *              Not enough workspace to use optimal NB:  reduce NB and
155: *              determine the minimum value of NB.
156: *
157:                NB = LWORK / LDWORK
158:                NBMIN = MAX( 2, ILAENV( 2, 'CGEQLF', ' ', M, N, -1,
159:      $                 -1 ) )
160:             END IF
161:          END IF
162:       END IF
163: *
164:       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
165: *
166: *        Use blocked code initially.
167: *        The last kk columns are handled by the block method.
168: *
169:          KI = ( ( K-NX-1 ) / NB )*NB
170:          KK = MIN( K, KI+NB )
171: *
172:          DO 10 I = K - KK + KI + 1, K - KK + 1, -NB
173:             IB = MIN( K-I+1, NB )
174: *
175: *           Compute the QL factorization of the current block
176: *           A(1:m-k+i+ib-1,n-k+i:n-k+i+ib-1)
177: *
178:             CALL CGEQL2( M-K+I+IB-1, IB, A( 1, N-K+I ), LDA, TAU( I ),
179:      $                   WORK, IINFO )
180:             IF( N-K+I.GT.1 ) THEN
181: *
182: *              Form the triangular factor of the block reflector
183: *              H = H(i+ib-1) . . . H(i+1) H(i)
184: *
185:                CALL CLARFT( 'Backward', 'Columnwise', M-K+I+IB-1, IB,
186:      $                      A( 1, N-K+I ), LDA, TAU( I ), WORK, LDWORK )
187: *
188: *              Apply H' to A(1:m-k+i+ib-1,1:n-k+i-1) from the left
189: *
190:                CALL CLARFB( 'Left', 'Conjugate transpose', 'Backward',
191:      $                      'Columnwise', M-K+I+IB-1, N-K+I-1, IB,
192:      $                      A( 1, N-K+I ), LDA, WORK, LDWORK, A, LDA,
193:      $                      WORK( IB+1 ), LDWORK )
194:             END IF
195:    10    CONTINUE
196:          MU = M - K + I + NB - 1
197:          NU = N - K + I + NB - 1
198:       ELSE
199:          MU = M
200:          NU = N
201:       END IF
202: *
203: *     Use unblocked code to factor the last or only block
204: *
205:       IF( MU.GT.0 .AND. NU.GT.0 )
206:      $   CALL CGEQL2( MU, NU, A, LDA, TAU, WORK, IINFO )
207: *
208:       WORK( 1 ) = IWS
209:       RETURN
210: *
211: *     End of CGEQLF
212: *
213:       END
214: