LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zpteqr()

subroutine zpteqr ( character  COMPZ,
integer  N,
double precision, dimension( * )  D,
double precision, dimension( * )  E,
complex*16, dimension( ldz, * )  Z,
integer  LDZ,
double precision, dimension( * )  WORK,
integer  INFO 
)

ZPTEQR

Download ZPTEQR + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZPTEQR computes all eigenvalues and, optionally, eigenvectors of a
 symmetric positive definite tridiagonal matrix by first factoring the
 matrix using DPTTRF and then calling ZBDSQR to compute the singular
 values of the bidiagonal factor.

 This routine computes the eigenvalues of the positive definite
 tridiagonal matrix to high relative accuracy.  This means that if the
 eigenvalues range over many orders of magnitude in size, then the
 small eigenvalues and corresponding eigenvectors will be computed
 more accurately than, for example, with the standard QR method.

 The eigenvectors of a full or band positive definite Hermitian matrix
 can also be found if ZHETRD, ZHPTRD, or ZHBTRD has been used to
 reduce this matrix to tridiagonal form.  (The reduction to
 tridiagonal form, however, may preclude the possibility of obtaining
 high relative accuracy in the small eigenvalues of the original
 matrix, if these eigenvalues range over many orders of magnitude.)
Parameters
[in]COMPZ
          COMPZ is CHARACTER*1
          = 'N':  Compute eigenvalues only.
          = 'V':  Compute eigenvectors of original Hermitian
                  matrix also.  Array Z contains the unitary matrix
                  used to reduce the original matrix to tridiagonal
                  form.
          = 'I':  Compute eigenvectors of tridiagonal matrix also.
[in]N
          N is INTEGER
          The order of the matrix.  N >= 0.
[in,out]D
          D is DOUBLE PRECISION array, dimension (N)
          On entry, the n diagonal elements of the tridiagonal matrix.
          On normal exit, D contains the eigenvalues, in descending
          order.
[in,out]E
          E is DOUBLE PRECISION array, dimension (N-1)
          On entry, the (n-1) subdiagonal elements of the tridiagonal
          matrix.
          On exit, E has been destroyed.
[in,out]Z
          Z is COMPLEX*16 array, dimension (LDZ, N)
          On entry, if COMPZ = 'V', the unitary matrix used in the
          reduction to tridiagonal form.
          On exit, if COMPZ = 'V', the orthonormal eigenvectors of the
          original Hermitian matrix;
          if COMPZ = 'I', the orthonormal eigenvectors of the
          tridiagonal matrix.
          If INFO > 0 on exit, Z contains the eigenvectors associated
          with only the stored eigenvalues.
          If  COMPZ = 'N', then Z is not referenced.
[in]LDZ
          LDZ is INTEGER
          The leading dimension of the array Z.  LDZ >= 1, and if
          COMPZ = 'V' or 'I', LDZ >= max(1,N).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (4*N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit.
          < 0:  if INFO = -i, the i-th argument had an illegal value.
          > 0:  if INFO = i, and i is:
                <= N  the Cholesky factorization of the matrix could
                      not be performed because the i-th principal minor
                      was not positive definite.
                > N   the SVD algorithm failed to converge;
                      if INFO = N+i, i off-diagonal elements of the
                      bidiagonal factor did not converge to zero.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 147 of file zpteqr.f.

147 *
148 * -- LAPACK computational routine (version 3.7.0) --
149 * -- LAPACK is a software package provided by Univ. of Tennessee, --
150 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
151 * December 2016
152 *
153 * .. Scalar Arguments ..
154  CHARACTER compz
155  INTEGER info, ldz, n
156 * ..
157 * .. Array Arguments ..
158  DOUBLE PRECISION d( * ), e( * ), work( * )
159  COMPLEX*16 z( ldz, * )
160 * ..
161 *
162 * ====================================================================
163 *
164 * .. Parameters ..
165  COMPLEX*16 czero, cone
166  parameter( czero = ( 0.0d+0, 0.0d+0 ),
167  $ cone = ( 1.0d+0, 0.0d+0 ) )
168 * ..
169 * .. External Functions ..
170  LOGICAL lsame
171  EXTERNAL lsame
172 * ..
173 * .. External Subroutines ..
174  EXTERNAL dpttrf, xerbla, zbdsqr, zlaset
175 * ..
176 * .. Local Arrays ..
177  COMPLEX*16 c( 1, 1 ), vt( 1, 1 )
178 * ..
179 * .. Local Scalars ..
180  INTEGER i, icompz, nru
181 * ..
182 * .. Intrinsic Functions ..
183  INTRINSIC max, sqrt
184 * ..
185 * .. Executable Statements ..
186 *
187 * Test the input parameters.
188 *
189  info = 0
190 *
191  IF( lsame( compz, 'N' ) ) THEN
192  icompz = 0
193  ELSE IF( lsame( compz, 'V' ) ) THEN
194  icompz = 1
195  ELSE IF( lsame( compz, 'I' ) ) THEN
196  icompz = 2
197  ELSE
198  icompz = -1
199  END IF
200  IF( icompz.LT.0 ) THEN
201  info = -1
202  ELSE IF( n.LT.0 ) THEN
203  info = -2
204  ELSE IF( ( ldz.LT.1 ) .OR. ( icompz.GT.0 .AND. ldz.LT.max( 1,
205  $ n ) ) ) THEN
206  info = -6
207  END IF
208  IF( info.NE.0 ) THEN
209  CALL xerbla( 'ZPTEQR', -info )
210  RETURN
211  END IF
212 *
213 * Quick return if possible
214 *
215  IF( n.EQ.0 )
216  $ RETURN
217 *
218  IF( n.EQ.1 ) THEN
219  IF( icompz.GT.0 )
220  $ z( 1, 1 ) = cone
221  RETURN
222  END IF
223  IF( icompz.EQ.2 )
224  $ CALL zlaset( 'Full', n, n, czero, cone, z, ldz )
225 *
226 * Call DPTTRF to factor the matrix.
227 *
228  CALL dpttrf( n, d, e, info )
229  IF( info.NE.0 )
230  $ RETURN
231  DO 10 i = 1, n
232  d( i ) = sqrt( d( i ) )
233  10 CONTINUE
234  DO 20 i = 1, n - 1
235  e( i ) = e( i )*d( i )
236  20 CONTINUE
237 *
238 * Call ZBDSQR to compute the singular values/vectors of the
239 * bidiagonal factor.
240 *
241  IF( icompz.GT.0 ) THEN
242  nru = n
243  ELSE
244  nru = 0
245  END IF
246  CALL zbdsqr( 'Lower', n, 0, nru, 0, d, e, vt, 1, z, ldz, c, 1,
247  $ work, info )
248 *
249 * Square the singular values.
250 *
251  IF( info.EQ.0 ) THEN
252  DO 30 i = 1, n
253  d( i ) = d( i )*d( i )
254  30 CONTINUE
255  ELSE
256  info = n + info
257  END IF
258 *
259  RETURN
260 *
261 * End of ZPTEQR
262 *
subroutine zbdsqr(UPLO, N, NCVT, NRU, NCC, D, E, VT, LDVT, U, LDU, C, LDC, RWORK, INFO)
ZBDSQR
Definition: zbdsqr.f:224
subroutine dpttrf(N, D, E, INFO)
DPTTRF
Definition: dpttrf.f:93
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: zlaset.f:108
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
Here is the call graph for this function:
Here is the caller graph for this function: