LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ dlange()

double precision function dlange ( character  NORM,
integer  M,
integer  N,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  WORK 
)

DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general rectangular matrix.

Download DLANGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DLANGE  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 real matrix A.
Returns
DLANGE
    DLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in DLANGE as described
          above.
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.  When M = 0,
          DLANGE is set to zero.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.  When N = 0,
          DLANGE is set to zero.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          The m by n matrix A.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(M,1).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= M when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 113 of file dlange.f.

114 *
115 * -- LAPACK auxiliary routine --
116 * -- LAPACK is a software package provided by Univ. of Tennessee, --
117 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118 *
119 * .. Scalar Arguments ..
120  CHARACTER NORM
121  INTEGER LDA, M, N
122 * ..
123 * .. Array Arguments ..
124  DOUBLE PRECISION A( LDA, * ), WORK( * )
125 * ..
126 *
127 * =====================================================================
128 *
129 * .. Parameters ..
130  DOUBLE PRECISION ONE, ZERO
131  parameter( one = 1.0d+0, zero = 0.0d+0 )
132 * ..
133 * .. Local Scalars ..
134  INTEGER I, J
135  DOUBLE PRECISION SCALE, SUM, VALUE, TEMP
136 * ..
137 * .. External Subroutines ..
138  EXTERNAL dlassq
139 * ..
140 * .. External Functions ..
141  LOGICAL LSAME, DISNAN
142  EXTERNAL lsame, disnan
143 * ..
144 * .. Intrinsic Functions ..
145  INTRINSIC abs, min, sqrt
146 * ..
147 * .. Executable Statements ..
148 *
149  IF( min( m, n ).EQ.0 ) THEN
150  VALUE = zero
151  ELSE IF( lsame( norm, 'M' ) ) THEN
152 *
153 * Find max(abs(A(i,j))).
154 *
155  VALUE = zero
156  DO 20 j = 1, n
157  DO 10 i = 1, m
158  temp = abs( a( i, j ) )
159  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
160  10 CONTINUE
161  20 CONTINUE
162  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
163 *
164 * Find norm1(A).
165 *
166  VALUE = zero
167  DO 40 j = 1, n
168  sum = zero
169  DO 30 i = 1, m
170  sum = sum + abs( a( i, j ) )
171  30 CONTINUE
172  IF( VALUE.LT.sum .OR. disnan( sum ) ) VALUE = sum
173  40 CONTINUE
174  ELSE IF( lsame( norm, 'I' ) ) THEN
175 *
176 * Find normI(A).
177 *
178  DO 50 i = 1, m
179  work( i ) = zero
180  50 CONTINUE
181  DO 70 j = 1, n
182  DO 60 i = 1, m
183  work( i ) = work( i ) + abs( a( i, j ) )
184  60 CONTINUE
185  70 CONTINUE
186  VALUE = zero
187  DO 80 i = 1, m
188  temp = work( i )
189  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
190  80 CONTINUE
191  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
192 *
193 * Find normF(A).
194 *
195  scale = zero
196  sum = one
197  DO 90 j = 1, n
198  CALL dlassq( m, a( 1, j ), 1, scale, sum )
199  90 CONTINUE
200  VALUE = scale*sqrt( sum )
201  END IF
202 *
203  dlange = VALUE
204  RETURN
205 *
206 * End of DLANGE
207 *
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dlassq(n, x, incx, scl, sumsq)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f90:137
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function dlange(NORM, M, N, A, LDA, WORK)
DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlange.f:114
Here is the call graph for this function:
Here is the caller graph for this function: