LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zhegvd.f
Go to the documentation of this file.
1*> \brief \b ZHEGVD
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download ZHEGVD + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhegvd.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhegvd.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhegvd.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE ZHEGVD( ITYPE, JOBZ, UPLO, N, A, LDA, B, LDB, W, WORK,
22* LWORK, RWORK, LRWORK, IWORK, LIWORK, INFO )
23*
24* .. Scalar Arguments ..
25* CHARACTER JOBZ, UPLO
26* INTEGER INFO, ITYPE, LDA, LDB, LIWORK, LRWORK, LWORK, N
27* ..
28* .. Array Arguments ..
29* INTEGER IWORK( * )
30* DOUBLE PRECISION RWORK( * ), W( * )
31* COMPLEX*16 A( LDA, * ), B( LDB, * ), WORK( * )
32* ..
33*
34*
35*> \par Purpose:
36* =============
37*>
38*> \verbatim
39*>
40*> ZHEGVD computes all the eigenvalues, and optionally, the eigenvectors
41*> of a complex generalized Hermitian-definite eigenproblem, of the form
42*> A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x. Here A and
43*> B are assumed to be Hermitian and B is also positive definite.
44*> If eigenvectors are desired, it uses a divide and conquer algorithm.
45*>
46*> \endverbatim
47*
48* Arguments:
49* ==========
50*
51*> \param[in] ITYPE
52*> \verbatim
53*> ITYPE is INTEGER
54*> Specifies the problem type to be solved:
55*> = 1: A*x = (lambda)*B*x
56*> = 2: A*B*x = (lambda)*x
57*> = 3: B*A*x = (lambda)*x
58*> \endverbatim
59*>
60*> \param[in] JOBZ
61*> \verbatim
62*> JOBZ is CHARACTER*1
63*> = 'N': Compute eigenvalues only;
64*> = 'V': Compute eigenvalues and eigenvectors.
65*> \endverbatim
66*>
67*> \param[in] UPLO
68*> \verbatim
69*> UPLO is CHARACTER*1
70*> = 'U': Upper triangles of A and B are stored;
71*> = 'L': Lower triangles of A and B are stored.
72*> \endverbatim
73*>
74*> \param[in] N
75*> \verbatim
76*> N is INTEGER
77*> The order of the matrices A and B. N >= 0.
78*> \endverbatim
79*>
80*> \param[in,out] A
81*> \verbatim
82*> A is COMPLEX*16 array, dimension (LDA, N)
83*> On entry, the Hermitian matrix A. If UPLO = 'U', the
84*> leading N-by-N upper triangular part of A contains the
85*> upper triangular part of the matrix A. If UPLO = 'L',
86*> the leading N-by-N lower triangular part of A contains
87*> the lower triangular part of the matrix A.
88*>
89*> On exit, if JOBZ = 'V', then if INFO = 0, A contains the
90*> matrix Z of eigenvectors. The eigenvectors are normalized
91*> as follows:
92*> if ITYPE = 1 or 2, Z**H*B*Z = I;
93*> if ITYPE = 3, Z**H*inv(B)*Z = I.
94*> If JOBZ = 'N', then on exit the upper triangle (if UPLO='U')
95*> or the lower triangle (if UPLO='L') of A, including the
96*> diagonal, is destroyed.
97*> \endverbatim
98*>
99*> \param[in] LDA
100*> \verbatim
101*> LDA is INTEGER
102*> The leading dimension of the array A. LDA >= max(1,N).
103*> \endverbatim
104*>
105*> \param[in,out] B
106*> \verbatim
107*> B is COMPLEX*16 array, dimension (LDB, N)
108*> On entry, the Hermitian matrix B. If UPLO = 'U', the
109*> leading N-by-N upper triangular part of B contains the
110*> upper triangular part of the matrix B. If UPLO = 'L',
111*> the leading N-by-N lower triangular part of B contains
112*> the lower triangular part of the matrix B.
113*>
114*> On exit, if INFO <= N, the part of B containing the matrix is
115*> overwritten by the triangular factor U or L from the Cholesky
116*> factorization B = U**H*U or B = L*L**H.
117*> \endverbatim
118*>
119*> \param[in] LDB
120*> \verbatim
121*> LDB is INTEGER
122*> The leading dimension of the array B. LDB >= max(1,N).
123*> \endverbatim
124*>
125*> \param[out] W
126*> \verbatim
127*> W is DOUBLE PRECISION array, dimension (N)
128*> If INFO = 0, the eigenvalues in ascending order.
129*> \endverbatim
130*>
131*> \param[out] WORK
132*> \verbatim
133*> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
134*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
135*> \endverbatim
136*>
137*> \param[in] LWORK
138*> \verbatim
139*> LWORK is INTEGER
140*> The length of the array WORK.
141*> If N <= 1, LWORK >= 1.
142*> If JOBZ = 'N' and N > 1, LWORK >= N + 1.
143*> If JOBZ = 'V' and N > 1, LWORK >= 2*N + N**2.
144*>
145*> If LWORK = -1, then a workspace query is assumed; the routine
146*> only calculates the optimal sizes of the WORK, RWORK and
147*> IWORK arrays, returns these values as the first entries of
148*> the WORK, RWORK and IWORK arrays, and no error message
149*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
150*> \endverbatim
151*>
152*> \param[out] RWORK
153*> \verbatim
154*> RWORK is DOUBLE PRECISION array, dimension (MAX(1,LRWORK))
155*> On exit, if INFO = 0, RWORK(1) returns the optimal LRWORK.
156*> \endverbatim
157*>
158*> \param[in] LRWORK
159*> \verbatim
160*> LRWORK is INTEGER
161*> The dimension of the array RWORK.
162*> If N <= 1, LRWORK >= 1.
163*> If JOBZ = 'N' and N > 1, LRWORK >= N.
164*> If JOBZ = 'V' and N > 1, LRWORK >= 1 + 5*N + 2*N**2.
165*>
166*> If LRWORK = -1, then a workspace query is assumed; the
167*> routine only calculates the optimal sizes of the WORK, RWORK
168*> and IWORK arrays, returns these values as the first entries
169*> of the WORK, RWORK and IWORK arrays, and no error message
170*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
171*> \endverbatim
172*>
173*> \param[out] IWORK
174*> \verbatim
175*> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
176*> On exit, if INFO = 0, IWORK(1) returns the optimal LIWORK.
177*> \endverbatim
178*>
179*> \param[in] LIWORK
180*> \verbatim
181*> LIWORK is INTEGER
182*> The dimension of the array IWORK.
183*> If N <= 1, LIWORK >= 1.
184*> If JOBZ = 'N' and N > 1, LIWORK >= 1.
185*> If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
186*>
187*> If LIWORK = -1, then a workspace query is assumed; the
188*> routine only calculates the optimal sizes of the WORK, RWORK
189*> and IWORK arrays, returns these values as the first entries
190*> of the WORK, RWORK and IWORK arrays, and no error message
191*> related to LWORK or LRWORK or LIWORK is issued by XERBLA.
192*> \endverbatim
193*>
194*> \param[out] INFO
195*> \verbatim
196*> INFO is INTEGER
197*> = 0: successful exit
198*> < 0: if INFO = -i, the i-th argument had an illegal value
199*> > 0: ZPOTRF or ZHEEVD returned an error code:
200*> <= N: if INFO = i and JOBZ = 'N', then the algorithm
201*> failed to converge; i off-diagonal elements of an
202*> intermediate tridiagonal form did not converge to
203*> zero;
204*> if INFO = i and JOBZ = 'V', then the algorithm
205*> failed to compute an eigenvalue while working on
206*> the submatrix lying in rows and columns INFO/(N+1)
207*> through mod(INFO,N+1);
208*> > N: if INFO = N + i, for 1 <= i <= N, then the leading
209*> principal minor of order i of B is not positive.
210*> The factorization of B could not be completed and
211*> no eigenvalues or eigenvectors were computed.
212*> \endverbatim
213*
214* Authors:
215* ========
216*
217*> \author Univ. of Tennessee
218*> \author Univ. of California Berkeley
219*> \author Univ. of Colorado Denver
220*> \author NAG Ltd.
221*
222*> \ingroup hegvd
223*
224*> \par Further Details:
225* =====================
226*>
227*> \verbatim
228*>
229*> Modified so that no backsubstitution is performed if ZHEEVD fails to
230*> converge (NEIG in old code could be greater than N causing out of
231*> bounds reference to A - reported by Ralf Meyer). Also corrected the
232*> description of INFO and the test on ITYPE. Sven, 16 Feb 05.
233*> \endverbatim
234*
235*> \par Contributors:
236* ==================
237*>
238*> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
239*>
240* =====================================================================
241 SUBROUTINE zhegvd( ITYPE, JOBZ, UPLO, N, A, LDA, B, LDB, W, WORK,
242 $ LWORK, RWORK, LRWORK, IWORK, LIWORK, INFO )
243*
244* -- LAPACK driver routine --
245* -- LAPACK is a software package provided by Univ. of Tennessee, --
246* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
247*
248* .. Scalar Arguments ..
249 CHARACTER JOBZ, UPLO
250 INTEGER INFO, ITYPE, LDA, LDB, LIWORK, LRWORK, LWORK, N
251* ..
252* .. Array Arguments ..
253 INTEGER IWORK( * )
254 DOUBLE PRECISION RWORK( * ), W( * )
255 COMPLEX*16 A( LDA, * ), B( LDB, * ), WORK( * )
256* ..
257*
258* =====================================================================
259*
260* .. Parameters ..
261 COMPLEX*16 CONE
262 parameter( cone = ( 1.0d+0, 0.0d+0 ) )
263* ..
264* .. Local Scalars ..
265 LOGICAL LQUERY, UPPER, WANTZ
266 CHARACTER TRANS
267 INTEGER LIOPT, LIWMIN, LOPT, LROPT, LRWMIN, LWMIN
268* ..
269* .. External Functions ..
270 LOGICAL LSAME
271 EXTERNAL lsame
272* ..
273* .. External Subroutines ..
274 EXTERNAL xerbla, zheevd, zhegst, zpotrf, ztrmm, ztrsm
275* ..
276* .. Intrinsic Functions ..
277 INTRINSIC dble, max
278* ..
279* .. Executable Statements ..
280*
281* Test the input parameters.
282*
283 wantz = lsame( jobz, 'V' )
284 upper = lsame( uplo, 'U' )
285 lquery = ( lwork.EQ.-1 .OR. lrwork.EQ.-1 .OR. liwork.EQ.-1 )
286*
287 info = 0
288 IF( n.LE.1 ) THEN
289 lwmin = 1
290 lrwmin = 1
291 liwmin = 1
292 ELSE IF( wantz ) THEN
293 lwmin = 2*n + n*n
294 lrwmin = 1 + 5*n + 2*n*n
295 liwmin = 3 + 5*n
296 ELSE
297 lwmin = n + 1
298 lrwmin = n
299 liwmin = 1
300 END IF
301 lopt = lwmin
302 lropt = lrwmin
303 liopt = liwmin
304 IF( itype.LT.1 .OR. itype.GT.3 ) THEN
305 info = -1
306 ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
307 info = -2
308 ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
309 info = -3
310 ELSE IF( n.LT.0 ) THEN
311 info = -4
312 ELSE IF( lda.LT.max( 1, n ) ) THEN
313 info = -6
314 ELSE IF( ldb.LT.max( 1, n ) ) THEN
315 info = -8
316 END IF
317*
318 IF( info.EQ.0 ) THEN
319 work( 1 ) = lopt
320 rwork( 1 ) = lropt
321 iwork( 1 ) = liopt
322*
323 IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
324 info = -11
325 ELSE IF( lrwork.LT.lrwmin .AND. .NOT.lquery ) THEN
326 info = -13
327 ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
328 info = -15
329 END IF
330 END IF
331*
332 IF( info.NE.0 ) THEN
333 CALL xerbla( 'ZHEGVD', -info )
334 RETURN
335 ELSE IF( lquery ) THEN
336 RETURN
337 END IF
338*
339* Quick return if possible
340*
341 IF( n.EQ.0 )
342 $ RETURN
343*
344* Form a Cholesky factorization of B.
345*
346 CALL zpotrf( uplo, n, b, ldb, info )
347 IF( info.NE.0 ) THEN
348 info = n + info
349 RETURN
350 END IF
351*
352* Transform problem to standard eigenvalue problem and solve.
353*
354 CALL zhegst( itype, uplo, n, a, lda, b, ldb, info )
355 CALL zheevd( jobz, uplo, n, a, lda, w, work, lwork, rwork, lrwork,
356 $ iwork, liwork, info )
357 lopt = int( max( dble( lopt ), dble( work( 1 ) ) ) )
358 lropt = int( max( dble( lropt ), dble( rwork( 1 ) ) ) )
359 liopt = int( max( dble( liopt ), dble( iwork( 1 ) ) ) )
360*
361 IF( wantz .AND. info.EQ.0 ) THEN
362*
363* Backtransform eigenvectors to the original problem.
364*
365 IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
366*
367* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
368* backtransform eigenvectors: x = inv(L)**H *y or inv(U)*y
369*
370 IF( upper ) THEN
371 trans = 'N'
372 ELSE
373 trans = 'C'
374 END IF
375*
376 CALL ztrsm( 'Left', uplo, trans, 'Non-unit', n, n, cone,
377 $ b, ldb, a, lda )
378*
379 ELSE IF( itype.EQ.3 ) THEN
380*
381* For B*A*x=(lambda)*x;
382* backtransform eigenvectors: x = L*y or U**H *y
383*
384 IF( upper ) THEN
385 trans = 'C'
386 ELSE
387 trans = 'N'
388 END IF
389*
390 CALL ztrmm( 'Left', uplo, trans, 'Non-unit', n, n, cone,
391 $ b, ldb, a, lda )
392 END IF
393 END IF
394*
395 work( 1 ) = lopt
396 rwork( 1 ) = lropt
397 iwork( 1 ) = liopt
398*
399 RETURN
400*
401* End of ZHEGVD
402*
403 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine zheevd(jobz, uplo, n, a, lda, w, work, lwork, rwork, lrwork, iwork, liwork, info)
ZHEEVD computes the eigenvalues and, optionally, the left and/or right eigenvectors for HE matrices
Definition zheevd.f:199
subroutine zhegst(itype, uplo, n, a, lda, b, ldb, info)
ZHEGST
Definition zhegst.f:128
subroutine zhegvd(itype, jobz, uplo, n, a, lda, b, ldb, w, work, lwork, rwork, lrwork, iwork, liwork, info)
ZHEGVD
Definition zhegvd.f:243
subroutine zpotrf(uplo, n, a, lda, info)
ZPOTRF
Definition zpotrf.f:107
subroutine ztrmm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
ZTRMM
Definition ztrmm.f:177
subroutine ztrsm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
ZTRSM
Definition ztrsm.f:180