LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zlatm2()

complex*16 function zlatm2 ( integer  M,
integer  N,
integer  I,
integer  J,
integer  KL,
integer  KU,
integer  IDIST,
integer, dimension( 4 )  ISEED,
complex*16, dimension( * )  D,
integer  IGRADE,
complex*16, dimension( * )  DL,
complex*16, dimension( * )  DR,
integer  IPVTNG,
integer, dimension( * )  IWORK,
double precision  SPARSE 
)

ZLATM2

Purpose:
    ZLATM2 returns the (I,J) entry of a random matrix of dimension
    (M, N) described by the other parameters. It is called by the
    ZLATMR routine in order to build random test matrices. No error
    checking on parameters is done, because this routine is called in
    a tight loop by ZLATMR which has already checked the parameters.

    Use of ZLATM2 differs from CLATM3 in the order in which the random
    number generator is called to fill in random matrix entries.
    With ZLATM2, the generator is called to fill in the pivoted matrix
    columnwise. With ZLATM3, the generator is called to fill in the
    matrix columnwise, after which it is pivoted. Thus, ZLATM3 can
    be used to construct random matrices which differ only in their
    order of rows and/or columns. ZLATM2 is used to construct band
    matrices while avoiding calling the random number generator for
    entries outside the band (and therefore generating random numbers

    The matrix whose (I,J) entry is returned is constructed as
    follows (this routine only computes one entry):

      If I is outside (1..M) or J is outside (1..N), return zero
         (this is convenient for generating matrices in band format).

      Generate a matrix A with random entries of distribution IDIST.

      Set the diagonal to D.

      Grade the matrix, if desired, from the left (by DL) and/or
         from the right (by DR or DL) as specified by IGRADE.

      Permute, if desired, the rows and/or columns as specified by
         IPVTNG and IWORK.

      Band the matrix to have lower bandwidth KL and upper
         bandwidth KU.

      Set random entries to zero as specified by SPARSE.
Parameters
[in]M
          M is INTEGER
           Number of rows of matrix. Not modified.
[in]N
          N is INTEGER
           Number of columns of matrix. Not modified.
[in]I
          I is INTEGER
           Row of entry to be returned. Not modified.
[in]J
          J is INTEGER
           Column of entry to be returned. Not modified.
[in]KL
          KL is INTEGER
           Lower bandwidth. Not modified.
[in]KU
          KU is INTEGER
           Upper bandwidth. Not modified.
[in]IDIST
          IDIST is INTEGER
           On entry, IDIST specifies the type of distribution to be
           used to generate a random matrix .
           1 => real and imaginary parts each UNIFORM( 0, 1 )
           2 => real and imaginary parts each UNIFORM( -1, 1 )
           3 => real and imaginary parts each NORMAL( 0, 1 )
           4 => complex number uniform in DISK( 0 , 1 )
           Not modified.
[in,out]ISEED
          ISEED is INTEGER array of dimension ( 4 )
           Seed for random number generator.
           Changed on exit.
[in]D
          D is COMPLEX*16 array of dimension ( MIN( I , J ) )
           Diagonal entries of matrix. Not modified.
[in]IGRADE
          IGRADE is INTEGER
           Specifies grading of matrix as follows:
           0  => no grading
           1  => matrix premultiplied by diag( DL )
           2  => matrix postmultiplied by diag( DR )
           3  => matrix premultiplied by diag( DL ) and
                         postmultiplied by diag( DR )
           4  => matrix premultiplied by diag( DL ) and
                         postmultiplied by inv( diag( DL ) )
           5  => matrix premultiplied by diag( DL ) and
                         postmultiplied by diag( CONJG(DL) )
           6  => matrix premultiplied by diag( DL ) and
                         postmultiplied by diag( DL )
           Not modified.
[in]DL
          DL is COMPLEX*16 array ( I or J, as appropriate )
           Left scale factors for grading matrix.  Not modified.
[in]DR
          DR is COMPLEX*16 array ( I or J, as appropriate )
           Right scale factors for grading matrix.  Not modified.
[in]IPVTNG
          IPVTNG is INTEGER
           On entry specifies pivoting permutations as follows:
           0 => none.
           1 => row pivoting.
           2 => column pivoting.
           3 => full pivoting, i.e., on both sides.
           Not modified.
[out]IWORK
          IWORK is INTEGER array ( I or J, as appropriate )
           This array specifies the permutation used. The
           row (or column) in position K was originally in
           position IWORK( K ).
           This differs from IWORK for ZLATM3. Not modified.
[in]SPARSE
          SPARSE is DOUBLE PRECISION between 0. and 1.
           On entry specifies the sparsity of the matrix
           if sparse matix is to be generated.
           SPARSE should lie between 0 and 1.
           A uniform ( 0, 1 ) random number x is generated and
           compared to SPARSE; if x is larger the matrix entry
           is unchanged and if x is smaller the entry is set
           to zero. Thus on the average a fraction SPARSE of the
           entries will be set to zero.
           Not modified.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2016

Definition at line 213 of file zlatm2.f.

213 *
214 * -- LAPACK auxiliary routine (version 3.7.0) --
215 * -- LAPACK is a software package provided by Univ. of Tennessee, --
216 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
217 * June 2016
218 *
219 * .. Scalar Arguments ..
220 *
221  INTEGER i, idist, igrade, ipvtng, j, kl, ku, m, n
222  DOUBLE PRECISION sparse
223 * ..
224 *
225 * .. Array Arguments ..
226 *
227  INTEGER iseed( 4 ), iwork( * )
228  COMPLEX*16 d( * ), dl( * ), dr( * )
229 * ..
230 *
231 * =====================================================================
232 *
233 * .. Parameters ..
234 *
235  COMPLEX*16 czero
236  parameter( czero = ( 0.0d0, 0.0d0 ) )
237  DOUBLE PRECISION zero
238  parameter( zero = 0.0d0 )
239 * ..
240 *
241 * .. Local Scalars ..
242 *
243  INTEGER isub, jsub
244  COMPLEX*16 ctemp
245 * ..
246 *
247 * .. External Functions ..
248 *
249  DOUBLE PRECISION dlaran
250  COMPLEX*16 zlarnd
251  EXTERNAL dlaran, zlarnd
252 * ..
253 *
254 * .. Intrinsic Functions ..
255 *
256  INTRINSIC dconjg
257 * ..
258 *
259 *-----------------------------------------------------------------------
260 *
261 * .. Executable Statements ..
262 *
263 *
264 * Check for I and J in range
265 *
266  IF( i.LT.1 .OR. i.GT.m .OR. j.LT.1 .OR. j.GT.n ) THEN
267  zlatm2 = czero
268  RETURN
269  END IF
270 *
271 * Check for banding
272 *
273  IF( j.GT.i+ku .OR. j.LT.i-kl ) THEN
274  zlatm2 = czero
275  RETURN
276  END IF
277 *
278 * Check for sparsity
279 *
280  IF( sparse.GT.zero ) THEN
281  IF( dlaran( iseed ).LT.sparse ) THEN
282  zlatm2 = czero
283  RETURN
284  END IF
285  END IF
286 *
287 * Compute subscripts depending on IPVTNG
288 *
289  IF( ipvtng.EQ.0 ) THEN
290  isub = i
291  jsub = j
292  ELSE IF( ipvtng.EQ.1 ) THEN
293  isub = iwork( i )
294  jsub = j
295  ELSE IF( ipvtng.EQ.2 ) THEN
296  isub = i
297  jsub = iwork( j )
298  ELSE IF( ipvtng.EQ.3 ) THEN
299  isub = iwork( i )
300  jsub = iwork( j )
301  END IF
302 *
303 * Compute entry and grade it according to IGRADE
304 *
305  IF( isub.EQ.jsub ) THEN
306  ctemp = d( isub )
307  ELSE
308  ctemp = zlarnd( idist, iseed )
309  END IF
310  IF( igrade.EQ.1 ) THEN
311  ctemp = ctemp*dl( isub )
312  ELSE IF( igrade.EQ.2 ) THEN
313  ctemp = ctemp*dr( jsub )
314  ELSE IF( igrade.EQ.3 ) THEN
315  ctemp = ctemp*dl( isub )*dr( jsub )
316  ELSE IF( igrade.EQ.4 .AND. isub.NE.jsub ) THEN
317  ctemp = ctemp*dl( isub ) / dl( jsub )
318  ELSE IF( igrade.EQ.5 ) THEN
319  ctemp = ctemp*dl( isub )*dconjg( dl( jsub ) )
320  ELSE IF( igrade.EQ.6 ) THEN
321  ctemp = ctemp*dl( isub )*dl( jsub )
322  END IF
323  zlatm2 = ctemp
324  RETURN
325 *
326 * End of ZLATM2
327 *
complex *16 function zlarnd(IDIST, ISEED)
ZLARND
Definition: zlarnd.f:77
double precision function dlaran(ISEED)
DLARAN
Definition: dlaran.f:69
complex *16 function zlatm2(M, N, I, J, KL, KU, IDIST, ISEED, D, IGRADE, DL, DR, IPVTNG, IWORK, SPARSE)
ZLATM2
Definition: zlatm2.f:213