LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ cgelqt3()

recursive subroutine cgelqt3 ( integer  M,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( ldt, * )  T,
integer  LDT,
integer  INFO 
)
Purpose:

CGELQT3 recursively computes a LQ factorization of a complex M-by-N matrix A, using the compact WY representation of Q.

Based on the algorithm of Elmroth and Gustavson, IBM J. Res. Develop. Vol 44 No. 4 July 2000.

Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M =< N.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the real M-by-N matrix A.  On exit, the elements on and
          below the diagonal contain the N-by-N lower triangular matrix L; the
          elements above the diagonal are the rows of V.  See below for
          further details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]T
          T is COMPLEX array, dimension (LDT,N)
          The N-by-N upper triangular factor of the block reflector.
          The elements on and above the diagonal contain the block
          reflector T; the elements below the diagonal are not used.
          See below for further details.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
November 2017
Further Details:

The matrix V stores the elementary reflectors H(i) in the i-th row above the diagonal. For example, if M=5 and N=3, the matrix V is

V = ( 1 v1 v1 v1 v1 ) ( 1 v2 v2 v2 ) ( 1 v3 v3 v3 )

where the vi's represent the vectors which define H(i), which are returned in the matrix A. The 1's along the diagonal of V are not stored in A. The block reflector H is then given by

H = I - V * T * V**T

where V**T is the transpose of V.

For details of the algorithm, see Elmroth and Gustavson (cited above).

Definition at line 116 of file cgelqt3.f.

116 *
117 * -- LAPACK computational routine (version 3.8.0) --
118 * -- LAPACK is a software package provided by Univ. of Tennessee, --
119 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
120 * November 2017
121 *
122 * .. Scalar Arguments ..
123  INTEGER info, lda, m, n, ldt
124 * ..
125 * .. Array Arguments ..
126  COMPLEX a( lda, * ), t( ldt, * )
127 * ..
128 *
129 * =====================================================================
130 *
131 * .. Parameters ..
132  COMPLEX one, zero
133  parameter( one = (1.0e+00,0.0e+00) )
134  parameter( zero = (0.0e+00,0.0e+00))
135 * ..
136 * .. Local Scalars ..
137  INTEGER i, i1, j, j1, m1, m2, iinfo
138 * ..
139 * .. External Subroutines ..
140  EXTERNAL clarfg, ctrmm, cgemm, xerbla
141 * ..
142 * .. Executable Statements ..
143 *
144  info = 0
145  IF( m .LT. 0 ) THEN
146  info = -1
147  ELSE IF( n .LT. m ) THEN
148  info = -2
149  ELSE IF( lda .LT. max( 1, m ) ) THEN
150  info = -4
151  ELSE IF( ldt .LT. max( 1, m ) ) THEN
152  info = -6
153  END IF
154  IF( info.NE.0 ) THEN
155  CALL xerbla( 'CGELQT3', -info )
156  RETURN
157  END IF
158 *
159  IF( m.EQ.1 ) THEN
160 *
161 * Compute Householder transform when N=1
162 *
163  CALL clarfg( n, a, a( 1, min( 2, n ) ), lda, t )
164  t(1,1)=conjg(t(1,1))
165 *
166  ELSE
167 *
168 * Otherwise, split A into blocks...
169 *
170  m1 = m/2
171  m2 = m-m1
172  i1 = min( m1+1, m )
173  j1 = min( m+1, n )
174 *
175 * Compute A(1:M1,1:N) <- (Y1,R1,T1), where Q1 = I - Y1 T1 Y1^H
176 *
177  CALL cgelqt3( m1, n, a, lda, t, ldt, iinfo )
178 *
179 * Compute A(J1:M,1:N) = A(J1:M,1:N) Q1^H [workspace: T(1:N1,J1:N)]
180 *
181  DO i=1,m2
182  DO j=1,m1
183  t( i+m1, j ) = a( i+m1, j )
184  END DO
185  END DO
186  CALL ctrmm( 'R', 'U', 'C', 'U', m2, m1, one,
187  & a, lda, t( i1, 1 ), ldt )
188 *
189  CALL cgemm( 'N', 'C', m2, m1, n-m1, one, a( i1, i1 ), lda,
190  & a( 1, i1 ), lda, one, t( i1, 1 ), ldt)
191 *
192  CALL ctrmm( 'R', 'U', 'N', 'N', m2, m1, one,
193  & t, ldt, t( i1, 1 ), ldt )
194 *
195  CALL cgemm( 'N', 'N', m2, n-m1, m1, -one, t( i1, 1 ), ldt,
196  & a( 1, i1 ), lda, one, a( i1, i1 ), lda )
197 *
198  CALL ctrmm( 'R', 'U', 'N', 'U', m2, m1 , one,
199  & a, lda, t( i1, 1 ), ldt )
200 *
201  DO i=1,m2
202  DO j=1,m1
203  a( i+m1, j ) = a( i+m1, j ) - t( i+m1, j )
204  t( i+m1, j )= zero
205  END DO
206  END DO
207 *
208 * Compute A(J1:M,J1:N) <- (Y2,R2,T2) where Q2 = I - Y2 T2 Y2^H
209 *
210  CALL cgelqt3( m2, n-m1, a( i1, i1 ), lda,
211  & t( i1, i1 ), ldt, iinfo )
212 *
213 * Compute T3 = T(J1:N1,1:N) = -T1 Y1^H Y2 T2
214 *
215  DO i=1,m2
216  DO j=1,m1
217  t( j, i+m1 ) = (a( j, i+m1 ))
218  END DO
219  END DO
220 *
221  CALL ctrmm( 'R', 'U', 'C', 'U', m1, m2, one,
222  & a( i1, i1 ), lda, t( 1, i1 ), ldt )
223 *
224  CALL cgemm( 'N', 'C', m1, m2, n-m, one, a( 1, j1 ), lda,
225  & a( i1, j1 ), lda, one, t( 1, i1 ), ldt )
226 *
227  CALL ctrmm( 'L', 'U', 'N', 'N', m1, m2, -one, t, ldt,
228  & t( 1, i1 ), ldt )
229 *
230  CALL ctrmm( 'R', 'U', 'N', 'N', m1, m2, one,
231  & t( i1, i1 ), ldt, t( 1, i1 ), ldt )
232 *
233 *
234 *
235 * Y = (Y1,Y2); L = [ L1 0 ]; T = [T1 T3]
236 * [ A(1:N1,J1:N) L2 ] [ 0 T2]
237 *
238  END IF
239 *
240  RETURN
241 *
242 * End of CGELQT3
243 *
subroutine clarfg(N, ALPHA, X, INCX, TAU)
CLARFG generates an elementary reflector (Householder matrix).
Definition: clarfg.f:108
recursive subroutine cgelqt3(M, N, A, LDA, T, LDT, INFO)
Definition: cgelqt3.f:116
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine ctrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
CTRMM
Definition: ctrmm.f:179
subroutine cgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CGEMM
Definition: cgemm.f:189
Here is the call graph for this function:
Here is the caller graph for this function: