001:       SUBROUTINE CGEGS( JOBVSL, JOBVSR, N, A, LDA, B, LDB, ALPHA, BETA,
002:      $                  VSL, LDVSL, VSR, LDVSR, WORK, LWORK, RWORK,
003:      $                  INFO )
004: *
005: *  -- LAPACK driver routine (version 3.2) --
006: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          JOBVSL, JOBVSR
011:       INTEGER            INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N
012: *     ..
013: *     .. Array Arguments ..
014:       REAL               RWORK( * )
015:       COMPLEX            A( LDA, * ), ALPHA( * ), B( LDB, * ),
016:      $                   BETA( * ), VSL( LDVSL, * ), VSR( LDVSR, * ),
017:      $                   WORK( * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  This routine is deprecated and has been replaced by routine CGGES.
024: *
025: *  CGEGS computes the eigenvalues, Schur form, and, optionally, the
026: *  left and or/right Schur vectors of a complex matrix pair (A,B).
027: *  Given two square matrices A and B, the generalized Schur
028: *  factorization has the form
029: *  
030: *     A = Q*S*Z**H,  B = Q*T*Z**H
031: *  
032: *  where Q and Z are unitary matrices and S and T are upper triangular.
033: *  The columns of Q are the left Schur vectors
034: *  and the columns of Z are the right Schur vectors.
035: *  
036: *  If only the eigenvalues of (A,B) are needed, the driver routine
037: *  CGEGV should be used instead.  See CGEGV for a description of the
038: *  eigenvalues of the generalized nonsymmetric eigenvalue problem
039: *  (GNEP).
040: *
041: *  Arguments
042: *  =========
043: *
044: *  JOBVSL   (input) CHARACTER*1
045: *          = 'N':  do not compute the left Schur vectors;
046: *          = 'V':  compute the left Schur vectors (returned in VSL).
047: *
048: *  JOBVSR   (input) CHARACTER*1
049: *          = 'N':  do not compute the right Schur vectors;
050: *          = 'V':  compute the right Schur vectors (returned in VSR).
051: *
052: *  N       (input) INTEGER
053: *          The order of the matrices A, B, VSL, and VSR.  N >= 0.
054: *
055: *  A       (input/output) COMPLEX array, dimension (LDA, N)
056: *          On entry, the matrix A.
057: *          On exit, the upper triangular matrix S from the generalized
058: *          Schur factorization.
059: *
060: *  LDA     (input) INTEGER
061: *          The leading dimension of A.  LDA >= max(1,N).
062: *
063: *  B       (input/output) COMPLEX array, dimension (LDB, N)
064: *          On entry, the matrix B.
065: *          On exit, the upper triangular matrix T from the generalized
066: *          Schur factorization.
067: *
068: *  LDB     (input) INTEGER
069: *          The leading dimension of B.  LDB >= max(1,N).
070: *
071: *  ALPHA   (output) COMPLEX array, dimension (N)
072: *          The complex scalars alpha that define the eigenvalues of
073: *          GNEP.  ALPHA(j) = S(j,j), the diagonal element of the Schur
074: *          form of A.
075: *
076: *  BETA    (output) COMPLEX array, dimension (N)
077: *          The non-negative real scalars beta that define the
078: *          eigenvalues of GNEP.  BETA(j) = T(j,j), the diagonal element
079: *          of the triangular factor T.
080: *
081: *          Together, the quantities alpha = ALPHA(j) and beta = BETA(j)
082: *          represent the j-th eigenvalue of the matrix pair (A,B), in
083: *          one of the forms lambda = alpha/beta or mu = beta/alpha.
084: *          Since either lambda or mu may overflow, they should not,
085: *          in general, be computed.
086: *
087: *  VSL     (output) COMPLEX array, dimension (LDVSL,N)
088: *          If JOBVSL = 'V', the matrix of left Schur vectors Q.
089: *          Not referenced if JOBVSL = 'N'.
090: *
091: *  LDVSL   (input) INTEGER
092: *          The leading dimension of the matrix VSL. LDVSL >= 1, and
093: *          if JOBVSL = 'V', LDVSL >= N.
094: *
095: *  VSR     (output) COMPLEX array, dimension (LDVSR,N)
096: *          If JOBVSR = 'V', the matrix of right Schur vectors Z.
097: *          Not referenced if JOBVSR = 'N'.
098: *
099: *  LDVSR   (input) INTEGER
100: *          The leading dimension of the matrix VSR. LDVSR >= 1, and
101: *          if JOBVSR = 'V', LDVSR >= N.
102: *
103: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
104: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
105: *
106: *  LWORK   (input) INTEGER
107: *          The dimension of the array WORK.  LWORK >= max(1,2*N).
108: *          For good performance, LWORK must generally be larger.
109: *          To compute the optimal value of LWORK, call ILAENV to get
110: *          blocksizes (for CGEQRF, CUNMQR, and CUNGQR.)  Then compute:
111: *          NB  -- MAX of the blocksizes for CGEQRF, CUNMQR, and CUNGQR;
112: *          the optimal LWORK is N*(NB+1).
113: *
114: *          If LWORK = -1, then a workspace query is assumed; the routine
115: *          only calculates the optimal size of the WORK array, returns
116: *          this value as the first entry of the WORK array, and no error
117: *          message related to LWORK is issued by XERBLA.
118: *
119: *  RWORK   (workspace) REAL array, dimension (3*N)
120: *
121: *  INFO    (output) INTEGER
122: *          = 0:  successful exit
123: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
124: *          =1,...,N:
125: *                The QZ iteration failed.  (A,B) are not in Schur
126: *                form, but ALPHA(j) and BETA(j) should be correct for
127: *                j=INFO+1,...,N.
128: *          > N:  errors that usually indicate LAPACK problems:
129: *                =N+1: error return from CGGBAL
130: *                =N+2: error return from CGEQRF
131: *                =N+3: error return from CUNMQR
132: *                =N+4: error return from CUNGQR
133: *                =N+5: error return from CGGHRD
134: *                =N+6: error return from CHGEQZ (other than failed
135: *                                               iteration)
136: *                =N+7: error return from CGGBAK (computing VSL)
137: *                =N+8: error return from CGGBAK (computing VSR)
138: *                =N+9: error return from CLASCL (various places)
139: *
140: *  =====================================================================
141: *
142: *     .. Parameters ..
143:       REAL               ZERO, ONE
144:       PARAMETER          ( ZERO = 0.0E0, ONE = 1.0E0 )
145:       COMPLEX            CZERO, CONE
146:       PARAMETER          ( CZERO = ( 0.0E0, 0.0E0 ),
147:      $                   CONE = ( 1.0E0, 0.0E0 ) )
148: *     ..
149: *     .. Local Scalars ..
150:       LOGICAL            ILASCL, ILBSCL, ILVSL, ILVSR, LQUERY
151:       INTEGER            ICOLS, IHI, IINFO, IJOBVL, IJOBVR, ILEFT,
152:      $                   ILO, IRIGHT, IROWS, IRWORK, ITAU, IWORK,
153:      $                   LOPT, LWKMIN, LWKOPT, NB, NB1, NB2, NB3
154:       REAL               ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS,
155:      $                   SAFMIN, SMLNUM
156: *     ..
157: *     .. External Subroutines ..
158:       EXTERNAL           CGEQRF, CGGBAK, CGGBAL, CGGHRD, CHGEQZ, CLACPY,
159:      $                   CLASCL, CLASET, CUNGQR, CUNMQR, XERBLA
160: *     ..
161: *     .. External Functions ..
162:       LOGICAL            LSAME
163:       INTEGER            ILAENV
164:       REAL               CLANGE, SLAMCH
165:       EXTERNAL           ILAENV, LSAME, CLANGE, SLAMCH
166: *     ..
167: *     .. Intrinsic Functions ..
168:       INTRINSIC          INT, MAX
169: *     ..
170: *     .. Executable Statements ..
171: *
172: *     Decode the input arguments
173: *
174:       IF( LSAME( JOBVSL, 'N' ) ) THEN
175:          IJOBVL = 1
176:          ILVSL = .FALSE.
177:       ELSE IF( LSAME( JOBVSL, 'V' ) ) THEN
178:          IJOBVL = 2
179:          ILVSL = .TRUE.
180:       ELSE
181:          IJOBVL = -1
182:          ILVSL = .FALSE.
183:       END IF
184: *
185:       IF( LSAME( JOBVSR, 'N' ) ) THEN
186:          IJOBVR = 1
187:          ILVSR = .FALSE.
188:       ELSE IF( LSAME( JOBVSR, 'V' ) ) THEN
189:          IJOBVR = 2
190:          ILVSR = .TRUE.
191:       ELSE
192:          IJOBVR = -1
193:          ILVSR = .FALSE.
194:       END IF
195: *
196: *     Test the input arguments
197: *
198:       LWKMIN = MAX( 2*N, 1 )
199:       LWKOPT = LWKMIN
200:       WORK( 1 ) = LWKOPT
201:       LQUERY = ( LWORK.EQ.-1 )
202:       INFO = 0
203:       IF( IJOBVL.LE.0 ) THEN
204:          INFO = -1
205:       ELSE IF( IJOBVR.LE.0 ) THEN
206:          INFO = -2
207:       ELSE IF( N.LT.0 ) THEN
208:          INFO = -3
209:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
210:          INFO = -5
211:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
212:          INFO = -7
213:       ELSE IF( LDVSL.LT.1 .OR. ( ILVSL .AND. LDVSL.LT.N ) ) THEN
214:          INFO = -11
215:       ELSE IF( LDVSR.LT.1 .OR. ( ILVSR .AND. LDVSR.LT.N ) ) THEN
216:          INFO = -13
217:       ELSE IF( LWORK.LT.LWKMIN .AND. .NOT.LQUERY ) THEN
218:          INFO = -15
219:       END IF
220: *
221:       IF( INFO.EQ.0 ) THEN
222:          NB1 = ILAENV( 1, 'CGEQRF', ' ', N, N, -1, -1 )
223:          NB2 = ILAENV( 1, 'CUNMQR', ' ', N, N, N, -1 )
224:          NB3 = ILAENV( 1, 'CUNGQR', ' ', N, N, N, -1 )
225:          NB = MAX( NB1, NB2, NB3 )
226:          LOPT = N*(NB+1)
227:          WORK( 1 ) = LOPT
228:       END IF
229: *
230:       IF( INFO.NE.0 ) THEN
231:          CALL XERBLA( 'CGEGS ', -INFO )
232:          RETURN
233:       ELSE IF( LQUERY ) THEN
234:          RETURN
235:       END IF
236: *
237: *     Quick return if possible
238: *
239:       IF( N.EQ.0 )
240:      $   RETURN
241: *
242: *     Get machine constants
243: *
244:       EPS = SLAMCH( 'E' )*SLAMCH( 'B' )
245:       SAFMIN = SLAMCH( 'S' )
246:       SMLNUM = N*SAFMIN / EPS
247:       BIGNUM = ONE / SMLNUM
248: *
249: *     Scale A if max element outside range [SMLNUM,BIGNUM]
250: *
251:       ANRM = CLANGE( 'M', N, N, A, LDA, RWORK )
252:       ILASCL = .FALSE.
253:       IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
254:          ANRMTO = SMLNUM
255:          ILASCL = .TRUE.
256:       ELSE IF( ANRM.GT.BIGNUM ) THEN
257:          ANRMTO = BIGNUM
258:          ILASCL = .TRUE.
259:       END IF
260: *
261:       IF( ILASCL ) THEN
262:          CALL CLASCL( 'G', -1, -1, ANRM, ANRMTO, N, N, A, LDA, IINFO )
263:          IF( IINFO.NE.0 ) THEN
264:             INFO = N + 9
265:             RETURN
266:          END IF
267:       END IF
268: *
269: *     Scale B if max element outside range [SMLNUM,BIGNUM]
270: *
271:       BNRM = CLANGE( 'M', N, N, B, LDB, RWORK )
272:       ILBSCL = .FALSE.
273:       IF( BNRM.GT.ZERO .AND. BNRM.LT.SMLNUM ) THEN
274:          BNRMTO = SMLNUM
275:          ILBSCL = .TRUE.
276:       ELSE IF( BNRM.GT.BIGNUM ) THEN
277:          BNRMTO = BIGNUM
278:          ILBSCL = .TRUE.
279:       END IF
280: *
281:       IF( ILBSCL ) THEN
282:          CALL CLASCL( 'G', -1, -1, BNRM, BNRMTO, N, N, B, LDB, IINFO )
283:          IF( IINFO.NE.0 ) THEN
284:             INFO = N + 9
285:             RETURN
286:          END IF
287:       END IF
288: *
289: *     Permute the matrix to make it more nearly triangular
290: *
291:       ILEFT = 1
292:       IRIGHT = N + 1
293:       IRWORK = IRIGHT + N
294:       IWORK = 1
295:       CALL CGGBAL( 'P', N, A, LDA, B, LDB, ILO, IHI, RWORK( ILEFT ),
296:      $             RWORK( IRIGHT ), RWORK( IRWORK ), IINFO )
297:       IF( IINFO.NE.0 ) THEN
298:          INFO = N + 1
299:          GO TO 10
300:       END IF
301: *
302: *     Reduce B to triangular form, and initialize VSL and/or VSR
303: *
304:       IROWS = IHI + 1 - ILO
305:       ICOLS = N + 1 - ILO
306:       ITAU = IWORK
307:       IWORK = ITAU + IROWS
308:       CALL CGEQRF( IROWS, ICOLS, B( ILO, ILO ), LDB, WORK( ITAU ),
309:      $             WORK( IWORK ), LWORK+1-IWORK, IINFO )
310:       IF( IINFO.GE.0 )
311:      $   LWKOPT = MAX( LWKOPT, INT( WORK( IWORK ) )+IWORK-1 )
312:       IF( IINFO.NE.0 ) THEN
313:          INFO = N + 2
314:          GO TO 10
315:       END IF
316: *
317:       CALL CUNMQR( 'L', 'C', IROWS, ICOLS, IROWS, B( ILO, ILO ), LDB,
318:      $             WORK( ITAU ), A( ILO, ILO ), LDA, WORK( IWORK ),
319:      $             LWORK+1-IWORK, IINFO )
320:       IF( IINFO.GE.0 )
321:      $   LWKOPT = MAX( LWKOPT, INT( WORK( IWORK ) )+IWORK-1 )
322:       IF( IINFO.NE.0 ) THEN
323:          INFO = N + 3
324:          GO TO 10
325:       END IF
326: *
327:       IF( ILVSL ) THEN
328:          CALL CLASET( 'Full', N, N, CZERO, CONE, VSL, LDVSL )
329:          CALL CLACPY( 'L', IROWS-1, IROWS-1, B( ILO+1, ILO ), LDB,
330:      $                VSL( ILO+1, ILO ), LDVSL )
331:          CALL CUNGQR( IROWS, IROWS, IROWS, VSL( ILO, ILO ), LDVSL,
332:      $                WORK( ITAU ), WORK( IWORK ), LWORK+1-IWORK,
333:      $                IINFO )
334:          IF( IINFO.GE.0 )
335:      $      LWKOPT = MAX( LWKOPT, INT( WORK( IWORK ) )+IWORK-1 )
336:          IF( IINFO.NE.0 ) THEN
337:             INFO = N + 4
338:             GO TO 10
339:          END IF
340:       END IF
341: *
342:       IF( ILVSR )
343:      $   CALL CLASET( 'Full', N, N, CZERO, CONE, VSR, LDVSR )
344: *
345: *     Reduce to generalized Hessenberg form
346: *
347:       CALL CGGHRD( JOBVSL, JOBVSR, N, ILO, IHI, A, LDA, B, LDB, VSL,
348:      $             LDVSL, VSR, LDVSR, IINFO )
349:       IF( IINFO.NE.0 ) THEN
350:          INFO = N + 5
351:          GO TO 10
352:       END IF
353: *
354: *     Perform QZ algorithm, computing Schur vectors if desired
355: *
356:       IWORK = ITAU
357:       CALL CHGEQZ( 'S', JOBVSL, JOBVSR, N, ILO, IHI, A, LDA, B, LDB,
358:      $             ALPHA, BETA, VSL, LDVSL, VSR, LDVSR, WORK( IWORK ),
359:      $             LWORK+1-IWORK, RWORK( IRWORK ), IINFO )
360:       IF( IINFO.GE.0 )
361:      $   LWKOPT = MAX( LWKOPT, INT( WORK( IWORK ) )+IWORK-1 )
362:       IF( IINFO.NE.0 ) THEN
363:          IF( IINFO.GT.0 .AND. IINFO.LE.N ) THEN
364:             INFO = IINFO
365:          ELSE IF( IINFO.GT.N .AND. IINFO.LE.2*N ) THEN
366:             INFO = IINFO - N
367:          ELSE
368:             INFO = N + 6
369:          END IF
370:          GO TO 10
371:       END IF
372: *
373: *     Apply permutation to VSL and VSR
374: *
375:       IF( ILVSL ) THEN
376:          CALL CGGBAK( 'P', 'L', N, ILO, IHI, RWORK( ILEFT ),
377:      $                RWORK( IRIGHT ), N, VSL, LDVSL, IINFO )
378:          IF( IINFO.NE.0 ) THEN
379:             INFO = N + 7
380:             GO TO 10
381:          END IF
382:       END IF
383:       IF( ILVSR ) THEN
384:          CALL CGGBAK( 'P', 'R', N, ILO, IHI, RWORK( ILEFT ),
385:      $                RWORK( IRIGHT ), N, VSR, LDVSR, IINFO )
386:          IF( IINFO.NE.0 ) THEN
387:             INFO = N + 8
388:             GO TO 10
389:          END IF
390:       END IF
391: *
392: *     Undo scaling
393: *
394:       IF( ILASCL ) THEN
395:          CALL CLASCL( 'U', -1, -1, ANRMTO, ANRM, N, N, A, LDA, IINFO )
396:          IF( IINFO.NE.0 ) THEN
397:             INFO = N + 9
398:             RETURN
399:          END IF
400:          CALL CLASCL( 'G', -1, -1, ANRMTO, ANRM, N, 1, ALPHA, N, IINFO )
401:          IF( IINFO.NE.0 ) THEN
402:             INFO = N + 9
403:             RETURN
404:          END IF
405:       END IF
406: *
407:       IF( ILBSCL ) THEN
408:          CALL CLASCL( 'U', -1, -1, BNRMTO, BNRM, N, N, B, LDB, IINFO )
409:          IF( IINFO.NE.0 ) THEN
410:             INFO = N + 9
411:             RETURN
412:          END IF
413:          CALL CLASCL( 'G', -1, -1, BNRMTO, BNRM, N, 1, BETA, N, IINFO )
414:          IF( IINFO.NE.0 ) THEN
415:             INFO = N + 9
416:             RETURN
417:          END IF
418:       END IF
419: *
420:    10 CONTINUE
421:       WORK( 1 ) = LWKOPT
422: *
423:       RETURN
424: *
425: *     End of CGEGS
426: *
427:       END
428: