LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zla_syrfsx_extended()

subroutine zla_syrfsx_extended ( integer  PREC_TYPE,
character  UPLO,
integer  N,
integer  NRHS,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( ldaf, * )  AF,
integer  LDAF,
integer, dimension( * )  IPIV,
logical  COLEQU,
double precision, dimension( * )  C,
complex*16, dimension( ldb, * )  B,
integer  LDB,
complex*16, dimension( ldy, * )  Y,
integer  LDY,
double precision, dimension( * )  BERR_OUT,
integer  N_NORMS,
double precision, dimension( nrhs, * )  ERR_BNDS_NORM,
double precision, dimension( nrhs, * )  ERR_BNDS_COMP,
complex*16, dimension( * )  RES,
double precision, dimension( * )  AYB,
complex*16, dimension( * )  DY,
complex*16, dimension( * )  Y_TAIL,
double precision  RCOND,
integer  ITHRESH,
double precision  RTHRESH,
double precision  DZ_UB,
logical  IGNORE_CWISE,
integer  INFO 
)

ZLA_SYRFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric indefinite matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.

Download ZLA_SYRFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLA_SYRFSX_EXTENDED improves the computed solution to a system of
 linear equations by performing extra-precise iterative refinement
 and provides error bounds and backward error estimates for the solution.
 This subroutine is called by ZSYRFSX to perform iterative refinement.
 In addition to normwise error bound, the code provides maximum
 componentwise error bound if possible. See comments for ERR_BNDS_NORM
 and ERR_BNDS_COMP for details of the error bounds. Note that this
 subroutine is only resonsible for setting the second fields of
 ERR_BNDS_NORM and ERR_BNDS_COMP.
Parameters
[in]PREC_TYPE
          PREC_TYPE is INTEGER
     Specifies the intermediate precision to be used in refinement.
     The value is defined by ILAPREC(P) where P is a CHARACTER and
     P    = 'S':  Single
          = 'D':  Double
          = 'I':  Indigenous
          = 'X', 'E':  Extra
[in]UPLO
          UPLO is CHARACTER*1
       = 'U':  Upper triangle of A is stored;
       = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right-hand-sides, i.e., the number of columns of the
     matrix B.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
     On entry, the N-by-N matrix A.
[in]LDA
          LDA is INTEGER
     The leading dimension of the array A.  LDA >= max(1,N).
[in]AF
          AF is COMPLEX*16 array, dimension (LDAF,N)
     The block diagonal matrix D and the multipliers used to
     obtain the factor U or L as computed by ZSYTRF.
[in]LDAF
          LDAF is INTEGER
     The leading dimension of the array AF.  LDAF >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
     Details of the interchanges and the block structure of D
     as determined by ZSYTRF.
[in]COLEQU
          COLEQU is LOGICAL
     If .TRUE. then column equilibration was done to A before calling
     this routine. This is needed to compute the solution and error
     bounds correctly.
[in]C
          C is DOUBLE PRECISION array, dimension (N)
     The column scale factors for A. If COLEQU = .FALSE., C
     is not accessed. If C is input, each element of C should be a power
     of the radix to ensure a reliable solution and error estimates.
     Scaling by powers of the radix does not cause rounding errors unless
     the result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in]B
          B is COMPLEX*16 array, dimension (LDB,NRHS)
     The right-hand-side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]Y
          Y is COMPLEX*16 array, dimension (LDY,NRHS)
     On entry, the solution matrix X, as computed by ZSYTRS.
     On exit, the improved solution matrix Y.
[in]LDY
          LDY is INTEGER
     The leading dimension of the array Y.  LDY >= max(1,N).
[out]BERR_OUT
          BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
     On exit, BERR_OUT(j) contains the componentwise relative backward
     error for right-hand-side j from the formula
         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
     where abs(Z) is the componentwise absolute value of the matrix
     or vector Z. This is computed by ZLA_LIN_BERR.
[in]N_NORMS
          N_NORMS is INTEGER
     Determines which error bounds to return (see ERR_BNDS_NORM
     and ERR_BNDS_COMP).
     If N_NORMS >= 1 return normwise error bounds.
     If N_NORMS >= 2 return componentwise error bounds.
[in,out]ERR_BNDS_NORM
          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in,out]ERR_BNDS_COMP
          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     This subroutine is only responsible for setting the second field
     above.
     See Lapack Working Note 165 for further details and extra
     cautions.
[in]RES
          RES is COMPLEX*16 array, dimension (N)
     Workspace to hold the intermediate residual.
[in]AYB
          AYB is DOUBLE PRECISION array, dimension (N)
     Workspace.
[in]DY
          DY is COMPLEX*16 array, dimension (N)
     Workspace to hold the intermediate solution.
