LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zgemqr.f
Go to the documentation of this file.
1*> \brief \b ZGEMQR
2*
3* Definition:
4* ===========
5*
6* SUBROUTINE ZGEMQR( SIDE, TRANS, M, N, K, A, LDA, T,
7* $ TSIZE, C, LDC, WORK, LWORK, INFO )
8*
9*
10* .. Scalar Arguments ..
11* CHARACTER SIDE, TRANS
12* INTEGER INFO, LDA, M, N, K, LDT, TSIZE, LWORK, LDC
13* ..
14* .. Array Arguments ..
15* COMPLEX*16 A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
16* ..
17*
18*> \par Purpose:
19* =============
20*>
21*> \verbatim
22*>
23*> ZGEMQR overwrites the general real M-by-N matrix C with
24*>
25*> SIDE = 'L' SIDE = 'R'
26*> TRANS = 'N': Q * C C * Q
27*> TRANS = 'T': Q**H * C C * Q**H
28*>
29*> where Q is a complex unitary matrix defined as the product
30*> of blocked elementary reflectors computed by tall skinny
31*> QR factorization (ZGEQR)
32*>
33*> \endverbatim
34*
35* Arguments:
36* ==========
37*
38*> \param[in] SIDE
39*> \verbatim
40*> SIDE is CHARACTER*1
41*> = 'L': apply Q or Q**H from the Left;
42*> = 'R': apply Q or Q**H from the Right.
43*> \endverbatim
44*>
45*> \param[in] TRANS
46*> \verbatim
47*> TRANS is CHARACTER*1
48*> = 'N': No transpose, apply Q;
49*> = 'C': Conjugate transpose, apply Q**H.
50*> \endverbatim
51*>
52*> \param[in] M
53*> \verbatim
54*> M is INTEGER
55*> The number of rows of the matrix A. M >=0.
56*> \endverbatim
57*>
58*> \param[in] N
59*> \verbatim
60*> N is INTEGER
61*> The number of columns of the matrix C. N >= 0.
62*> \endverbatim
63*>
64*> \param[in] K
65*> \verbatim
66*> K is INTEGER
67*> The number of elementary reflectors whose product defines
68*> the matrix Q.
69*> If SIDE = 'L', M >= K >= 0;
70*> if SIDE = 'R', N >= K >= 0.
71*> \endverbatim
72*>
73*> \param[in] A
74*> \verbatim
75*> A is COMPLEX*16 array, dimension (LDA,K)
76*> Part of the data structure to represent Q as returned by ZGEQR.
77*> \endverbatim
78*>
79*> \param[in] LDA
80*> \verbatim
81*> LDA is INTEGER
82*> The leading dimension of the array A.
83*> If SIDE = 'L', LDA >= max(1,M);
84*> if SIDE = 'R', LDA >= max(1,N).
85*> \endverbatim
86*>
87*> \param[in] T
88*> \verbatim
89*> T is COMPLEX*16 array, dimension (MAX(5,TSIZE)).
90*> Part of the data structure to represent Q as returned by ZGEQR.
91*> \endverbatim
92*>
93*> \param[in] TSIZE
94*> \verbatim
95*> TSIZE is INTEGER
96*> The dimension of the array T. TSIZE >= 5.
97*> \endverbatim
98*>
99*> \param[in,out] C
100*> \verbatim
101*> C is COMPLEX*16 array, dimension (LDC,N)
102*> On entry, the M-by-N matrix C.
103*> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
104*> \endverbatim
105*>
106*> \param[in] LDC
107*> \verbatim
108*> LDC is INTEGER
109*> The leading dimension of the array C. LDC >= max(1,M).
110*> \endverbatim
111*>
112*> \param[out] WORK
113*> \verbatim
114*> (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
115*> \endverbatim
116*>
117*> \param[in] LWORK
118*> \verbatim
119*> LWORK is INTEGER
120*> The dimension of the array WORK.
121*> If LWORK = -1, then a workspace query is assumed. The routine
122*> only calculates the size of the WORK array, returns this
123*> value as WORK(1), and no error message related to WORK
124*> is issued by XERBLA.
125*> \endverbatim
126*>
127*> \param[out] INFO
128*> \verbatim
129*> INFO is INTEGER
130*> = 0: successful exit
131*> < 0: if INFO = -i, the i-th argument had an illegal value
132*> \endverbatim
133*
134* Authors:
135* ========
136*
137*> \author Univ. of Tennessee
138*> \author Univ. of California Berkeley
139*> \author Univ. of Colorado Denver
140*> \author NAG Ltd.
141*
142*> \par Further Details
143* ====================
144*>
145*> \verbatim
146*>
147*> These details are particular for this LAPACK implementation. Users should not
148*> take them for granted. These details may change in the future, and are not likely
149*> true for another LAPACK implementation. These details are relevant if one wants
150*> to try to understand the code. They are not part of the interface.
151*>
152*> In this version,
153*>
154*> T(2): row block size (MB)
155*> T(3): column block size (NB)
156*> T(6:TSIZE): data structure needed for Q, computed by
157*> ZLATSQR or ZGEQRT
158*>
159*> Depending on the matrix dimensions M and N, and row and column
160*> block sizes MB and NB returned by ILAENV, ZGEQR will use either
161*> ZLATSQR (if the matrix is tall-and-skinny) or ZGEQRT to compute
162*> the QR factorization.
163*> This version of ZGEMQR will use either ZLAMTSQR or ZGEMQRT to
164*> multiply matrix Q by another matrix.
165*> Further Details in ZLAMTSQR or ZGEMQRT.
166*>
167*> \endverbatim
168*>
169*> \ingroup gemqr
170*>
171* =====================================================================
172 SUBROUTINE zgemqr( SIDE, TRANS, M, N, K, A, LDA, T, TSIZE,
173 $ C, LDC, WORK, LWORK, INFO )
174*
175* -- LAPACK computational routine --
176* -- LAPACK is a software package provided by Univ. of Tennessee, --
177* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
178*
179* .. Scalar Arguments ..
180 CHARACTER SIDE, TRANS
181 INTEGER INFO, LDA, M, N, K, TSIZE, LWORK, LDC
182* ..
183* .. Array Arguments ..
184 COMPLEX*16 A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
185* ..
186*
187* =====================================================================
188*
189* ..
190* .. Local Scalars ..
191 LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
192 INTEGER MB, NB, LW, NBLCKS, MN
193* ..
194* .. External Functions ..
195 LOGICAL LSAME
196 EXTERNAL lsame
197* ..
198* .. External Subroutines ..
199 EXTERNAL zgemqrt, zlamtsqr, xerbla
200* ..
201* .. Intrinsic Functions ..
202 INTRINSIC int, max, min, mod
203* ..
204* .. Executable Statements ..
205*
206* Test the input arguments
207*
208 lquery = lwork.EQ.-1
209 notran = lsame( trans, 'N' )
210 tran = lsame( trans, 'C' )
211 left = lsame( side, 'L' )
212 right = lsame( side, 'R' )
213*
214 mb = int( t( 2 ) )
215 nb = int( t( 3 ) )
216 IF( left ) THEN
217 lw = n * nb
218 mn = m
219 ELSE
220 lw = mb * nb
221 mn = n
222 END IF
223*
224 IF( ( mb.GT.k ) .AND. ( mn.GT.k ) ) THEN
225 IF( mod( mn - k, mb - k ).EQ.0 ) THEN
226 nblcks = ( mn - k ) / ( mb - k )
227 ELSE
228 nblcks = ( mn - k ) / ( mb - k ) + 1
229 END IF
230 ELSE
231 nblcks = 1
232 END IF
233*
234 info = 0
235 IF( .NOT.left .AND. .NOT.right ) THEN
236 info = -1
237 ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
238 info = -2
239 ELSE IF( m.LT.0 ) THEN
240 info = -3
241 ELSE IF( n.LT.0 ) THEN
242 info = -4
243 ELSE IF( k.LT.0 .OR. k.GT.mn ) THEN
244 info = -5
245 ELSE IF( lda.LT.max( 1, mn ) ) THEN
246 info = -7
247 ELSE IF( tsize.LT.5 ) THEN
248 info = -9
249 ELSE IF( ldc.LT.max( 1, m ) ) THEN
250 info = -11
251 ELSE IF( ( lwork.LT.max( 1, lw ) ) .AND. ( .NOT.lquery ) ) THEN
252 info = -13
253 END IF
254*
255 IF( info.EQ.0 ) THEN
256 work( 1 ) = lw
257 END IF
258*
259 IF( info.NE.0 ) THEN
260 CALL xerbla( 'ZGEMQR', -info )
261 RETURN
262 ELSE IF( lquery ) THEN
263 RETURN
264 END IF
265*
266* Quick return if possible
267*
268 IF( min( m, n, k ).EQ.0 ) THEN
269 RETURN
270 END IF
271*
272 IF( ( left .AND. m.LE.k ) .OR. ( right .AND. n.LE.k )
273 $ .OR. ( mb.LE.k ) .OR. ( mb.GE.max( m, n, k ) ) ) THEN
274 CALL zgemqrt( side, trans, m, n, k, nb, a, lda, t( 6 ),
275 $ nb, c, ldc, work, info )
276 ELSE
277 CALL zlamtsqr( side, trans, m, n, k, mb, nb, a, lda, t( 6 ),
278 $ nb, c, ldc, work, lwork, info )
279 END IF
280*
281 work( 1 ) = lw
282*
283 RETURN
284*
285* End of ZGEMQR
286*
287 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine zgemqr(side, trans, m, n, k, a, lda, t, tsize, c, ldc, work, lwork, info)
ZGEMQR
Definition zgemqr.f:174
subroutine zgemqrt(side, trans, m, n, k, nb, v, ldv, t, ldt, c, ldc, work, info)
ZGEMQRT
Definition zgemqrt.f:168
subroutine zlamtsqr(side, trans, m, n, k, mb, nb, a, lda, t, ldt, c, ldc, work, lwork, info)
ZLAMTSQR
Definition zlamtsqr.f:199