LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dlasd3()

subroutine dlasd3 ( integer  NL,
integer  NR,
integer  SQRE,
integer  K,
double precision, dimension( * )  D,
double precision, dimension( ldq, * )  Q,
integer  LDQ,
double precision, dimension( * )  DSIGMA,
double precision, dimension( ldu, * )  U,
integer  LDU,
double precision, dimension( ldu2, * )  U2,
integer  LDU2,
double precision, dimension( ldvt, * )  VT,
integer  LDVT,
double precision, dimension( ldvt2, * )  VT2,
integer  LDVT2,
integer, dimension( * )  IDXC,
integer, dimension( * )  CTOT,
double precision, dimension( * )  Z,
integer  INFO 
)

DLASD3 finds all square roots of the roots of the secular equation, as defined by the values in D and Z, and then updates the singular vectors by matrix multiplication. Used by sbdsdc.

Download DLASD3 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLASD3 finds all the square roots of the roots of the secular
 equation, as defined by the values in D and Z.  It makes the
 appropriate calls to DLASD4 and then updates the singular
 vectors by matrix multiplication.

 This code makes very mild assumptions about floating point
 arithmetic. It will work on machines with a guard digit in
 add/subtract, or on those binary machines without guard digits
 which subtract like the Cray XMP, Cray YMP, Cray C 90, or Cray 2.
 It could conceivably fail on hexadecimal or decimal machines
 without guard digits, but we know of none.

 DLASD3 is called from DLASD1.
Parameters
[in]NL
          NL is INTEGER
         The row dimension of the upper block.  NL >= 1.
[in]NR
          NR is INTEGER
         The row dimension of the lower block.  NR >= 1.
[in]SQRE
          SQRE is INTEGER
         = 0: the lower block is an NR-by-NR square matrix.
         = 1: the lower block is an NR-by-(NR+1) rectangular matrix.

         The bidiagonal matrix has N = NL + NR + 1 rows and
         M = N + SQRE >= N columns.
[in]K
          K is INTEGER
         The size of the secular equation, 1 =< K = < N.
[out]D
          D is DOUBLE PRECISION array, dimension(K)
         On exit the square roots of the roots of the secular equation,
         in ascending order.
[out]Q
          Q is DOUBLE PRECISION array, dimension (LDQ,K)
[in]LDQ
          LDQ is INTEGER
         The leading dimension of the array Q.  LDQ >= K.
[in,out]DSIGMA
          DSIGMA is DOUBLE PRECISION array, dimension(K)
         The first K elements of this array contain the old roots
         of the deflated updating problem.  These are the poles
         of the secular equation.
[out]U
          U is DOUBLE PRECISION array, dimension (LDU, N)
         The last N - K columns of this matrix contain the deflated
         left singular vectors.
[in]LDU
          LDU is INTEGER
         The leading dimension of the array U.  LDU >= N.
[in]U2
          U2 is DOUBLE PRECISION array, dimension (LDU2, N)
         The first K columns of this matrix contain the non-deflated
         left singular vectors for the split problem.
[in]LDU2
          LDU2 is INTEGER
         The leading dimension of the array U2.  LDU2 >= N.
[out]VT
          VT is DOUBLE PRECISION array, dimension (LDVT, M)
         The last M - K columns of VT**T contain the deflated
         right singular vectors.
[in]LDVT
          LDVT is INTEGER
         The leading dimension of the array VT.  LDVT >= N.
[in,out]VT2
          VT2 is DOUBLE PRECISION array, dimension (LDVT2, N)
         The first K columns of VT2**T contain the non-deflated
         right singular vectors for the split problem.
[in]LDVT2
          LDVT2 is INTEGER
         The leading dimension of the array VT2.  LDVT2 >= N.
[in]IDXC
          IDXC is INTEGER array, dimension ( N )
         The permutation used to arrange the columns of U (and rows of
         VT) into three groups:  the first group contains non-zero
         entries only at and above (or before) NL +1; the second
         contains non-zero entries only at and below (or after) NL+2;
         and the third is dense. The first column of U and the row of
         VT are treated separately, however.

         The rows of the singular vectors found by DLASD4
         must be likewise permuted before the matrix multiplies can
         take place.
[in]CTOT
          CTOT is INTEGER array, dimension ( 4 )
         A count of the total number of the various types of columns
         in U (or rows in VT), as described in IDXC. The fourth column
         type is any column which has been deflated.
[in,out]Z
          Z is DOUBLE PRECISION array, dimension (K)
         The first K elements of this array contain the components
         of the deflation-adjusted updating row vector.
[out]INFO
          INFO is INTEGER
         = 0:  successful exit.
         < 0:  if INFO = -i, the i-th argument had an illegal value.
         > 0:  if INFO = 1, a singular value did not converge
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2017
Contributors:
Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA

Definition at line 226 of file dlasd3.f.

226 *
227 * -- LAPACK auxiliary routine (version 3.7.1) --
228 * -- LAPACK is a software package provided by Univ. of Tennessee, --
229 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
230 * June 2017
231 *
232 * .. Scalar Arguments ..
233  INTEGER info, k, ldq, ldu, ldu2, ldvt, ldvt2, nl, nr,
234  $ sqre
235 * ..
236 * .. Array Arguments ..
237  INTEGER ctot( * ), idxc( * )
238  DOUBLE PRECISION d( * ), dsigma( * ), q( ldq, * ), u( ldu, * ),
239  $ u2( ldu2, * ), vt( ldvt, * ), vt2( ldvt2, * ),
240  $ z( * )
241 * ..
242 *
243 * =====================================================================
244 *
245 * .. Parameters ..
246  DOUBLE PRECISION one, zero, negone
247  parameter( one = 1.0d+0, zero = 0.0d+0,
248  $ negone = -1.0d+0 )
249 * ..
250 * .. Local Scalars ..
251  INTEGER ctemp, i, j, jc, ktemp, m, n, nlp1, nlp2, nrp1
252  DOUBLE PRECISION rho, temp
253 * ..
254 * .. External Functions ..
255  DOUBLE PRECISION dlamc3, dnrm2
256  EXTERNAL dlamc3, dnrm2
257 * ..
258 * .. External Subroutines ..
259  EXTERNAL dcopy, dgemm, dlacpy, dlascl, dlasd4, xerbla
260 * ..
261 * .. Intrinsic Functions ..
262  INTRINSIC abs, sign, sqrt
263 * ..
264 * .. Executable Statements ..
265 *
266 * Test the input parameters.
267 *
268  info = 0
269 *
270  IF( nl.LT.1 ) THEN
271  info = -1
272  ELSE IF( nr.LT.1 ) THEN
273  info = -2
274  ELSE IF( ( sqre.NE.1 ) .AND. ( sqre.NE.0 ) ) THEN
275  info = -3
276  END IF
277 *
278  n = nl + nr + 1
279  m = n + sqre
280  nlp1 = nl + 1
281  nlp2 = nl + 2
282 *
283  IF( ( k.LT.1 ) .OR. ( k.GT.n ) ) THEN
284  info = -4
285  ELSE IF( ldq.LT.k ) THEN
286  info = -7
287  ELSE IF( ldu.LT.n ) THEN
288  info = -10
289  ELSE IF( ldu2.LT.n ) THEN
290  info = -12
291  ELSE IF( ldvt.LT.m ) THEN
292  info = -14
293  ELSE IF( ldvt2.LT.m ) THEN
294  info = -16
295  END IF
296  IF( info.NE.0 ) THEN
297  CALL xerbla( 'DLASD3', -info )
298  RETURN
299  END IF
300 *
301 * Quick return if possible
302 *
303  IF( k.EQ.1 ) THEN
304  d( 1 ) = abs( z( 1 ) )
305  CALL dcopy( m, vt2( 1, 1 ), ldvt2, vt( 1, 1 ), ldvt )
306  IF( z( 1 ).GT.zero ) THEN
307  CALL dcopy( n, u2( 1, 1 ), 1, u( 1, 1 ), 1 )
308  ELSE
309  DO 10 i = 1, n
310  u( i, 1 ) = -u2( i, 1 )
311  10 CONTINUE
312  END IF
313  RETURN
314  END IF
315 *
316 * Modify values DSIGMA(i) to make sure all DSIGMA(i)-DSIGMA(j) can
317 * be computed with high relative accuracy (barring over/underflow).
318 * This is a problem on machines without a guard digit in
319 * add/subtract (Cray XMP, Cray YMP, Cray C 90 and Cray 2).
320 * The following code replaces DSIGMA(I) by 2*DSIGMA(I)-DSIGMA(I),
321 * which on any of these machines zeros out the bottommost
322 * bit of DSIGMA(I) if it is 1; this makes the subsequent
323 * subtractions DSIGMA(I)-DSIGMA(J) unproblematic when cancellation
324 * occurs. On binary machines with a guard digit (almost all
325 * machines) it does not change DSIGMA(I) at all. On hexadecimal
326 * and decimal machines with a guard digit, it slightly
327 * changes the bottommost bits of DSIGMA(I). It does not account
328 * for hexadecimal or decimal machines without guard digits
329 * (we know of none). We use a subroutine call to compute
330 * 2*DSIGMA(I) to prevent optimizing compilers from eliminating
331 * this code.
332 *
333  DO 20 i = 1, k
334  dsigma( i ) = dlamc3( dsigma( i ), dsigma( i ) ) - dsigma( i )
335  20 CONTINUE
336 *
337 * Keep a copy of Z.
338 *
339  CALL dcopy( k, z, 1, q, 1 )
340 *
341 * Normalize Z.
342 *
343  rho = dnrm2( k, z, 1 )
344  CALL dlascl( 'G', 0, 0, rho, one, k, 1, z, k, info )
345  rho = rho*rho
346 *
347 * Find the new singular values.
348 *
349  DO 30 j = 1, k
350  CALL dlasd4( k, j, dsigma, z, u( 1, j ), rho, d( j ),
351  $ vt( 1, j ), info )
352 *
353 * If the zero finder fails, report the convergence failure.
354 *
355  IF( info.NE.0 ) THEN
356  RETURN
357  END IF
358  30 CONTINUE
359 *
360 * Compute updated Z.
361 *
362  DO 60 i = 1, k
363  z( i ) = u( i, k )*vt( i, k )
364  DO 40 j = 1, i - 1
365  z( i ) = z( i )*( u( i, j )*vt( i, j ) /
366  $ ( dsigma( i )-dsigma( j ) ) /
367  $ ( dsigma( i )+dsigma( j ) ) )
368  40 CONTINUE
369  DO 50 j = i, k - 1
370  z( i ) = z( i )*( u( i, j )*vt( i, j ) /
371  $ ( dsigma( i )-dsigma( j+1 ) ) /
372  $ ( dsigma( i )+dsigma( j+1 ) ) )
373  50 CONTINUE
374  z( i ) = sign( sqrt( abs( z( i ) ) ), q( i, 1 ) )
375  60 CONTINUE
376 *
377 * Compute left singular vectors of the modified diagonal matrix,
378 * and store related information for the right singular vectors.
379 *
380  DO 90 i = 1, k
381  vt( 1, i ) = z( 1 ) / u( 1, i ) / vt( 1, i )
382  u( 1, i ) = negone
383  DO 70 j = 2, k
384  vt( j, i ) = z( j ) / u( j, i ) / vt( j, i )
385  u( j, i ) = dsigma( j )*vt( j, i )
386  70 CONTINUE
387  temp = dnrm2( k, u( 1, i ), 1 )
388  q( 1, i ) = u( 1, i ) / temp
389  DO 80 j = 2, k
390  jc = idxc( j )
391  q( j, i ) = u( jc, i ) / temp
392  80 CONTINUE
393  90 CONTINUE
394 *
395 * Update the left singular vector matrix.
396 *
397  IF( k.EQ.2 ) THEN
398  CALL dgemm( 'N', 'N', n, k, k, one, u2, ldu2, q, ldq, zero, u,
399  $ ldu )
400  GO TO 100
401  END IF
402  IF( ctot( 1 ).GT.0 ) THEN
403  CALL dgemm( 'N', 'N', nl, k, ctot( 1 ), one, u2( 1, 2 ), ldu2,
404  $ q( 2, 1 ), ldq, zero, u( 1, 1 ), ldu )
405  IF( ctot( 3 ).GT.0 ) THEN
406  ktemp = 2 + ctot( 1 ) + ctot( 2 )
407  CALL dgemm( 'N', 'N', nl, k, ctot( 3 ), one, u2( 1, ktemp ),
408  $ ldu2, q( ktemp, 1 ), ldq, one, u( 1, 1 ), ldu )
409  END IF
410  ELSE IF( ctot( 3 ).GT.0 ) THEN
411  ktemp = 2 + ctot( 1 ) + ctot( 2 )
412  CALL dgemm( 'N', 'N', nl, k, ctot( 3 ), one, u2( 1, ktemp ),
413  $ ldu2, q( ktemp, 1 ), ldq, zero, u( 1, 1 ), ldu )
414  ELSE
415  CALL dlacpy( 'F', nl, k, u2, ldu2, u, ldu )
416  END IF
417  CALL dcopy( k, q( 1, 1 ), ldq, u( nlp1, 1 ), ldu )
418  ktemp = 2 + ctot( 1 )
419  ctemp = ctot( 2 ) + ctot( 3 )
420  CALL dgemm( 'N', 'N', nr, k, ctemp, one, u2( nlp2, ktemp ), ldu2,
421  $ q( ktemp, 1 ), ldq, zero, u( nlp2, 1 ), ldu )
422 *
423 * Generate the right singular vectors.
424 *
425  100 CONTINUE
426  DO 120 i = 1, k
427  temp = dnrm2( k, vt( 1, i ), 1 )
428  q( i, 1 ) = vt( 1, i ) / temp
429  DO 110 j = 2, k
430  jc = idxc( j )
431  q( i, j ) = vt( jc, i ) / temp
432  110 CONTINUE
433  120 CONTINUE
434 *
435 * Update the right singular vector matrix.
436 *
437  IF( k.EQ.2 ) THEN
438  CALL dgemm( 'N', 'N', k, m, k, one, q, ldq, vt2, ldvt2, zero,
439  $ vt, ldvt )
440  RETURN
441  END IF
442  ktemp = 1 + ctot( 1 )
443  CALL dgemm( 'N', 'N', k, nlp1, ktemp, one, q( 1, 1 ), ldq,
444  $ vt2( 1, 1 ), ldvt2, zero, vt( 1, 1 ), ldvt )
445  ktemp = 2 + ctot( 1 ) + ctot( 2 )
446  IF( ktemp.LE.ldvt2 )
447  $ CALL dgemm( 'N', 'N', k, nlp1, ctot( 3 ), one, q( 1, ktemp ),
448  $ ldq, vt2( ktemp, 1 ), ldvt2, one, vt( 1, 1 ),
449  $ ldvt )
450 *
451  ktemp = ctot( 1 ) + 1
452  nrp1 = nr + sqre
453  IF( ktemp.GT.1 ) THEN
454  DO 130 i = 1, k
455  q( i, ktemp ) = q( i, 1 )
456  130 CONTINUE
457  DO 140 i = nlp2, m
458  vt2( ktemp, i ) = vt2( 1, i )
459  140 CONTINUE
460  END IF
461  ctemp = 1 + ctot( 2 ) + ctot( 3 )
462  CALL dgemm( 'N', 'N', k, nrp1, ctemp, one, q( 1, ktemp ), ldq,
463  $ vt2( ktemp, nlp2 ), ldvt2, zero, vt( 1, nlp2 ), ldvt )
464 *
465  RETURN
466 *
467 * End of DLASD3
468 *
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:105
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:84
subroutine dlasd4(N, I, D, Z, DELTA, RHO, SIGMA, WORK, INFO)
DLASD4 computes the square root of the i-th updated eigenvalue of a positive symmetric rank-one modif...
Definition: dlasd4.f:155
subroutine dlascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
DLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: dlascl.f:145
subroutine dgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DGEMM
Definition: dgemm.f:189
double precision function dlamc3(A, B)
DLAMC3
Definition: dlamch.f:169
double precision function dnrm2(N, X, INCX)
DNRM2
Definition: dnrm2.f:76
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
Here is the call graph for this function:
Here is the caller graph for this function: