LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dlasd1()

subroutine dlasd1 ( integer  NL,
integer  NR,
integer  SQRE,
double precision, dimension( * )  D,
double precision  ALPHA,
double precision  BETA,
double precision, dimension( ldu, * )  U,
integer  LDU,
double precision, dimension( ldvt, * )  VT,
integer  LDVT,
integer, dimension( * )  IDXQ,
integer, dimension( * )  IWORK,
double precision, dimension( * )  WORK,
integer  INFO 
)

DLASD1 computes the SVD of an upper bidiagonal matrix B of the specified size. Used by sbdsdc.

Download DLASD1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLASD1 computes the SVD of an upper bidiagonal N-by-M matrix B,
 where N = NL + NR + 1 and M = N + SQRE. DLASD1 is called from DLASD0.

 A related subroutine DLASD7 handles the case in which the singular
 values (and the singular vectors in factored form) are desired.

 DLASD1 computes the SVD as follows:

               ( D1(in)    0    0       0 )
   B = U(in) * (   Z1**T   a   Z2**T    b ) * VT(in)
               (   0       0   D2(in)   0 )

     = U(out) * ( D(out) 0) * VT(out)

 where Z**T = (Z1**T a Z2**T b) = u**T VT**T, and u is a vector of dimension M
 with ALPHA and BETA in the NL+1 and NL+2 th entries and zeros
 elsewhere; and the entry b is empty if SQRE = 0.

 The left singular vectors of the original matrix are stored in U, and
 the transpose of the right singular vectors are stored in VT, and the
 singular values are in D.  The algorithm consists of three stages:

    The first stage consists of deflating the size of the problem
    when there are multiple singular values or when there are zeros in
    the Z vector.  For each such occurrence the dimension of the
    secular equation problem is reduced by one.  This stage is
    performed by the routine DLASD2.

    The second stage consists of calculating the updated
    singular values. This is done by finding the square roots of the
    roots of the secular equation via the routine DLASD4 (as called
    by DLASD3). This routine also calculates the singular vectors of
    the current problem.

    The final stage consists of computing the updated singular vectors
    directly using the updated singular values.  The singular vectors
    for the current problem are multiplied with the singular vectors
    from the overall problem.
Parameters
[in]NL
          NL is INTEGER
         The row dimension of the upper block.  NL >= 1.
[in]NR
          NR is INTEGER
         The row dimension of the lower block.  NR >= 1.
[in]SQRE
          SQRE is INTEGER
         = 0: the lower block is an NR-by-NR square matrix.
         = 1: the lower block is an NR-by-(NR+1) rectangular matrix.

         The bidiagonal matrix has row dimension N = NL + NR + 1,
         and column dimension M = N + SQRE.
[in,out]D
          D is DOUBLE PRECISION array,
                        dimension (N = NL+NR+1).
         On entry D(1:NL,1:NL) contains the singular values of the
         upper block; and D(NL+2:N) contains the singular values of
         the lower block. On exit D(1:N) contains the singular values
         of the modified matrix.
[in,out]ALPHA
          ALPHA is DOUBLE PRECISION
         Contains the diagonal element associated with the added row.
[in,out]BETA
          BETA is DOUBLE PRECISION
         Contains the off-diagonal element associated with the added
         row.
[in,out]U
          U is DOUBLE PRECISION array, dimension(LDU,N)
         On entry U(1:NL, 1:NL) contains the left singular vectors of
         the upper block; U(NL+2:N, NL+2:N) contains the left singular
         vectors of the lower block. On exit U contains the left
         singular vectors of the bidiagonal matrix.
[in]LDU
          LDU is INTEGER
         The leading dimension of the array U.  LDU >= max( 1, N ).
[in,out]VT
          VT is DOUBLE PRECISION array, dimension(LDVT,M)
         where M = N + SQRE.
         On entry VT(1:NL+1, 1:NL+1)**T contains the right singular
         vectors of the upper block; VT(NL+2:M, NL+2:M)**T contains
         the right singular vectors of the lower block. On exit
         VT**T contains the right singular vectors of the
         bidiagonal matrix.
[in]LDVT
          LDVT is INTEGER
         The leading dimension of the array VT.  LDVT >= max( 1, M ).
[in,out]IDXQ
          IDXQ is INTEGER array, dimension(N)
         This contains the permutation which will reintegrate the
         subproblem just solved back into sorted order, i.e.
         D( IDXQ( I = 1, N ) ) will be in ascending order.
[out]IWORK
          IWORK is INTEGER array, dimension( 4 * N )
[out]WORK
          WORK is DOUBLE PRECISION array, dimension( 3*M**2 + 2*M )
[out]INFO
          INFO is INTEGER
          = 0:  successful exit.
          < 0:  if INFO = -i, the i-th argument had an illegal value.
          > 0:  if INFO = 1, a singular value did not converge
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2016
Contributors:
Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA

Definition at line 206 of file dlasd1.f.

206 *
207 * -- LAPACK auxiliary routine (version 3.7.0) --
208 * -- LAPACK is a software package provided by Univ. of Tennessee, --
209 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
210 * June 2016
211 *
212 * .. Scalar Arguments ..
213  INTEGER info, ldu, ldvt, nl, nr, sqre
214  DOUBLE PRECISION alpha, beta
215 * ..
216 * .. Array Arguments ..
217  INTEGER idxq( * ), iwork( * )
218  DOUBLE PRECISION d( * ), u( ldu, * ), vt( ldvt, * ), work( * )
219 * ..
220 *
221 * =====================================================================
222 *
223 * .. Parameters ..
224 *
225  DOUBLE PRECISION one, zero
226  parameter( one = 1.0d+0, zero = 0.0d+0 )
227 * ..
228 * .. Local Scalars ..
229  INTEGER coltyp, i, idx, idxc, idxp, iq, isigma, iu2,
230  $ ivt2, iz, k, ldq, ldu2, ldvt2, m, n, n1, n2
231  DOUBLE PRECISION orgnrm
232 * ..
233 * .. External Subroutines ..
234  EXTERNAL dlamrg, dlascl, dlasd2, dlasd3, xerbla
235 * ..
236 * .. Intrinsic Functions ..
237  INTRINSIC abs, max
238 * ..
239 * .. Executable Statements ..
240 *
241 * Test the input parameters.
242 *
243  info = 0
244 *
245  IF( nl.LT.1 ) THEN
246  info = -1
247  ELSE IF( nr.LT.1 ) THEN
248  info = -2
249  ELSE IF( ( sqre.LT.0 ) .OR. ( sqre.GT.1 ) ) THEN
250  info = -3
251  END IF
252  IF( info.NE.0 ) THEN
253  CALL xerbla( 'DLASD1', -info )
254  RETURN
255  END IF
256 *
257  n = nl + nr + 1
258  m = n + sqre
259 *
260 * The following values are for bookkeeping purposes only. They are
261 * integer pointers which indicate the portion of the workspace
262 * used by a particular array in DLASD2 and DLASD3.
263 *
264  ldu2 = n
265  ldvt2 = m
266 *
267  iz = 1
268  isigma = iz + m
269  iu2 = isigma + n
270  ivt2 = iu2 + ldu2*n
271  iq = ivt2 + ldvt2*m
272 *
273  idx = 1
274  idxc = idx + n
275  coltyp = idxc + n
276  idxp = coltyp + n
277 *
278 * Scale.
279 *
280  orgnrm = max( abs( alpha ), abs( beta ) )
281  d( nl+1 ) = zero
282  DO 10 i = 1, n
283  IF( abs( d( i ) ).GT.orgnrm ) THEN
284  orgnrm = abs( d( i ) )
285  END IF
286  10 CONTINUE
287  CALL dlascl( 'G', 0, 0, orgnrm, one, n, 1, d, n, info )
288  alpha = alpha / orgnrm
289  beta = beta / orgnrm
290 *
291 * Deflate singular values.
292 *
293  CALL dlasd2( nl, nr, sqre, k, d, work( iz ), alpha, beta, u, ldu,
294  $ vt, ldvt, work( isigma ), work( iu2 ), ldu2,
295  $ work( ivt2 ), ldvt2, iwork( idxp ), iwork( idx ),
296  $ iwork( idxc ), idxq, iwork( coltyp ), info )
297 *
298 * Solve Secular Equation and update singular vectors.
299 *
300  ldq = k
301  CALL dlasd3( nl, nr, sqre, k, d, work( iq ), ldq, work( isigma ),
302  $ u, ldu, work( iu2 ), ldu2, vt, ldvt, work( ivt2 ),
303  $ ldvt2, iwork( idxc ), iwork( coltyp ), work( iz ),
304  $ info )
305 *
306 * Report the convergence failure.
307 *
308  IF( info.NE.0 ) THEN
309  RETURN
310  END IF
311 *
312 * Unscale.
313 *
314  CALL dlascl( 'G', 0, 0, one, orgnrm, n, 1, d, n, info )
315 *
316 * Prepare the IDXQ sorting permutation.
317 *
318  n1 = k
319  n2 = n - k
320  CALL dlamrg( n1, n2, d, 1, -1, idxq )
321 *
322  RETURN
323 *
324 * End of DLASD1
325 *
subroutine dlascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
DLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: dlascl.f:145
subroutine dlasd3(NL, NR, SQRE, K, D, Q, LDQ, DSIGMA, U, LDU, U2, LDU2, VT, LDVT, VT2, LDVT2, IDXC, CTOT, Z, INFO)
DLASD3 finds all square roots of the roots of the secular equation, as defined by the values in D and...
Definition: dlasd3.f:226
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dlasd2(NL, NR, SQRE, K, D, Z, ALPHA, BETA, U, LDU, VT, LDVT, DSIGMA, U2, LDU2, VT2, LDVT2, IDXP, IDX, IDXC, IDXQ, COLTYP, INFO)
DLASD2 merges the two sets of singular values together into a single sorted set. Used by sbdsdc...
Definition: dlasd2.f:271
subroutine dlamrg(N1, N2, A, DTRD1, DTRD2, INDEX)
DLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition: dlamrg.f:101
Here is the call graph for this function:
Here is the caller graph for this function: