LAPACK  3.6.0
LAPACK: Linear Algebra PACKage
zgebal.f
Go to the documentation of this file.
1 *> \brief \b ZGEBAL
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZGEBAL + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgebal.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgebal.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgebal.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZGEBAL( JOB, N, A, LDA, ILO, IHI, SCALE, INFO )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER JOB
25 * INTEGER IHI, ILO, INFO, LDA, N
26 * ..
27 * .. Array Arguments ..
28 * DOUBLE PRECISION SCALE( * )
29 * COMPLEX*16 A( LDA, * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> ZGEBAL balances a general complex matrix A. This involves, first,
39 *> permuting A by a similarity transformation to isolate eigenvalues
40 *> in the first 1 to ILO-1 and last IHI+1 to N elements on the
41 *> diagonal; and second, applying a diagonal similarity transformation
42 *> to rows and columns ILO to IHI to make the rows and columns as
43 *> close in norm as possible. Both steps are optional.
44 *>
45 *> Balancing may reduce the 1-norm of the matrix, and improve the
46 *> accuracy of the computed eigenvalues and/or eigenvectors.
47 *> \endverbatim
48 *
49 * Arguments:
50 * ==========
51 *
52 *> \param[in] JOB
53 *> \verbatim
54 *> JOB is CHARACTER*1
55 *> Specifies the operations to be performed on A:
56 *> = 'N': none: simply set ILO = 1, IHI = N, SCALE(I) = 1.0
57 *> for i = 1,...,N;
58 *> = 'P': permute only;
59 *> = 'S': scale only;
60 *> = 'B': both permute and scale.
61 *> \endverbatim
62 *>
63 *> \param[in] N
64 *> \verbatim
65 *> N is INTEGER
66 *> The order of the matrix A. N >= 0.
67 *> \endverbatim
68 *>
69 *> \param[in,out] A
70 *> \verbatim
71 *> A is COMPLEX*16 array, dimension (LDA,N)
72 *> On entry, the input matrix A.
73 *> On exit, A is overwritten by the balanced matrix.
74 *> If JOB = 'N', A is not referenced.
75 *> See Further Details.
76 *> \endverbatim
77 *>
78 *> \param[in] LDA
79 *> \verbatim
80 *> LDA is INTEGER
81 *> The leading dimension of the array A. LDA >= max(1,N).
82 *> \endverbatim
83 *>
84 *> \param[out] ILO
85 *> \verbatim
86 *> \endverbatim
87 *>
88 *> \param[out] IHI
89 *> \verbatim
90 *> ILO and IHI are set to INTEGER such that on exit
91 *> A(i,j) = 0 if i > j and j = 1,...,ILO-1 or I = IHI+1,...,N.
92 *> If JOB = 'N' or 'S', ILO = 1 and IHI = N.
93 *> \endverbatim
94 *>
95 *> \param[out] SCALE
96 *> \verbatim
97 *> SCALE is DOUBLE PRECISION array, dimension (N)
98 *> Details of the permutations and scaling factors applied to
99 *> A. If P(j) is the index of the row and column interchanged
100 *> with row and column j and D(j) is the scaling factor
101 *> applied to row and column j, then
102 *> SCALE(j) = P(j) for j = 1,...,ILO-1
103 *> = D(j) for j = ILO,...,IHI
104 *> = P(j) for j = IHI+1,...,N.
105 *> The order in which the interchanges are made is N to IHI+1,
106 *> then 1 to ILO-1.
107 *> \endverbatim
108 *>
109 *> \param[out] INFO
110 *> \verbatim
111 *> INFO is INTEGER
112 *> = 0: successful exit.
113 *> < 0: if INFO = -i, the i-th argument had an illegal value.
114 *> \endverbatim
115 *
116 * Authors:
117 * ========
118 *
119 *> \author Univ. of Tennessee
120 *> \author Univ. of California Berkeley
121 *> \author Univ. of Colorado Denver
122 *> \author NAG Ltd.
123 *
124 *> \date November 2015
125 *
126 *> \ingroup complex16GEcomputational
127 *
128 *> \par Further Details:
129 * =====================
130 *>
131 *> \verbatim
132 *>
133 *> The permutations consist of row and column interchanges which put
134 *> the matrix in the form
135 *>
136 *> ( T1 X Y )
137 *> P A P = ( 0 B Z )
138 *> ( 0 0 T2 )
139 *>
140 *> where T1 and T2 are upper triangular matrices whose eigenvalues lie
141 *> along the diagonal. The column indices ILO and IHI mark the starting
142 *> and ending columns of the submatrix B. Balancing consists of applying
143 *> a diagonal similarity transformation inv(D) * B * D to make the
144 *> 1-norms of each row of B and its corresponding column nearly equal.
145 *> The output matrix is
146 *>
147 *> ( T1 X*D Y )
148 *> ( 0 inv(D)*B*D inv(D)*Z ).
149 *> ( 0 0 T2 )
150 *>
151 *> Information about the permutations P and the diagonal matrix D is
152 *> returned in the vector SCALE.
153 *>
154 *> This subroutine is based on the EISPACK routine CBAL.
155 *>
156 *> Modified by Tzu-Yi Chen, Computer Science Division, University of
157 *> California at Berkeley, USA
158 *> \endverbatim
159 *>
160 * =====================================================================
161  SUBROUTINE zgebal( JOB, N, A, LDA, ILO, IHI, SCALE, INFO )
162 *
163 * -- LAPACK computational routine (version 3.6.0) --
164 * -- LAPACK is a software package provided by Univ. of Tennessee, --
165 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
166 * November 2015
167 *
168 * .. Scalar Arguments ..
169  CHARACTER JOB
170  INTEGER IHI, ILO, INFO, LDA, N
171 * ..
172 * .. Array Arguments ..
173  DOUBLE PRECISION SCALE( * )
174  COMPLEX*16 A( lda, * )
175 * ..
176 *
177 * =====================================================================
178 *
179 * .. Parameters ..
180  DOUBLE PRECISION ZERO, ONE
181  parameter( zero = 0.0d+0, one = 1.0d+0 )
182  DOUBLE PRECISION SCLFAC
183  parameter( sclfac = 2.0d+0 )
184  DOUBLE PRECISION FACTOR
185  parameter( factor = 0.95d+0 )
186 * ..
187 * .. Local Scalars ..
188  LOGICAL NOCONV
189  INTEGER I, ICA, IEXC, IRA, J, K, L, M
190  DOUBLE PRECISION C, CA, F, G, R, RA, S, SFMAX1, SFMAX2, SFMIN1,
191  $ sfmin2
192  COMPLEX*16 CDUM
193 * ..
194 * .. External Functions ..
195  LOGICAL DISNAN, LSAME
196  INTEGER IZAMAX
197  DOUBLE PRECISION DLAMCH, DZNRM2
198  EXTERNAL disnan, lsame, izamax, dlamch, dznrm2
199 * ..
200 * .. External Subroutines ..
201  EXTERNAL xerbla, zdscal, zswap
202 * ..
203 * .. Intrinsic Functions ..
204  INTRINSIC abs, dble, dimag, max, min
205 *
206 * Test the input parameters
207 *
208  info = 0
209  IF( .NOT.lsame( job, 'N' ) .AND. .NOT.lsame( job, 'P' ) .AND.
210  $ .NOT.lsame( job, 'S' ) .AND. .NOT.lsame( job, 'B' ) ) THEN
211  info = -1
212  ELSE IF( n.LT.0 ) THEN
213  info = -2
214  ELSE IF( lda.LT.max( 1, n ) ) THEN
215  info = -4
216  END IF
217  IF( info.NE.0 ) THEN
218  CALL xerbla( 'ZGEBAL', -info )
219  RETURN
220  END IF
221 *
222  k = 1
223  l = n
224 *
225  IF( n.EQ.0 )
226  $ GO TO 210
227 *
228  IF( lsame( job, 'N' ) ) THEN
229  DO 10 i = 1, n
230  scale( i ) = one
231  10 CONTINUE
232  GO TO 210
233  END IF
234 *
235  IF( lsame( job, 'S' ) )
236  $ GO TO 120
237 *
238 * Permutation to isolate eigenvalues if possible
239 *
240  GO TO 50
241 *
242 * Row and column exchange.
243 *
244  20 CONTINUE
245  scale( m ) = j
246  IF( j.EQ.m )
247  $ GO TO 30
248 *
249  CALL zswap( l, a( 1, j ), 1, a( 1, m ), 1 )
250  CALL zswap( n-k+1, a( j, k ), lda, a( m, k ), lda )
251 *
252  30 CONTINUE
253  GO TO ( 40, 80 )iexc
254 *
255 * Search for rows isolating an eigenvalue and push them down.
256 *
257  40 CONTINUE
258  IF( l.EQ.1 )
259  $ GO TO 210
260  l = l - 1
261 *
262  50 CONTINUE
263  DO 70 j = l, 1, -1
264 *
265  DO 60 i = 1, l
266  IF( i.EQ.j )
267  $ GO TO 60
268  IF( dble( a( j, i ) ).NE.zero .OR. dimag( a( j, i ) ).NE.
269  $ zero )GO TO 70
270  60 CONTINUE
271 *
272  m = l
273  iexc = 1
274  GO TO 20
275  70 CONTINUE
276 *
277  GO TO 90
278 *
279 * Search for columns isolating an eigenvalue and push them left.
280 *
281  80 CONTINUE
282  k = k + 1
283 *
284  90 CONTINUE
285  DO 110 j = k, l
286 *
287  DO 100 i = k, l
288  IF( i.EQ.j )
289  $ GO TO 100
290  IF( dble( a( i, j ) ).NE.zero .OR. dimag( a( i, j ) ).NE.
291  $ zero )GO TO 110
292  100 CONTINUE
293 *
294  m = k
295  iexc = 2
296  GO TO 20
297  110 CONTINUE
298 *
299  120 CONTINUE
300  DO 130 i = k, l
301  scale( i ) = one
302  130 CONTINUE
303 *
304  IF( lsame( job, 'P' ) )
305  $ GO TO 210
306 *
307 * Balance the submatrix in rows K to L.
308 *
309 * Iterative loop for norm reduction
310 *
311  sfmin1 = dlamch( 'S' ) / dlamch( 'P' )
312  sfmax1 = one / sfmin1
313  sfmin2 = sfmin1*sclfac
314  sfmax2 = one / sfmin2
315  140 CONTINUE
316  noconv = .false.
317 *
318  DO 200 i = k, l
319 *
320  c = dznrm2( l-k+1, a( k, i ), 1 )
321  r = dznrm2( l-k+1, a( i, k ), lda )
322  ica = izamax( l, a( 1, i ), 1 )
323  ca = abs( a( ica, i ) )
324  ira = izamax( n-k+1, a( i, k ), lda )
325  ra = abs( a( i, ira+k-1 ) )
326 *
327 * Guard against zero C or R due to underflow.
328 *
329  IF( c.EQ.zero .OR. r.EQ.zero )
330  $ GO TO 200
331  g = r / sclfac
332  f = one
333  s = c + r
334  160 CONTINUE
335  IF( c.GE.g .OR. max( f, c, ca ).GE.sfmax2 .OR.
336  $ min( r, g, ra ).LE.sfmin2 )GO TO 170
337  IF( disnan( c+f+ca+r+g+ra ) ) THEN
338 *
339 * Exit if NaN to avoid infinite loop
340 *
341  info = -3
342  CALL xerbla( 'ZGEBAL', -info )
343  RETURN
344  END IF
345  f = f*sclfac
346  c = c*sclfac
347  ca = ca*sclfac
348  r = r / sclfac
349  g = g / sclfac
350  ra = ra / sclfac
351  GO TO 160
352 *
353  170 CONTINUE
354  g = c / sclfac
355  180 CONTINUE
356  IF( g.LT.r .OR. max( r, ra ).GE.sfmax2 .OR.
357  $ min( f, c, g, ca ).LE.sfmin2 )GO TO 190
358  f = f / sclfac
359  c = c / sclfac
360  g = g / sclfac
361  ca = ca / sclfac
362  r = r*sclfac
363  ra = ra*sclfac
364  GO TO 180
365 *
366 * Now balance.
367 *
368  190 CONTINUE
369  IF( ( c+r ).GE.factor*s )
370  $ GO TO 200
371  IF( f.LT.one .AND. scale( i ).LT.one ) THEN
372  IF( f*scale( i ).LE.sfmin1 )
373  $ GO TO 200
374  END IF
375  IF( f.GT.one .AND. scale( i ).GT.one ) THEN
376  IF( scale( i ).GE.sfmax1 / f )
377  $ GO TO 200
378  END IF
379  g = one / f
380  scale( i ) = scale( i )*f
381  noconv = .true.
382 *
383  CALL zdscal( n-k+1, g, a( i, k ), lda )
384  CALL zdscal( l, f, a( 1, i ), 1 )
385 *
386  200 CONTINUE
387 *
388  IF( noconv )
389  $ GO TO 140
390 *
391  210 CONTINUE
392  ilo = k
393  ihi = l
394 *
395  RETURN
396 *
397 * End of ZGEBAL
398 *
399  END
subroutine zgebal(JOB, N, A, LDA, ILO, IHI, SCALE, INFO)
ZGEBAL
Definition: zgebal.f:162
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zswap(N, ZX, INCX, ZY, INCY)
ZSWAP
Definition: zswap.f:52
subroutine zdscal(N, DA, ZX, INCX)
ZDSCAL
Definition: zdscal.f:54