LAPACK  3.7.0 LAPACK: Linear Algebra PACKage
zgeqr2p.f
Go to the documentation of this file.
1 *> \brief \b ZGEQR2P computes the QR factorization of a general rectangular matrix with non-negative diagonal elements using an unblocked algorithm.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgeqr2p.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgeqr2p.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgeqr2p.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZGEQR2P( M, N, A, LDA, TAU, WORK, INFO )
22 *
23 * .. Scalar Arguments ..
24 * INTEGER INFO, LDA, M, N
25 * ..
26 * .. Array Arguments ..
27 * COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
28 * ..
29 *
30 *
31 *> \par Purpose:
32 * =============
33 *>
34 *> \verbatim
35 *>
36 *> ZGEQR2P computes a QR factorization of a complex m by n matrix A:
37 *> A = Q * R. The diagonal entries of R are real and nonnegative.
38 *> \endverbatim
39 *
40 * Arguments:
41 * ==========
42 *
43 *> \param[in] M
44 *> \verbatim
45 *> M is INTEGER
46 *> The number of rows of the matrix A. M >= 0.
47 *> \endverbatim
48 *>
49 *> \param[in] N
50 *> \verbatim
51 *> N is INTEGER
52 *> The number of columns of the matrix A. N >= 0.
53 *> \endverbatim
54 *>
55 *> \param[in,out] A
56 *> \verbatim
57 *> A is COMPLEX*16 array, dimension (LDA,N)
58 *> On entry, the m by n matrix A.
59 *> On exit, the elements on and above the diagonal of the array
60 *> contain the min(m,n) by n upper trapezoidal matrix R (R is
61 *> upper triangular if m >= n). The diagonal entries of R
62 *> are real and nonnegative; the elements below the diagonal,
63 *> with the array TAU, represent the unitary matrix Q as a
64 *> product of elementary reflectors (see Further Details).
65 *> \endverbatim
66 *>
67 *> \param[in] LDA
68 *> \verbatim
69 *> LDA is INTEGER
70 *> The leading dimension of the array A. LDA >= max(1,M).
71 *> \endverbatim
72 *>
73 *> \param[out] TAU
74 *> \verbatim
75 *> TAU is COMPLEX*16 array, dimension (min(M,N))
76 *> The scalar factors of the elementary reflectors (see Further
77 *> Details).
78 *> \endverbatim
79 *>
80 *> \param[out] WORK
81 *> \verbatim
82 *> WORK is COMPLEX*16 array, dimension (N)
83 *> \endverbatim
84 *>
85 *> \param[out] INFO
86 *> \verbatim
87 *> INFO is INTEGER
88 *> = 0: successful exit
89 *> < 0: if INFO = -i, the i-th argument had an illegal value
90 *> \endverbatim
91 *
92 * Authors:
93 * ========
94 *
95 *> \author Univ. of Tennessee
96 *> \author Univ. of California Berkeley
97 *> \author Univ. of Colorado Denver
98 *> \author NAG Ltd.
99 *
100 *> \date December 2016
101 *
102 *> \ingroup complex16GEcomputational
103 *
104 *> \par Further Details:
105 * =====================
106 *>
107 *> \verbatim
108 *>
109 *> The matrix Q is represented as a product of elementary reflectors
110 *>
111 *> Q = H(1) H(2) . . . H(k), where k = min(m,n).
112 *>
113 *> Each H(i) has the form
114 *>
115 *> H(i) = I - tau * v * v**H
116 *>
117 *> where tau is a complex scalar, and v is a complex vector with
118 *> v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i),
119 *> and tau in TAU(i).
120 *>
121 *> See Lapack Working Note 203 for details
122 *> \endverbatim
123 *>
124 * =====================================================================
125  SUBROUTINE zgeqr2p( M, N, A, LDA, TAU, WORK, INFO )
126 *
127 * -- LAPACK computational routine (version 3.7.0) --
128 * -- LAPACK is a software package provided by Univ. of Tennessee, --
129 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130 * December 2016
131 *
132 * .. Scalar Arguments ..
133  INTEGER INFO, LDA, M, N
134 * ..
135 * .. Array Arguments ..
136  COMPLEX*16 A( lda, * ), TAU( * ), WORK( * )
137 * ..
138 *
139 * =====================================================================
140 *
141 * .. Parameters ..
142  COMPLEX*16 ONE
143  parameter ( one = ( 1.0d+0, 0.0d+0 ) )
144 * ..
145 * .. Local Scalars ..
146  INTEGER I, K
147  COMPLEX*16 ALPHA
148 * ..
149 * .. External Subroutines ..
150  EXTERNAL xerbla, zlarf, zlarfgp
151 * ..
152 * .. Intrinsic Functions ..
153  INTRINSIC dconjg, max, min
154 * ..
155 * .. Executable Statements ..
156 *
157 * Test the input arguments
158 *
159  info = 0
160  IF( m.LT.0 ) THEN
161  info = -1
162  ELSE IF( n.LT.0 ) THEN
163  info = -2
164  ELSE IF( lda.LT.max( 1, m ) ) THEN
165  info = -4
166  END IF
167  IF( info.NE.0 ) THEN
168  CALL xerbla( 'ZGEQR2P', -info )
169  RETURN
170  END IF
171 *
172  k = min( m, n )
173 *
174  DO 10 i = 1, k
175 *
176 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
177 *
178  CALL zlarfgp( m-i+1, a( i, i ), a( min( i+1, m ), i ), 1,
179  \$ tau( i ) )
180  IF( i.LT.n ) THEN
181 *
182 * Apply H(i)**H to A(i:m,i+1:n) from the left
183 *
184  alpha = a( i, i )
185  a( i, i ) = one
186  CALL zlarf( 'Left', m-i+1, n-i, a( i, i ), 1,
187  \$ dconjg( tau( i ) ), a( i, i+1 ), lda, work )
188  a( i, i ) = alpha
189  END IF
190  10 CONTINUE
191  RETURN
192 *
193 * End of ZGEQR2P
194 *
195  END
subroutine zlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
ZLARF applies an elementary reflector to a general rectangular matrix.
Definition: zlarf.f:130
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zlarfgp(N, ALPHA, X, INCX, TAU)
ZLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: zlarfgp.f:106
subroutine zgeqr2p(M, N, A, LDA, TAU, WORK, INFO)
ZGEQR2P computes the QR factorization of a general rectangular matrix with non-negative diagonal elem...
Definition: zgeqr2p.f:126