LAPACK  3.10.0 LAPACK: Linear Algebra PACKage

## ◆ slasd1()

 subroutine slasd1 ( integer NL, integer NR, integer SQRE, real, dimension( * ) D, real ALPHA, real BETA, real, dimension( ldu, * ) U, integer LDU, real, dimension( ldvt, * ) VT, integer LDVT, integer, dimension( * ) IDXQ, integer, dimension( * ) IWORK, real, dimension( * ) WORK, integer INFO )

SLASD1 computes the SVD of an upper bidiagonal matrix B of the specified size. Used by sbdsdc.

Purpose:
``` SLASD1 computes the SVD of an upper bidiagonal N-by-M matrix B,
where N = NL + NR + 1 and M = N + SQRE. SLASD1 is called from SLASD0.

A related subroutine SLASD7 handles the case in which the singular
values (and the singular vectors in factored form) are desired.

SLASD1 computes the SVD as follows:

( D1(in)    0    0       0 )
B = U(in) * (   Z1**T   a   Z2**T    b ) * VT(in)
(   0       0   D2(in)   0 )

= U(out) * ( D(out) 0) * VT(out)

where Z**T = (Z1**T a Z2**T b) = u**T VT**T, and u is a vector of dimension M
with ALPHA and BETA in the NL+1 and NL+2 th entries and zeros
elsewhere; and the entry b is empty if SQRE = 0.

The left singular vectors of the original matrix are stored in U, and
the transpose of the right singular vectors are stored in VT, and the
singular values are in D.  The algorithm consists of three stages:

The first stage consists of deflating the size of the problem
when there are multiple singular values or when there are zeros in
the Z vector.  For each such occurrence the dimension of the
secular equation problem is reduced by one.  This stage is
performed by the routine SLASD2.

The second stage consists of calculating the updated
singular values. This is done by finding the square roots of the
roots of the secular equation via the routine SLASD4 (as called
by SLASD3). This routine also calculates the singular vectors of
the current problem.

The final stage consists of computing the updated singular vectors
directly using the updated singular values.  The singular vectors
for the current problem are multiplied with the singular vectors
from the overall problem.```
Parameters
 [in] NL ``` NL is INTEGER The row dimension of the upper block. NL >= 1.``` [in] NR ``` NR is INTEGER The row dimension of the lower block. NR >= 1.``` [in] SQRE ``` SQRE is INTEGER = 0: the lower block is an NR-by-NR square matrix. = 1: the lower block is an NR-by-(NR+1) rectangular matrix. The bidiagonal matrix has row dimension N = NL + NR + 1, and column dimension M = N + SQRE.``` [in,out] D ``` D is REAL array, dimension (NL+NR+1). N = NL+NR+1 On entry D(1:NL,1:NL) contains the singular values of the upper block; and D(NL+2:N) contains the singular values of the lower block. On exit D(1:N) contains the singular values of the modified matrix.``` [in,out] ALPHA ``` ALPHA is REAL Contains the diagonal element associated with the added row.``` [in,out] BETA ``` BETA is REAL Contains the off-diagonal element associated with the added row.``` [in,out] U ``` U is REAL array, dimension (LDU,N) On entry U(1:NL, 1:NL) contains the left singular vectors of the upper block; U(NL+2:N, NL+2:N) contains the left singular vectors of the lower block. On exit U contains the left singular vectors of the bidiagonal matrix.``` [in] LDU ``` LDU is INTEGER The leading dimension of the array U. LDU >= max( 1, N ).``` [in,out] VT ``` VT is REAL array, dimension (LDVT,M) where M = N + SQRE. On entry VT(1:NL+1, 1:NL+1)**T contains the right singular vectors of the upper block; VT(NL+2:M, NL+2:M)**T contains the right singular vectors of the lower block. On exit VT**T contains the right singular vectors of the bidiagonal matrix.``` [in] LDVT ``` LDVT is INTEGER The leading dimension of the array VT. LDVT >= max( 1, M ).``` [in,out] IDXQ ``` IDXQ is INTEGER array, dimension (N) This contains the permutation which will reintegrate the subproblem just solved back into sorted order, i.e. D( IDXQ( I = 1, N ) ) will be in ascending order.``` [out] IWORK ` IWORK is INTEGER array, dimension (4*N)` [out] WORK ` WORK is REAL array, dimension (3*M**2+2*M)` [out] INFO ``` INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = 1, a singular value did not converge```
Contributors:
Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA

Definition at line 202 of file slasd1.f.

