LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
cgges.f
Go to the documentation of this file.
1*> \brief <b> CGGES computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices</b>
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download CGGES + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cgges.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cgges.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cgges.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE CGGES( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B, LDB,
22* SDIM, ALPHA, BETA, VSL, LDVSL, VSR, LDVSR, WORK,
23* LWORK, RWORK, BWORK, INFO )
24*
25* .. Scalar Arguments ..
26* CHARACTER JOBVSL, JOBVSR, SORT
27* INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
28* ..
29* .. Array Arguments ..
30* LOGICAL BWORK( * )
31* REAL RWORK( * )
32* COMPLEX A( LDA, * ), ALPHA( * ), B( LDB, * ),
33* $ BETA( * ), VSL( LDVSL, * ), VSR( LDVSR, * ),
34* $ WORK( * )
35* ..
36* .. Function Arguments ..
37* LOGICAL SELCTG
38* EXTERNAL SELCTG
39* ..
40*
41*
42*> \par Purpose:
43* =============
44*>
45*> \verbatim
46*>
47*> CGGES computes for a pair of N-by-N complex nonsymmetric matrices
48*> (A,B), the generalized eigenvalues, the generalized complex Schur
49*> form (S, T), and optionally left and/or right Schur vectors (VSL
50*> and VSR). This gives the generalized Schur factorization
51*>
52*> (A,B) = ( (VSL)*S*(VSR)**H, (VSL)*T*(VSR)**H )
53*>
54*> where (VSR)**H is the conjugate-transpose of VSR.
55*>
56*> Optionally, it also orders the eigenvalues so that a selected cluster
57*> of eigenvalues appears in the leading diagonal blocks of the upper
58*> triangular matrix S and the upper triangular matrix T. The leading
59*> columns of VSL and VSR then form an unitary basis for the
60*> corresponding left and right eigenspaces (deflating subspaces).
61*>
62*> (If only the generalized eigenvalues are needed, use the driver
63*> CGGEV instead, which is faster.)
64*>
65*> A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
66*> or a ratio alpha/beta = w, such that A - w*B is singular. It is
67*> usually represented as the pair (alpha,beta), as there is a
68*> reasonable interpretation for beta=0, and even for both being zero.
69*>
70*> A pair of matrices (S,T) is in generalized complex Schur form if S
71*> and T are upper triangular and, in addition, the diagonal elements
72*> of T are non-negative real numbers.
73*> \endverbatim
74*
75* Arguments:
76* ==========
77*
78*> \param[in] JOBVSL
79*> \verbatim
80*> JOBVSL is CHARACTER*1
81*> = 'N': do not compute the left Schur vectors;
82*> = 'V': compute the left Schur vectors.
83*> \endverbatim
84*>
85*> \param[in] JOBVSR
86*> \verbatim
87*> JOBVSR is CHARACTER*1
88*> = 'N': do not compute the right Schur vectors;
89*> = 'V': compute the right Schur vectors.
90*> \endverbatim
91*>
92*> \param[in] SORT
93*> \verbatim
94*> SORT is CHARACTER*1
95*> Specifies whether or not to order the eigenvalues on the
96*> diagonal of the generalized Schur form.
97*> = 'N': Eigenvalues are not ordered;
98*> = 'S': Eigenvalues are ordered (see SELCTG).
99*> \endverbatim
100*>
101*> \param[in] SELCTG
102*> \verbatim
103*> SELCTG is a LOGICAL FUNCTION of two COMPLEX arguments
104*> SELCTG must be declared EXTERNAL in the calling subroutine.
105*> If SORT = 'N', SELCTG is not referenced.
106*> If SORT = 'S', SELCTG is used to select eigenvalues to sort
107*> to the top left of the Schur form.
108*> An eigenvalue ALPHA(j)/BETA(j) is selected if
109*> SELCTG(ALPHA(j),BETA(j)) is true.
110*>
111*> Note that a selected complex eigenvalue may no longer satisfy
112*> SELCTG(ALPHA(j),BETA(j)) = .TRUE. after ordering, since
113*> ordering may change the value of complex eigenvalues
114*> (especially if the eigenvalue is ill-conditioned), in this
115*> case INFO is set to N+2 (See INFO below).
116*> \endverbatim
117*>
118*> \param[in] N
119*> \verbatim
120*> N is INTEGER
121*> The order of the matrices A, B, VSL, and VSR. N >= 0.
122*> \endverbatim
123*>
124*> \param[in,out] A
125*> \verbatim
126*> A is COMPLEX array, dimension (LDA, N)
127*> On entry, the first of the pair of matrices.
128*> On exit, A has been overwritten by its generalized Schur
129*> form S.
130*> \endverbatim
131*>
132*> \param[in] LDA
133*> \verbatim
134*> LDA is INTEGER
135*> The leading dimension of A. LDA >= max(1,N).
136*> \endverbatim
137*>
138*> \param[in,out] B
139*> \verbatim
140*> B is COMPLEX array, dimension (LDB, N)
141*> On entry, the second of the pair of matrices.
142*> On exit, B has been overwritten by its generalized Schur
143*> form T.
144*> \endverbatim
145*>
146*> \param[in] LDB
147*> \verbatim
148*> LDB is INTEGER
149*> The leading dimension of B. LDB >= max(1,N).
150*> \endverbatim
151*>
152*> \param[out] SDIM
153*> \verbatim
154*> SDIM is INTEGER
155*> If SORT = 'N', SDIM = 0.
156*> If SORT = 'S', SDIM = number of eigenvalues (after sorting)
157*> for which SELCTG is true.
158*> \endverbatim
159*>
160*> \param[out] ALPHA
161*> \verbatim
162*> ALPHA is COMPLEX array, dimension (N)
163*> \endverbatim
164*>
165*> \param[out] BETA
166*> \verbatim
167*> BETA is COMPLEX array, dimension (N)
168*> On exit, ALPHA(j)/BETA(j), j=1,...,N, will be the
169*> generalized eigenvalues. ALPHA(j), j=1,...,N and BETA(j),
170*> j=1,...,N are the diagonals of the complex Schur form (A,B)
171*> output by CGGES. The BETA(j) will be non-negative real.
172*>
173*> Note: the quotients ALPHA(j)/BETA(j) may easily over- or
174*> underflow, and BETA(j) may even be zero. Thus, the user
175*> should avoid naively computing the ratio alpha/beta.
176*> However, ALPHA will be always less than and usually
177*> comparable with norm(A) in magnitude, and BETA always less
178*> than and usually comparable with norm(B).
179*> \endverbatim
180*>
181*> \param[out] VSL
182*> \verbatim
183*> VSL is COMPLEX array, dimension (LDVSL,N)
184*> If JOBVSL = 'V', VSL will contain the left Schur vectors.
185*> Not referenced if JOBVSL = 'N'.
186*> \endverbatim
187*>
188*> \param[in] LDVSL
189*> \verbatim
190*> LDVSL is INTEGER
191*> The leading dimension of the matrix VSL. LDVSL >= 1, and
192*> if JOBVSL = 'V', LDVSL >= N.
193*> \endverbatim
194*>
195*> \param[out] VSR
196*> \verbatim
197*> VSR is COMPLEX array, dimension (LDVSR,N)
198*> If JOBVSR = 'V', VSR will contain the right Schur vectors.
199*> Not referenced if JOBVSR = 'N'.
200*> \endverbatim
201*>
202*> \param[in] LDVSR
203*> \verbatim
204*> LDVSR is INTEGER
205*> The leading dimension of the matrix VSR. LDVSR >= 1, and
206*> if JOBVSR = 'V', LDVSR >= N.
207*> \endverbatim
208*>
209*> \param[out] WORK
210*> \verbatim
211*> WORK is COMPLEX array, dimension (MAX(1,LWORK))
212*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
213*> \endverbatim
214*>
215*> \param[in] LWORK
216*> \verbatim
217*> LWORK is INTEGER
218*> The dimension of the array WORK. LWORK >= max(1,2*N).
219*> For good performance, LWORK must generally be larger.
220*>
221*> If LWORK = -1, then a workspace query is assumed; the routine
222*> only calculates the optimal size of the WORK array, returns
223*> this value as the first entry of the WORK array, and no error
224*> message related to LWORK is issued by XERBLA.
225*> \endverbatim
226*>
227*> \param[out] RWORK
228*> \verbatim
229*> RWORK is REAL array, dimension (8*N)
230*> \endverbatim
231*>
232*> \param[out] BWORK
233*> \verbatim
234*> BWORK is LOGICAL array, dimension (N)
235*> Not referenced if SORT = 'N'.
236*> \endverbatim
237*>
238*> \param[out] INFO
239*> \verbatim
240*> INFO is INTEGER
241*> = 0: successful exit
242*> < 0: if INFO = -i, the i-th argument had an illegal value.
243*> =1,...,N:
244*> The QZ iteration failed. (A,B) are not in Schur
245*> form, but ALPHA(j) and BETA(j) should be correct for
246*> j=INFO+1,...,N.
247*> > N: =N+1: other than QZ iteration failed in CHGEQZ
248*> =N+2: after reordering, roundoff changed values of
249*> some complex eigenvalues so that leading
250*> eigenvalues in the Generalized Schur form no
251*> longer satisfy SELCTG=.TRUE. This could also
252*> be caused due to scaling.
253*> =N+3: reordering failed in CTGSEN.
254*> \endverbatim
255*
256* Authors:
257* ========
258*
259*> \author Univ. of Tennessee
260*> \author Univ. of California Berkeley
261*> \author Univ. of Colorado Denver
262*> \author NAG Ltd.
263*
264*> \ingroup gges
265*
266* =====================================================================
267 SUBROUTINE cgges( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B, LDB,
268 $ SDIM, ALPHA, BETA, VSL, LDVSL, VSR, LDVSR, WORK,
269 $ LWORK, RWORK, BWORK, INFO )
270*
271* -- LAPACK driver routine --
272* -- LAPACK is a software package provided by Univ. of Tennessee, --
273* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
274*
275* .. Scalar Arguments ..
276 CHARACTER JOBVSL, JOBVSR, SORT
277 INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
278* ..
279* .. Array Arguments ..
280 LOGICAL BWORK( * )
281 REAL RWORK( * )
282 COMPLEX A( LDA, * ), ALPHA( * ), B( LDB, * ),
283 $ beta( * ), vsl( ldvsl, * ), vsr( ldvsr, * ),
284 $ work( * )
285* ..
286* .. Function Arguments ..
287 LOGICAL SELCTG
288 EXTERNAL SELCTG
289* ..
290*
291* =====================================================================
292*
293* .. Parameters ..
294 REAL ZERO, ONE
295 PARAMETER ( ZERO = 0.0e0, one = 1.0e0 )
296 COMPLEX CZERO, CONE
297 parameter( czero = ( 0.0e0, 0.0e0 ),
298 $ cone = ( 1.0e0, 0.0e0 ) )
299* ..
300* .. Local Scalars ..
301 LOGICAL CURSL, ILASCL, ILBSCL, ILVSL, ILVSR, LASTSL,
302 $ LQUERY, WANTST
303 INTEGER I, ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT,
304 $ ILO, IRIGHT, IROWS, IRWRK, ITAU, IWRK, LWKMIN,
305 $ lwkopt
306 REAL ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS, PVSL,
307 $ PVSR, SMLNUM
308* ..
309* .. Local Arrays ..
310 INTEGER IDUM( 1 )
311 REAL DIF( 2 )
312* ..
313* .. External Subroutines ..
314 EXTERNAL cgeqrf, cggbak, cggbal, cgghrd, chgeqz, clacpy,
316* ..
317* .. External Functions ..
318 LOGICAL LSAME
319 INTEGER ILAENV
320 REAL CLANGE, SLAMCH, SROUNDUP_LWORK
321 EXTERNAL lsame, ilaenv, clange, slamch, sroundup_lwork
322* ..
323* .. Intrinsic Functions ..
324 INTRINSIC max, sqrt
325* ..
326* .. Executable Statements ..
327*
328* Decode the input arguments
329*
330 IF( lsame( jobvsl, 'N' ) ) THEN
331 ijobvl = 1
332 ilvsl = .false.
333 ELSE IF( lsame( jobvsl, 'V' ) ) THEN
334 ijobvl = 2
335 ilvsl = .true.
336 ELSE
337 ijobvl = -1
338 ilvsl = .false.
339 END IF
340*
341 IF( lsame( jobvsr, 'N' ) ) THEN
342 ijobvr = 1
343 ilvsr = .false.
344 ELSE IF( lsame( jobvsr, 'V' ) ) THEN
345 ijobvr = 2
346 ilvsr = .true.
347 ELSE
348 ijobvr = -1
349 ilvsr = .false.
350 END IF
351*
352 wantst = lsame( sort, 'S' )
353*
354* Test the input arguments
355*
356 info = 0
357 lquery = ( lwork.EQ.-1 )
358 IF( ijobvl.LE.0 ) THEN
359 info = -1
360 ELSE IF( ijobvr.LE.0 ) THEN
361 info = -2
362 ELSE IF( ( .NOT.wantst ) .AND. ( .NOT.lsame( sort, 'N' ) ) ) THEN
363 info = -3
364 ELSE IF( n.LT.0 ) THEN
365 info = -5
366 ELSE IF( lda.LT.max( 1, n ) ) THEN
367 info = -7
368 ELSE IF( ldb.LT.max( 1, n ) ) THEN
369 info = -9
370 ELSE IF( ldvsl.LT.1 .OR. ( ilvsl .AND. ldvsl.LT.n ) ) THEN
371 info = -14
372 ELSE IF( ldvsr.LT.1 .OR. ( ilvsr .AND. ldvsr.LT.n ) ) THEN
373 info = -16
374 END IF
375*
376* Compute workspace
377* (Note: Comments in the code beginning "Workspace:" describe the
378* minimal amount of workspace needed at that point in the code,
379* as well as the preferred amount for good performance.
380* NB refers to the optimal block size for the immediately
381* following subroutine, as returned by ILAENV.)
382*
383 IF( info.EQ.0 ) THEN
384 lwkmin = max( 1, 2*n )
385 lwkopt = max( 1, n + n*ilaenv( 1, 'CGEQRF', ' ', n, 1, n, 0 ) )
386 lwkopt = max( lwkopt, n +
387 $ n*ilaenv( 1, 'CUNMQR', ' ', n, 1, n, -1 ) )
388 IF( ilvsl ) THEN
389 lwkopt = max( lwkopt, n +
390 $ n*ilaenv( 1, 'CUNGQR', ' ', n, 1, n, -1 ) )
391 END IF
392 work( 1 ) = sroundup_lwork(lwkopt)
393*
394 IF( lwork.LT.lwkmin .AND. .NOT.lquery )
395 $ info = -18
396 END IF
397*
398 IF( info.NE.0 ) THEN
399 CALL xerbla( 'CGGES ', -info )
400 RETURN
401 ELSE IF( lquery ) THEN
402 RETURN
403 END IF
404*
405* Quick return if possible
406*
407 IF( n.EQ.0 ) THEN
408 sdim = 0
409 RETURN
410 END IF
411*
412* Get machine constants
413*
414 eps = slamch( 'P' )
415 smlnum = slamch( 'S' )
416 bignum = one / smlnum
417 smlnum = sqrt( smlnum ) / eps
418 bignum = one / smlnum
419*
420* Scale A if max element outside range [SMLNUM,BIGNUM]
421*
422 anrm = clange( 'M', n, n, a, lda, rwork )
423 ilascl = .false.
424 IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
425 anrmto = smlnum
426 ilascl = .true.
427 ELSE IF( anrm.GT.bignum ) THEN
428 anrmto = bignum
429 ilascl = .true.
430 END IF
431*
432 IF( ilascl )
433 $ CALL clascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
434*
435* Scale B if max element outside range [SMLNUM,BIGNUM]
436*
437 bnrm = clange( 'M', n, n, b, ldb, rwork )
438 ilbscl = .false.
439 IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
440 bnrmto = smlnum
441 ilbscl = .true.
442 ELSE IF( bnrm.GT.bignum ) THEN
443 bnrmto = bignum
444 ilbscl = .true.
445 END IF
446*
447 IF( ilbscl )
448 $ CALL clascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
449*
450* Permute the matrix to make it more nearly triangular
451* (Real Workspace: need 6*N)
452*
453 ileft = 1
454 iright = n + 1
455 irwrk = iright + n
456 CALL cggbal( 'P', n, a, lda, b, ldb, ilo, ihi, rwork( ileft ),
457 $ rwork( iright ), rwork( irwrk ), ierr )
458*
459* Reduce B to triangular form (QR decomposition of B)
460* (Complex Workspace: need N, prefer N*NB)
461*
462 irows = ihi + 1 - ilo
463 icols = n + 1 - ilo
464 itau = 1
465 iwrk = itau + irows
466 CALL cgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
467 $ work( iwrk ), lwork+1-iwrk, ierr )
468*
469* Apply the orthogonal transformation to matrix A
470* (Complex Workspace: need N, prefer N*NB)
471*
472 CALL cunmqr( 'L', 'C', irows, icols, irows, b( ilo, ilo ), ldb,
473 $ work( itau ), a( ilo, ilo ), lda, work( iwrk ),
474 $ lwork+1-iwrk, ierr )
475*
476* Initialize VSL
477* (Complex Workspace: need N, prefer N*NB)
478*
479 IF( ilvsl ) THEN
480 CALL claset( 'Full', n, n, czero, cone, vsl, ldvsl )
481 IF( irows.GT.1 ) THEN
482 CALL clacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
483 $ vsl( ilo+1, ilo ), ldvsl )
484 END IF
485 CALL cungqr( irows, irows, irows, vsl( ilo, ilo ), ldvsl,
486 $ work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
487 END IF
488*
489* Initialize VSR
490*
491 IF( ilvsr )
492 $ CALL claset( 'Full', n, n, czero, cone, vsr, ldvsr )
493*
494* Reduce to generalized Hessenberg form
495* (Workspace: none needed)
496*
497 CALL cgghrd( jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb, vsl,
498 $ ldvsl, vsr, ldvsr, ierr )
499*
500 sdim = 0
501*
502* Perform QZ algorithm, computing Schur vectors if desired
503* (Complex Workspace: need N)
504* (Real Workspace: need N)
505*
506 iwrk = itau
507 CALL chgeqz( 'S', jobvsl, jobvsr, n, ilo, ihi, a, lda, b, ldb,
508 $ alpha, beta, vsl, ldvsl, vsr, ldvsr, work( iwrk ),
509 $ lwork+1-iwrk, rwork( irwrk ), ierr )
510 IF( ierr.NE.0 ) THEN
511 IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
512 info = ierr
513 ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
514 info = ierr - n
515 ELSE
516 info = n + 1
517 END IF
518 GO TO 30
519 END IF
520*
521* Sort eigenvalues ALPHA/BETA if desired
522* (Workspace: none needed)
523*
524 IF( wantst ) THEN
525*
526* Undo scaling on eigenvalues before selecting
527*
528 IF( ilascl )
529 $ CALL clascl( 'G', 0, 0, anrm, anrmto, n, 1, alpha, n, ierr )
530 IF( ilbscl )
531 $ CALL clascl( 'G', 0, 0, bnrm, bnrmto, n, 1, beta, n, ierr )
532*
533* Select eigenvalues
534*
535 DO 10 i = 1, n
536 bwork( i ) = selctg( alpha( i ), beta( i ) )
537 10 CONTINUE
538*
539 CALL ctgsen( 0, ilvsl, ilvsr, bwork, n, a, lda, b, ldb, alpha,
540 $ beta, vsl, ldvsl, vsr, ldvsr, sdim, pvsl, pvsr,
541 $ dif, work( iwrk ), lwork-iwrk+1, idum, 1, ierr )
542 IF( ierr.EQ.1 )
543 $ info = n + 3
544*
545 END IF
546*
547* Apply back-permutation to VSL and VSR
548* (Workspace: none needed)
549*
550 IF( ilvsl )
551 $ CALL cggbak( 'P', 'L', n, ilo, ihi, rwork( ileft ),
552 $ rwork( iright ), n, vsl, ldvsl, ierr )
553 IF( ilvsr )
554 $ CALL cggbak( 'P', 'R', n, ilo, ihi, rwork( ileft ),
555 $ rwork( iright ), n, vsr, ldvsr, ierr )
556*
557* Undo scaling
558*
559 IF( ilascl ) THEN
560 CALL clascl( 'U', 0, 0, anrmto, anrm, n, n, a, lda, ierr )
561 CALL clascl( 'G', 0, 0, anrmto, anrm, n, 1, alpha, n, ierr )
562 END IF
563*
564 IF( ilbscl ) THEN
565 CALL clascl( 'U', 0, 0, bnrmto, bnrm, n, n, b, ldb, ierr )
566 CALL clascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
567 END IF
568*
569 IF( wantst ) THEN
570*
571* Check if reordering is correct
572*
573 lastsl = .true.
574 sdim = 0
575 DO 20 i = 1, n
576 cursl = selctg( alpha( i ), beta( i ) )
577 IF( cursl )
578 $ sdim = sdim + 1
579 IF( cursl .AND. .NOT.lastsl )
580 $ info = n + 2
581 lastsl = cursl
582 20 CONTINUE
583*
584 END IF
585*
586 30 CONTINUE
587*
588 work( 1 ) = sroundup_lwork(lwkopt)
589*
590 RETURN
591*
592* End of CGGES
593*
594 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine cgeqrf(m, n, a, lda, tau, work, lwork, info)
CGEQRF
Definition cgeqrf.f:146
subroutine cggbak(job, side, n, ilo, ihi, lscale, rscale, m, v, ldv, info)
CGGBAK
Definition cggbak.f:148
subroutine cggbal(job, n, a, lda, b, ldb, ilo, ihi, lscale, rscale, work, info)
CGGBAL
Definition cggbal.f:177
subroutine cgges(jobvsl, jobvsr, sort, selctg, n, a, lda, b, ldb, sdim, alpha, beta, vsl, ldvsl, vsr, ldvsr, work, lwork, rwork, bwork, info)
CGGES computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE m...
Definition cgges.f:270
subroutine cgghrd(compq, compz, n, ilo, ihi, a, lda, b, ldb, q, ldq, z, ldz, info)
CGGHRD
Definition cgghrd.f:204
subroutine chgeqz(job, compq, compz, n, ilo, ihi, h, ldh, t, ldt, alpha, beta, q, ldq, z, ldz, work, lwork, rwork, info)
CHGEQZ
Definition chgeqz.f:284
subroutine clacpy(uplo, m, n, a, lda, b, ldb)
CLACPY copies all or part of one two-dimensional array to another.
Definition clacpy.f:103
subroutine clascl(type, kl, ku, cfrom, cto, m, n, a, lda, info)
CLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition clascl.f:143
subroutine claset(uplo, m, n, alpha, beta, a, lda)
CLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values.
Definition claset.f:106
subroutine ctgsen(ijob, wantq, wantz, select, n, a, lda, b, ldb, alpha, beta, q, ldq, z, ldz, m, pl, pr, dif, work, lwork, iwork, liwork, info)
CTGSEN
Definition ctgsen.f:433
subroutine cungqr(m, n, k, a, lda, tau, work, lwork, info)
CUNGQR
Definition cungqr.f:128
subroutine cunmqr(side, trans, m, n, k, a, lda, tau, c, ldc, work, lwork, info)
CUNMQR
Definition cunmqr.f:168