LAPACK  3.8.0
LAPACK: Linear Algebra PACKage
dspgv.f
Go to the documentation of this file.
1 *> \brief \b DSPGV
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DSPGV + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dspgv.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dspgv.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dspgv.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DSPGV( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
22 * INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER JOBZ, UPLO
26 * INTEGER INFO, ITYPE, LDZ, N
27 * ..
28 * .. Array Arguments ..
29 * DOUBLE PRECISION AP( * ), BP( * ), W( * ), WORK( * ),
30 * $ Z( LDZ, * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> DSPGV computes all the eigenvalues and, optionally, the eigenvectors
40 *> of a real generalized symmetric-definite eigenproblem, of the form
41 *> A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x.
42 *> Here A and B are assumed to be symmetric, stored in packed format,
43 *> and B is also positive definite.
44 *> \endverbatim
45 *
46 * Arguments:
47 * ==========
48 *
49 *> \param[in] ITYPE
50 *> \verbatim
51 *> ITYPE is INTEGER
52 *> Specifies the problem type to be solved:
53 *> = 1: A*x = (lambda)*B*x
54 *> = 2: A*B*x = (lambda)*x
55 *> = 3: B*A*x = (lambda)*x
56 *> \endverbatim
57 *>
58 *> \param[in] JOBZ
59 *> \verbatim
60 *> JOBZ is CHARACTER*1
61 *> = 'N': Compute eigenvalues only;
62 *> = 'V': Compute eigenvalues and eigenvectors.
63 *> \endverbatim
64 *>
65 *> \param[in] UPLO
66 *> \verbatim
67 *> UPLO is CHARACTER*1
68 *> = 'U': Upper triangles of A and B are stored;
69 *> = 'L': Lower triangles of A and B are stored.
70 *> \endverbatim
71 *>
72 *> \param[in] N
73 *> \verbatim
74 *> N is INTEGER
75 *> The order of the matrices A and B. N >= 0.
76 *> \endverbatim
77 *>
78 *> \param[in,out] AP
79 *> \verbatim
80 *> AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
81 *> On entry, the upper or lower triangle of the symmetric matrix
82 *> A, packed columnwise in a linear array. The j-th column of A
83 *> is stored in the array AP as follows:
84 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
85 *> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
86 *>
87 *> On exit, the contents of AP are destroyed.
88 *> \endverbatim
89 *>
90 *> \param[in,out] BP
91 *> \verbatim
92 *> BP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
93 *> On entry, the upper or lower triangle of the symmetric matrix
94 *> B, packed columnwise in a linear array. The j-th column of B
95 *> is stored in the array BP as follows:
96 *> if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
97 *> if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
98 *>
99 *> On exit, the triangular factor U or L from the Cholesky
100 *> factorization B = U**T*U or B = L*L**T, in the same storage
101 *> format as B.
102 *> \endverbatim
103 *>
104 *> \param[out] W
105 *> \verbatim
106 *> W is DOUBLE PRECISION array, dimension (N)
107 *> If INFO = 0, the eigenvalues in ascending order.
108 *> \endverbatim
109 *>
110 *> \param[out] Z
111 *> \verbatim
112 *> Z is DOUBLE PRECISION array, dimension (LDZ, N)
113 *> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
114 *> eigenvectors. The eigenvectors are normalized as follows:
115 *> if ITYPE = 1 or 2, Z**T*B*Z = I;
116 *> if ITYPE = 3, Z**T*inv(B)*Z = I.
117 *> If JOBZ = 'N', then Z is not referenced.
118 *> \endverbatim
119 *>
120 *> \param[in] LDZ
121 *> \verbatim
122 *> LDZ is INTEGER
123 *> The leading dimension of the array Z. LDZ >= 1, and if
124 *> JOBZ = 'V', LDZ >= max(1,N).
125 *> \endverbatim
126 *>
127 *> \param[out] WORK
128 *> \verbatim
129 *> WORK is DOUBLE PRECISION array, dimension (3*N)
130 *> \endverbatim
131 *>
132 *> \param[out] INFO
133 *> \verbatim
134 *> INFO is INTEGER
135 *> = 0: successful exit
136 *> < 0: if INFO = -i, the i-th argument had an illegal value
137 *> > 0: DPPTRF or DSPEV returned an error code:
138 *> <= N: if INFO = i, DSPEV failed to converge;
139 *> i off-diagonal elements of an intermediate
140 *> tridiagonal form did not converge to zero.
141 *> > N: if INFO = n + i, for 1 <= i <= n, then the leading
142 *> minor of order i of B is not positive definite.
143 *> The factorization of B could not be completed and
144 *> no eigenvalues or eigenvectors were computed.
145 *> \endverbatim
146 *
147 * Authors:
148 * ========
149 *
150 *> \author Univ. of Tennessee
151 *> \author Univ. of California Berkeley
152 *> \author Univ. of Colorado Denver
153 *> \author NAG Ltd.
154 *
155 *> \date June 2017
156 *
157 *> \ingroup doubleOTHEReigen
158 *
159 * =====================================================================
160  SUBROUTINE dspgv( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
161  $ INFO )
162 *
163 * -- LAPACK driver routine (version 3.7.1) --
164 * -- LAPACK is a software package provided by Univ. of Tennessee, --
165 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
166 * June 2017
167 *
168 * .. Scalar Arguments ..
169  CHARACTER JOBZ, UPLO
170  INTEGER INFO, ITYPE, LDZ, N
171 * ..
172 * .. Array Arguments ..
173  DOUBLE PRECISION AP( * ), BP( * ), W( * ), WORK( * ),
174  $ z( ldz, * )
175 * ..
176 *
177 * =====================================================================
178 *
179 * .. Local Scalars ..
180  LOGICAL UPPER, WANTZ
181  CHARACTER TRANS
182  INTEGER J, NEIG
183 * ..
184 * .. External Functions ..
185  LOGICAL LSAME
186  EXTERNAL lsame
187 * ..
188 * .. External Subroutines ..
189  EXTERNAL dpptrf, dspev, dspgst, dtpmv, dtpsv, xerbla
190 * ..
191 * .. Executable Statements ..
192 *
193 * Test the input parameters.
194 *
195  wantz = lsame( jobz, 'V' )
196  upper = lsame( uplo, 'U' )
197 *
198  info = 0
199  IF( itype.LT.1 .OR. itype.GT.3 ) THEN
200  info = -1
201  ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
202  info = -2
203  ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
204  info = -3
205  ELSE IF( n.LT.0 ) THEN
206  info = -4
207  ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
208  info = -9
209  END IF
210  IF( info.NE.0 ) THEN
211  CALL xerbla( 'DSPGV ', -info )
212  RETURN
213  END IF
214 *
215 * Quick return if possible
216 *
217  IF( n.EQ.0 )
218  $ RETURN
219 *
220 * Form a Cholesky factorization of B.
221 *
222  CALL dpptrf( uplo, n, bp, info )
223  IF( info.NE.0 ) THEN
224  info = n + info
225  RETURN
226  END IF
227 *
228 * Transform problem to standard eigenvalue problem and solve.
229 *
230  CALL dspgst( itype, uplo, n, ap, bp, info )
231  CALL dspev( jobz, uplo, n, ap, w, z, ldz, work, info )
232 *
233  IF( wantz ) THEN
234 *
235 * Backtransform eigenvectors to the original problem.
236 *
237  neig = n
238  IF( info.GT.0 )
239  $ neig = info - 1
240  IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
241 *
242 * For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
243 * backtransform eigenvectors: x = inv(L)**T*y or inv(U)*y
244 *
245  IF( upper ) THEN
246  trans = 'N'
247  ELSE
248  trans = 'T'
249  END IF
250 *
251  DO 10 j = 1, neig
252  CALL dtpsv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
253  $ 1 )
254  10 CONTINUE
255 *
256  ELSE IF( itype.EQ.3 ) THEN
257 *
258 * For B*A*x=(lambda)*x;
259 * backtransform eigenvectors: x = L*y or U**T*y
260 *
261  IF( upper ) THEN
262  trans = 'T'
263  ELSE
264  trans = 'N'
265  END IF
266 *
267  DO 20 j = 1, neig
268  CALL dtpmv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
269  $ 1 )
270  20 CONTINUE
271  END IF
272  END IF
273  RETURN
274 *
275 * End of DSPGV
276 *
277  END
subroutine dspgst(ITYPE, UPLO, N, AP, BP, INFO)
DSPGST
Definition: dspgst.f:115
subroutine dtpsv(UPLO, TRANS, DIAG, N, AP, X, INCX)
DTPSV
Definition: dtpsv.f:146
subroutine dpptrf(UPLO, N, AP, INFO)
DPPTRF
Definition: dpptrf.f:121
subroutine dspgv(ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK, INFO)
DSPGV
Definition: dspgv.f:162
subroutine dtpmv(UPLO, TRANS, DIAG, N, AP, X, INCX)
DTPMV
Definition: dtpmv.f:144
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dspev(JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, INFO)
DSPEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrice...
Definition: dspev.f:132