204 *
205 * -- LAPACK auxiliary routine --
206 * -- LAPACK is a software package provided by Univ. of Tennessee, --
207 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
208 *
209 * .. Scalar Arguments ..
210  INTEGER INFO, LDU, LDVT, NL, NR, SQRE
211  REAL ALPHA, BETA
212 * ..
213 * .. Array Arguments ..
214  INTEGER IDXQ( * ), IWORK( * )
215  REAL D( * ), U( LDU, * ), VT( LDVT, * ), WORK( * )
216 * ..
217 *
218 * =====================================================================
219 *
220 * .. Parameters ..
221 *
222  REAL ONE, ZERO
223  parameter( one = 1.0e+0, zero = 0.0e+0 )
224 * ..
225 * .. Local Scalars ..
226  INTEGER COLTYP, I, IDX, IDXC, IDXP, IQ, ISIGMA, IU2,
227  \$ IVT2, IZ, K, LDQ, LDU2, LDVT2, M, N, N1, N2
228  REAL ORGNRM
229 * ..
230 * .. External Subroutines ..
231  EXTERNAL slamrg, slascl, slasd2, slasd3, xerbla
232 * ..
233 * .. Intrinsic Functions ..
234  INTRINSIC abs, max
235 * ..
236 * .. Executable Statements ..
237 *
238 * Test the input parameters.
239 *
240  info = 0
241 *
242  IF( nl.LT.1 ) THEN
243  info = -1
244  ELSE IF( nr.LT.1 ) THEN
245  info = -2
246  ELSE IF( ( sqre.LT.0 ) .OR. ( sqre.GT.1 ) ) THEN
247  info = -3
248  END IF
249  IF( info.NE.0 ) THEN
250  CALL xerbla( 'SLASD1', -info )
251  RETURN
252  END IF
253 *
254  n = nl + nr + 1
255  m = n + sqre
256 *
257 * The following values are for bookkeeping purposes only. They are
258 * integer pointers which indicate the portion of the workspace
259 * used by a particular array in SLASD2 and SLASD3.
260 *
261  ldu2 = n
262  ldvt2 = m
263 *
264  iz = 1
265  isigma = iz + m
266  iu2 = isigma + n
267  ivt2 = iu2 + ldu2*n
268  iq = ivt2 + ldvt2*m
269 *
270  idx = 1
271  idxc = idx + n
272  coltyp = idxc + n
273  idxp = coltyp + n
274 *
275 * Scale.
276 *
277  orgnrm = max( abs( alpha ), abs( beta ) )
278  d( nl+1 ) = zero
279  DO 10 i = 1, n
280  IF( abs( d( i ) ).GT.orgnrm ) THEN
281  orgnrm = abs( d( i ) )
282  END IF
283  10 CONTINUE
284  CALL slascl( 'G', 0, 0, orgnrm, one, n, 1, d, n, info )
285  alpha = alpha / orgnrm
286  beta = beta / orgnrm
287 *
288 * Deflate singular values.
289 *
290  CALL slasd2( nl, nr, sqre, k, d, work( iz ), alpha, beta, u, ldu,
291  \$ vt, ldvt, work( isigma ), work( iu2 ), ldu2,
292  \$ work( ivt2 ), ldvt2, iwork( idxp ), iwork( idx ),
293  \$ iwork( idxc ), idxq, iwork( coltyp ), info )
294 *
295 * Solve Secular Equation and update singular vectors.
296 *
297  ldq = k
298  CALL slasd3( nl, nr, sqre, k, d, work( iq ), ldq, work( isigma ),
299  \$ u, ldu, work( iu2 ), ldu2, vt, ldvt, work( ivt2 ),
300  \$ ldvt2, iwork( idxc ), iwork( coltyp ), work( iz ),
301  \$ info )
302 *
303 * Report the possible convergence failure.
304 *
305  IF( info.NE.0 ) THEN
306  RETURN
307  END IF
308 *
309 * Unscale.
310 *
311  CALL slascl( 'G', 0, 0, one, orgnrm, n, 1, d, n, info )
312 *
313 * Prepare the IDXQ sorting permutation.
314 *
315  n1 = k
316  n2 = n - k
317  CALL slamrg( n1, n2, d, 1, -1, idxq )
318 *
319  RETURN
320 *
321 * End of SLASD1
322 *
subroutine slascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
SLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: slascl.f:143
subroutine slasd2(NL, NR, SQRE, K, D, Z, ALPHA, BETA, U, LDU, VT, LDVT, DSIGMA, U2, LDU2, VT2, LDVT2, IDXP, IDX, IDXC, IDXQ, COLTYP, INFO)
SLASD2 merges the two sets of singular values together into a single sorted set. Used by sbdsdc.
Definition: slasd2.f:269
subroutine slasd3(NL, NR, SQRE, K, D, Q, LDQ, DSIGMA, U, LDU, U2, LDU2, VT, LDVT, VT2, LDVT2, IDXC, CTOT, Z, INFO)
SLASD3 finds all square roots of the roots of the secular equation, as defined by the values in D and...
Definition: slasd3.f:224
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slamrg(N1, N2, A, STRD1, STRD2, INDEX)
SLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition: slamrg.f:99
Here is the call graph for this function:
Here is the caller graph for this function: