LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dgecon()

subroutine dgecon ( character  NORM,
integer  N,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision  ANORM,
double precision  RCOND,
double precision, dimension( * )  WORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

DGECON

Download DGECON + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DGECON estimates the reciprocal of the condition number of a general
 real matrix A, in either the 1-norm or the infinity-norm, using
 the LU factorization computed by DGETRF.

 An estimate is obtained for norm(inv(A)), and the reciprocal of the
 condition number is computed as
    RCOND = 1 / ( norm(A) * norm(inv(A)) ).
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies whether the 1-norm condition number or the
          infinity-norm condition number is required:
          = '1' or 'O':  1-norm;
          = 'I':         Infinity-norm.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          The factors L and U from the factorization A = P*L*U
          as computed by DGETRF.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in]ANORM
          ANORM is DOUBLE PRECISION
          If NORM = '1' or 'O', the 1-norm of the original matrix A.
          If NORM = 'I', the infinity-norm of the original matrix A.
[out]RCOND
          RCOND is DOUBLE PRECISION
          The reciprocal of the condition number of the matrix A,
          computed as RCOND = 1/(norm(A) * norm(inv(A))).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (4*N)
[out]IWORK
          IWORK is INTEGER array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 126 of file dgecon.f.

126 *
127 * -- LAPACK computational routine (version 3.7.0) --
128 * -- LAPACK is a software package provided by Univ. of Tennessee, --
129 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130 * December 2016
131 *
132 * .. Scalar Arguments ..
133  CHARACTER norm
134  INTEGER info, lda, n
135  DOUBLE PRECISION anorm, rcond
136 * ..
137 * .. Array Arguments ..
138  INTEGER iwork( * )
139  DOUBLE PRECISION a( lda, * ), work( * )
140 * ..
141 *
142 * =====================================================================
143 *
144 * .. Parameters ..
145  DOUBLE PRECISION one, zero
146  parameter( one = 1.0d+0, zero = 0.0d+0 )
147 * ..
148 * .. Local Scalars ..
149  LOGICAL onenrm
150  CHARACTER normin
151  INTEGER ix, kase, kase1
152  DOUBLE PRECISION ainvnm, scale, sl, smlnum, su
153 * ..
154 * .. Local Arrays ..
155  INTEGER isave( 3 )
156 * ..
157 * .. External Functions ..
158  LOGICAL lsame
159  INTEGER idamax
160  DOUBLE PRECISION dlamch
161  EXTERNAL lsame, idamax, dlamch
162 * ..
163 * .. External Subroutines ..
164  EXTERNAL dlacn2, dlatrs, drscl, xerbla
165 * ..
166 * .. Intrinsic Functions ..
167  INTRINSIC abs, max
168 * ..
169 * .. Executable Statements ..
170 *
171 * Test the input parameters.
172 *
173  info = 0
174  onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
175  IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
176  info = -1
177  ELSE IF( n.LT.0 ) THEN
178  info = -2
179  ELSE IF( lda.LT.max( 1, n ) ) THEN
180  info = -4
181  ELSE IF( anorm.LT.zero ) THEN
182  info = -5
183  END IF
184  IF( info.NE.0 ) THEN
185  CALL xerbla( 'DGECON', -info )
186  RETURN
187  END IF
188 *
189 * Quick return if possible
190 *
191  rcond = zero
192  IF( n.EQ.0 ) THEN
193  rcond = one
194  RETURN
195  ELSE IF( anorm.EQ.zero ) THEN
196  RETURN
197  END IF
198 *
199  smlnum = dlamch( 'Safe minimum' )
200 *
201 * Estimate the norm of inv(A).
202 *
203  ainvnm = zero
204  normin = 'N'
205  IF( onenrm ) THEN
206  kase1 = 1
207  ELSE
208  kase1 = 2
209  END IF
210  kase = 0
211  10 CONTINUE
212  CALL dlacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
213  IF( kase.NE.0 ) THEN
214  IF( kase.EQ.kase1 ) THEN
215 *
216 * Multiply by inv(L).
217 *
218  CALL dlatrs( 'Lower', 'No transpose', 'Unit', normin, n, a,
219  $ lda, work, sl, work( 2*n+1 ), info )
220 *
221 * Multiply by inv(U).
222 *
223  CALL dlatrs( 'Upper', 'No transpose', 'Non-unit', normin, n,
224  $ a, lda, work, su, work( 3*n+1 ), info )
225  ELSE
226 *
227 * Multiply by inv(U**T).
228 *
229  CALL dlatrs( 'Upper', 'Transpose', 'Non-unit', normin, n, a,
230  $ lda, work, su, work( 3*n+1 ), info )
231 *
232 * Multiply by inv(L**T).
233 *
234  CALL dlatrs( 'Lower', 'Transpose', 'Unit', normin, n, a,
235  $ lda, work, sl, work( 2*n+1 ), info )
236  END IF
237 *
238 * Divide X by 1/(SL*SU) if doing so will not cause overflow.
239 *
240  scale = sl*su
241  normin = 'Y'
242  IF( scale.NE.one ) THEN
243  ix = idamax( n, work, 1 )
244  IF( scale.LT.abs( work( ix ) )*smlnum .OR. scale.EQ.zero )
245  $ GO TO 20
246  CALL drscl( n, scale, work, 1 )
247  END IF
248  GO TO 10
249  END IF
250 *
251 * Compute the estimate of the reciprocal condition number.
252 *
253  IF( ainvnm.NE.zero )
254  $ rcond = ( one / ainvnm ) / anorm
255 *
256  20 CONTINUE
257  RETURN
258 *
259 * End of DGECON
260 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
integer function idamax(N, DX, INCX)
IDAMAX
Definition: idamax.f:73
subroutine dlatrs(UPLO, TRANS, DIAG, NORMIN, N, A, LDA, X, SCALE, CNORM, INFO)
DLATRS solves a triangular system of equations with the scale factor set to prevent overflow...
Definition: dlatrs.f:240
subroutine dlacn2(N, V, X, ISGN, EST, KASE, ISAVE)
DLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: dlacn2.f:138
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine drscl(N, SA, SX, INCX)
DRSCL multiplies a vector by the reciprocal of a real scalar.
Definition: drscl.f:86
Here is the call graph for this function:
Here is the caller graph for this function: