LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dlanst()

double precision function dlanst ( character  NORM,
integer  N,
double precision, dimension( * )  D,
double precision, dimension( * )  E 
)

DLANST returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric tridiagonal matrix.

Download DLANST + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLANST  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 real symmetric tridiagonal matrix A.
Returns
DLANST
    DLANST = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in DLANST as described
          above.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, DLANST is
          set to zero.
[in]D
          D is DOUBLE PRECISION array, dimension (N)
          The diagonal elements of A.
[in]E
          E is DOUBLE PRECISION array, dimension (N-1)
          The (n-1) sub-diagonal or super-diagonal elements of A.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 102 of file dlanst.f.

102 *
103 * -- LAPACK auxiliary routine (version 3.7.0) --
104 * -- LAPACK is a software package provided by Univ. of Tennessee, --
105 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
106 * December 2016
107 *
108 * .. Scalar Arguments ..
109  CHARACTER norm
110  INTEGER n
111 * ..
112 * .. Array Arguments ..
113  DOUBLE PRECISION d( * ), e( * )
114 * ..
115 *
116 * =====================================================================
117 *
118 * .. Parameters ..
119  DOUBLE PRECISION one, zero
120  parameter( one = 1.0d+0, zero = 0.0d+0 )
121 * ..
122 * .. Local Scalars ..
123  INTEGER i
124  DOUBLE PRECISION anorm, scale, sum
125 * ..
126 * .. External Functions ..
127  LOGICAL lsame, disnan
128  EXTERNAL lsame, disnan
129 * ..
130 * .. External Subroutines ..
131  EXTERNAL dlassq
132 * ..
133 * .. Intrinsic Functions ..
134  INTRINSIC abs, sqrt
135 * ..
136 * .. Executable Statements ..
137 *
138  IF( n.LE.0 ) THEN
139  anorm = zero
140  ELSE IF( lsame( norm, 'M' ) ) THEN
141 *
142 * Find max(abs(A(i,j))).
143 *
144  anorm = abs( d( n ) )
145  DO 10 i = 1, n - 1
146  sum = abs( d( i ) )
147  IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
148  sum = abs( e( i ) )
149  IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
150  10 CONTINUE
151  ELSE IF( lsame( norm, 'O' ) .OR. norm.EQ.'1' .OR.
152  $ lsame( norm, 'I' ) ) THEN
153 *
154 * Find norm1(A).
155 *
156  IF( n.EQ.1 ) THEN
157  anorm = abs( d( 1 ) )
158  ELSE
159  anorm = abs( d( 1 ) )+abs( e( 1 ) )
160  sum = abs( e( n-1 ) )+abs( d( n ) )
161  IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
162  DO 20 i = 2, n - 1
163  sum = abs( d( i ) )+abs( e( i ) )+abs( e( i-1 ) )
164  IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
165  20 CONTINUE
166  END IF
167  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
168 *
169 * Find normF(A).
170 *
171  scale = zero
172  sum = one
173  IF( n.GT.1 ) THEN
174  CALL dlassq( n-1, e, 1, scale, sum )
175  sum = 2*sum
176  END IF
177  CALL dlassq( n, d, 1, scale, sum )
178  anorm = scale*sqrt( sum )
179  END IF
180 *
181  dlanst = anorm
182  RETURN
183 *
184 * End of DLANST
185 *
subroutine dlassq(N, X, INCX, SCALE, SUMSQ)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f:105
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:61
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
double precision function dlanst(NORM, N, D, E)
DLANST returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric tridiagonal matrix.
Definition: dlanst.f:102
Here is the call graph for this function: