pzqrt13.f

Go to the documentation of this file.

      SUBROUTINE pzqrt13( SCALE, M, N, A, IA, JA, DESCA, NORMA, ISEED,
     $                    WORK )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IA, ISEED, JA, M, N, SCALE
      DOUBLE PRECISION   NORMA
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      DOUBLE PRECISION   WORK( * )
      COMPLEX*16         A( * )
*     ..
*
*  Purpose
*  =======
*
*  PZQRT13 generates a full-rank matrix that may be scaled to have
*  large or small norm.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  SCALE   (global input) INTEGER
*          SCALE = 1: normally scaled matrix
*          SCALE = 2: matrix scaled up
*          SCALE = 3: matrix scaled down
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local output) COMPLEX*16 pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+N-1)). This array
*          contains the local pieces of the distributed matrix sub( A ).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  NORMA   (global output) DOUBLE PRECISION
*          The one-norm of A.
*
*  ISEED   (global input/global output) INTEGER
*          Seed for random number generator.
*
*  WORK    (local workspace) DOUBLE PRECISION   array, dimension (LWORK)
*          LWORK >= Nq0, where
*
*          ICOFFA = MOD( JA-1, NB_A ),
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ), and
*          Nq0 = NUMROC( N+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ).
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions; MYROW,
*          MYCOL, NPROW and NPCOL can be determined by calling the
*          subroutine BLACS_GRIDINFO.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IACOL, IAROW, ICOFFA, ICTXT, IIA, INFO,
     $                   iroffa, j, jja, mp, mycol, myrow, npcol,
     $                   nprow, nq
      DOUBLE PRECISION   ASUM, BIGNUM, SMLNUM
      COMPLEX*16         AJJ
*     ..
*     .. External Functions ..
      INTEGER            NUMROC
      DOUBLE PRECISION   PDLAMCH, PZLANGE
      EXTERNAL           numroc, pdlamch, pdlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, infog2l, pdlabad,
     $                   pdzasum, pzlascl, pzmatgen,
     $                   pzelget, pzelset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, mod, sign
*     ..
*     .. Executable Statements ..
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     generate the matrix
*
      iroffa = mod( ia-1, desca( mb_ ) )
      icoffa = mod( ja-1, desca( nb_ ) )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, iia,
     $              jja, iarow, iacol )
      mp = numroc( m+iroffa, desca( mb_ ), myrow, iarow, nprow )
      nq = numroc( n+icoffa, desca( nb_ ), mycol, iacol, npcol )
      IF( myrow.EQ.iarow )
     $   mp = mp - iroffa
      IF( mycol.EQ.iacol )
     $   nq = nq  - icoffa
*
      CALL pzmatgen( ictxt, 'N', 'N', desca( m_ ), desca( n_ ),
     $               desca( mb_ ), desca( nb_ ), a, desca( lld_ ),
     $               desca( rsrc_ ), desca( csrc_ ), iseed, iia-1, mp,
     $               jja-1, nq, myrow, mycol, nprow, npcol )
*
      DO 10 j = ja, ja+n-1
         i = ia + j - ja
         IF( i.LE.ia+m-1 ) THEN
            CALL pdzasum( m, asum, a, ia, j, desca, 1 )
            CALL pzelget( 'Column', ' ', ajj, a, i, j, desca )
            ajj = ajj + dcmplx( sign( asum, dble( ajj ) ) )
            CALL pzelset( a, i, j, desca, ajj )
         END IF
   10 CONTINUE
*
*     scaled versions
*
      IF( scale.NE.1 ) THEN
*
         norma = pzlange( 'M', m, n, a, ia, ja, desca, work )
         smlnum = pdlamch( ictxt, 'Safe minimum' )
         bignum = one / smlnum
         CALL pdlabad( ictxt, smlnum, bignum )
         smlnum = smlnum / pdlamch( ictxt, 'Epsilon' )
         bignum = one / smlnum
*
         IF( scale.EQ.2 ) THEN
*
*           matrix scaled up
*
            CALL pzlascl( 'General', norma, bignum, m, n, a, ia,
     $                   ja, desca, info )
*
         ELSE IF( scale.EQ.3 ) THEN
*
*           matrix scaled down
*
            CALL pzlascl( 'General', norma, smlnum, m, n, a, ia,
     $                   ja, desca, info )
*
         END IF
*
      END IF
*
      norma = pzlange( 'One-norm', m, n, a, ia, ja, desca, work )
*
      RETURN
*
*     End of PZQRT13
*
      END