[in]Y_TAIL
          Y_TAIL is COMPLEX*16 array, dimension (N)
     Workspace to hold the trailing bits of the intermediate solution.
[in]RCOND
          RCOND is DOUBLE PRECISION
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[in]ITHRESH
          ITHRESH is INTEGER
     The maximum number of residual computations allowed for
     refinement. The default is 10. For 'aggressive' set to 100 to
     permit convergence using approximate factorizations or
     factorizations other than LU. If the factorization uses a
     technique other than Gaussian elimination, the guarantees in
     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
[in]RTHRESH
          RTHRESH is DOUBLE PRECISION
     Determines when to stop refinement if the error estimate stops
     decreasing. Refinement will stop when the next solution no longer
     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
     default value is 0.5. For 'aggressive' set to 0.9 to permit
     convergence on extremely ill-conditioned matrices. See LAWN 165
     for more details.
[in]DZ_UB
          DZ_UB is DOUBLE PRECISION
     Determines when to start considering componentwise convergence.
     Componentwise convergence is only considered after each component
     of the solution Y is stable, which we definte as the relative
     change in each component being less than DZ_UB. The default value
     is 0.25, requiring the first bit to be stable. See LAWN 165 for
     more details.
[in]IGNORE_CWISE
          IGNORE_CWISE is LOGICAL
     If .TRUE. then ignore componentwise convergence. Default value
     is .FALSE..
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit.
       < 0:  if INFO = -i, the ith argument to ZLA_HERFSX_EXTENDED had an illegal
             value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2017

Definition at line 397 of file zla_syrfsx_extended.f.

397 *
398 * -- LAPACK computational routine (version 3.7.1) --
399 * -- LAPACK is a software package provided by Univ. of Tennessee, --
400 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
401 * June 2017
402 *
403 * .. Scalar Arguments ..
404  INTEGER info, lda, ldaf, ldb, ldy, n, nrhs, prec_type,
405  $ n_norms, ithresh
406  CHARACTER uplo
407  LOGICAL colequ, ignore_cwise
408  DOUBLE PRECISION rthresh, dz_ub
409 * ..
410 * .. Array Arguments ..
411  INTEGER ipiv( * )
412  COMPLEX*16 a( lda, * ), af( ldaf, * ), b( ldb, * ),
413  $ y( ldy, * ), res( * ), dy( * ), y_tail( * )
414  DOUBLE PRECISION c( * ), ayb( * ), rcond, berr_out( * ),
415  $ err_bnds_norm( nrhs, * ),
416  $ err_bnds_comp( nrhs, * )
417 * ..
418 *
419 * =====================================================================
420 *
421 * .. Local Scalars ..
422  INTEGER uplo2, cnt, i, j, x_state, z_state,
423  $ y_prec_state
424  DOUBLE PRECISION yk, dyk, ymin, normy, normx, normdx, dxrat,
425  $ dzrat, prevnormdx, prev_dz_z, dxratmax,
426  $ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
427  $ eps, hugeval, incr_thresh
428  LOGICAL incr_prec, upper
429  COMPLEX*16 zdum
430 * ..
431 * .. Parameters ..
432  INTEGER unstable_state, working_state, conv_state,
433  $ noprog_state, base_residual, extra_residual,
434  $ extra_y
435  parameter( unstable_state = 0, working_state = 1,
436  $ conv_state = 2, noprog_state = 3 )
437  parameter( base_residual = 0, extra_residual = 1,
438  $ extra_y = 2 )
439  INTEGER final_nrm_err_i, final_cmp_err_i, berr_i
440  INTEGER rcond_i, nrm_rcond_i, nrm_err_i, cmp_rcond_i
441  INTEGER cmp_err_i, piv_growth_i
442  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
443  $ berr_i = 3 )
444  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
445  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
446  $ piv_growth_i = 9 )
447  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
448  $ la_linrx_cwise_i
449  parameter( la_linrx_itref_i = 1,
450  $ la_linrx_ithresh_i = 2 )
451  parameter( la_linrx_cwise_i = 3 )
452  INTEGER la_linrx_trust_i, la_linrx_err_i,
453  $ la_linrx_rcond_i
454  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
455  parameter( la_linrx_rcond_i = 3 )
456 * ..
457 * .. External Functions ..
458  LOGICAL lsame
459  EXTERNAL ilauplo
460  INTEGER ilauplo
461 * ..
462 * .. External Subroutines ..
463  EXTERNAL zaxpy, zcopy, zsytrs, zsymv, blas_zsymv_x,
464  $ blas_zsymv2_x, zla_syamv, zla_wwaddw,
465  $ zla_lin_berr
466  DOUBLE PRECISION dlamch
467 * ..
468 * .. Intrinsic Functions ..
469  INTRINSIC abs, REAL, dimag, max, min
470 * ..
471 * .. Statement Functions ..
472  DOUBLE PRECISION cabs1
473 * ..
474 * .. Statement Function Definitions ..
475  cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
476 * ..
477 * .. Executable Statements ..
478 *
479  info = 0
480  upper = lsame( uplo, 'U' )
481  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
482  info = -2
483  ELSE IF( n.LT.0 ) THEN
484  info = -3
485  ELSE IF( nrhs.LT.0 ) THEN
486  info = -4
487  ELSE IF( lda.LT.max( 1, n ) ) THEN
488  info = -6
489  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
490  info = -8
491  ELSE IF( ldb.LT.max( 1, n ) ) THEN
492  info = -13
493  ELSE IF( ldy.LT.max( 1, n ) ) THEN
494  info = -15
495  END IF
496  IF( info.NE.0 ) THEN
497  CALL xerbla( 'ZLA_HERFSX_EXTENDED', -info )
498  RETURN
499  END IF
500  eps = dlamch( 'Epsilon' )
501  hugeval = dlamch( 'Overflow' )
502 * Force HUGEVAL to Inf
503  hugeval = hugeval * hugeval
504 * Using HUGEVAL may lead to spurious underflows.
505  incr_thresh = dble( n ) * eps
506 
507  IF ( lsame( uplo, 'L' ) ) THEN
508  uplo2 = ilauplo( 'L' )
509  ELSE
510  uplo2 = ilauplo( 'U' )
511  ENDIF
512 
513  DO j = 1, nrhs
514  y_prec_state = extra_residual
515  IF ( y_prec_state .EQ. extra_y ) THEN
516  DO i = 1, n
517  y_tail( i ) = 0.0d+0
518  END DO
519  END IF
520 
521  dxrat = 0.0d+0
522  dxratmax = 0.0d+0
523  dzrat = 0.0d+0
524  dzratmax = 0.0d+0
525  final_dx_x = hugeval
526  final_dz_z = hugeval
527  prevnormdx = hugeval
528  prev_dz_z = hugeval
529  dz_z = hugeval
530  dx_x = hugeval
531 
532  x_state = working_state
533  z_state = unstable_state
534  incr_prec = .false.
535 
536  DO cnt = 1, ithresh
537 *
538 * Compute residual RES = B_s - op(A_s) * Y,
539 * op(A) = A, A**T, or A**H depending on TRANS (and type).
540 *
541  CALL zcopy( n, b( 1, j ), 1, res, 1 )
542  IF ( y_prec_state .EQ. base_residual ) THEN
543  CALL zsymv( uplo, n, dcmplx(-1.0d+0), a, lda, y(1,j), 1,
544  $ dcmplx(1.0d+0), res, 1 )
545  ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
546  CALL blas_zsymv_x( uplo2, n, dcmplx(-1.0d+0), a, lda,
547  $ y( 1, j ), 1, dcmplx(1.0d+0), res, 1, prec_type )
548  ELSE
549  CALL blas_zsymv2_x(uplo2, n, dcmplx(-1.0d+0), a, lda,
550  $ y(1, j), y_tail, 1, dcmplx(1.0d+0), res, 1,
551  $ prec_type)
552  END IF
553 
554 ! XXX: RES is no longer needed.
555  CALL zcopy( n, res, 1, dy, 1 )
556  CALL zsytrs( uplo, n, 1, af, ldaf, ipiv, dy, n, info )
557 *
558 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
559 *
560  normx = 0.0d+0
561  normy = 0.0d+0
562  normdx = 0.0d+0
563  dz_z = 0.0d+0
564  ymin = hugeval
565 
566  DO i = 1, n
567  yk = cabs1( y( i, j ) )
568  dyk = cabs1( dy( i ) )
569 
570  IF ( yk .NE. 0.0d+0 ) THEN
571  dz_z = max( dz_z, dyk / yk )
572  ELSE IF ( dyk .NE. 0.0d+0 ) THEN
573  dz_z = hugeval
574  END IF
575 
576  ymin = min( ymin, yk )
577 
578  normy = max( normy, yk )
579 
580  IF ( colequ ) THEN
581  normx = max( normx, yk * c( i ) )
582  normdx = max( normdx, dyk * c( i ) )
583  ELSE
584  normx = normy
585  normdx = max( normdx, dyk )
586  END IF
587  END DO
588 
589  IF ( normx .NE. 0.0d+0 ) THEN
590  dx_x = normdx / normx
591  ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
592  dx_x = 0.0d+0
593  ELSE
594  dx_x = hugeval
595  END IF
596 
597  dxrat = normdx / prevnormdx
598  dzrat = dz_z / prev_dz_z
599 *
600 * Check termination criteria.
601 *
602  IF ( ymin*rcond .LT. incr_thresh*normy
603  $ .AND. y_prec_state .LT. extra_y )
604  $ incr_prec = .true.
605 
606  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
607  $ x_state = working_state
608  IF ( x_state .EQ. working_state ) THEN
609  IF ( dx_x .LE. eps ) THEN
610  x_state = conv_state
611  ELSE IF ( dxrat .GT. rthresh ) THEN
612  IF ( y_prec_state .NE. extra_y ) THEN
613  incr_prec = .true.
614  ELSE
615  x_state = noprog_state
616  END IF
617  ELSE
618  IF (dxrat .GT. dxratmax) dxratmax = dxrat
619  END IF
620  IF ( x_state .GT. working_state ) final_dx_x = dx_x
621  END IF
622 
623  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
624  $ z_state = working_state
625  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
626  $ z_state = working_state
627  IF ( z_state .EQ. working_state ) THEN
628  IF ( dz_z .LE. eps ) THEN
629  z_state = conv_state
630  ELSE IF ( dz_z .GT. dz_ub ) THEN
631  z_state = unstable_state
632  dzratmax = 0.0d+0
633  final_dz_z = hugeval
634  ELSE IF ( dzrat .GT. rthresh ) THEN
635  IF ( y_prec_state .NE. extra_y ) THEN
636  incr_prec = .true.
637  ELSE
638  z_state = noprog_state
639  END IF
640  ELSE
641  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
642  END IF
643  IF ( z_state .GT. working_state ) final_dz_z = dz_z
644  END IF
645 
646  IF ( x_state.NE.working_state.AND.
647  $ ( ignore_cwise.OR.z_state.NE.working_state ) )
648  $ GOTO 666
649 
650  IF ( incr_prec ) THEN
651  incr_prec = .false.
652  y_prec_state = y_prec_state + 1
653  DO i = 1, n
654  y_tail( i ) = 0.0d+0
655  END DO
656  END IF
657 
658  prevnormdx = normdx
659  prev_dz_z = dz_z
660 *
661 * Update soluton.
662 *
663  IF ( y_prec_state .LT. extra_y ) THEN
664  CALL zaxpy( n, dcmplx(1.0d+0), dy, 1, y(1,j), 1 )
665  ELSE
666  CALL zla_wwaddw( n, y(1,j), y_tail, dy )
667  END IF
668 
669  END DO
670 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
671  666 CONTINUE
672 *
673 * Set final_* when cnt hits ithresh.
674 *
675  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
676  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
677 *
678 * Compute error bounds.
679 *
680  IF ( n_norms .GE. 1 ) THEN
681  err_bnds_norm( j, la_linrx_err_i ) =
682  $ final_dx_x / (1 - dxratmax)
683  END IF
684  IF ( n_norms .GE. 2 ) THEN
685  err_bnds_comp( j, la_linrx_err_i ) =
686  $ final_dz_z / (1 - dzratmax)
687  END IF
688 *
689 * Compute componentwise relative backward error from formula
690 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
691 * where abs(Z) is the componentwise absolute value of the matrix
692 * or vector Z.
693 *
694 * Compute residual RES = B_s - op(A_s) * Y,
695 * op(A) = A, A**T, or A**H depending on TRANS (and type).
696 *
697  CALL zcopy( n, b( 1, j ), 1, res, 1 )
698  CALL zsymv( uplo, n, dcmplx(-1.0d+0), a, lda, y(1,j), 1,
699  $ dcmplx(1.0d+0), res, 1 )
700 
701  DO i = 1, n
702  ayb( i ) = cabs1( b( i, j ) )
703  END DO
704 *
705 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
706 *
707  CALL zla_syamv ( uplo2, n, 1.0d+0,
708  $ a, lda, y(1, j), 1, 1.0d+0, ayb, 1 )
709 
710  CALL zla_lin_berr ( n, n, 1, res, ayb, berr_out( j ) )
711 *
712 * End of loop for each RHS.
713 *
714  END DO
715 *
716  RETURN
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine zcopy(N, ZX, INCX, ZY, INCY)
ZCOPY
Definition: zcopy.f:83
subroutine zla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
ZLA_LIN_BERR computes a component-wise relative backward error.
Definition: zla_lin_berr.f:103
subroutine zsymv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZSYMV computes a matrix-vector product for a complex symmetric matrix.
Definition: zsymv.f:159
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
integer function ilauplo(UPLO)
ILAUPLO
Definition: ilauplo.f:60
subroutine zla_wwaddw(N, X, Y, W)
ZLA_WWADDW adds a vector into a doubled-single vector.
Definition: zla_wwaddw.f:83
subroutine zla_syamv(UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZLA_SYAMV computes a matrix-vector product using a symmetric indefinite matrix to calculate error bou...
Definition: zla_syamv.f:181
subroutine zsytrs(UPLO, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
ZSYTRS
Definition: zsytrs.f:122
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:90
Here is the call graph for this function:
Here is the caller graph for this function: