LAPACK  3.6.0
LAPACK: Linear Algebra PACKage
Collaboration diagram for real:

Functions

subroutine sgbsv (N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
  SGBSV computes the solution to system of linear equations A * X = B for GB matrices (simple driver) More...
 
subroutine sgbsvx (FACT, TRANS, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB, IPIV, EQUED, R, C, B, LDB, X, LDX, RCOND, FERR, BERR, WORK, IWORK, INFO)
  SGBSVX computes the solution to system of linear equations A * X = B for GB matrices More...
 
subroutine sgbsvxx (FACT, TRANS, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB, IPIV, EQUED, R, C, B, LDB, X, LDX, RCOND, RPVGRW, BERR, N_ERR_BNDS, ERR_BNDS_NORM, ERR_BNDS_COMP, NPARAMS, PARAMS, WORK, IWORK, INFO)
  SGBSVXX computes the solution to system of linear equations A * X = B for GB matrices More...
 

Detailed Description

This is the group of real solve driver functions for GB matrices

Function Documentation

subroutine sgbsv ( integer  N,
integer  KL,
integer  KU,
integer  NRHS,
real, dimension( ldab, * )  AB,
integer  LDAB,
integer, dimension( * )  IPIV,
real, dimension( ldb, * )  B,
integer  LDB,
integer  INFO 
)

SGBSV computes the solution to system of linear equations A * X = B for GB matrices (simple driver)

Download SGBSV + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGBSV computes the solution to a real system of linear equations
 A * X = B, where A is a band matrix of order N with KL subdiagonals
 and KU superdiagonals, and X and B are N-by-NRHS matrices.

 The LU decomposition with partial pivoting and row interchanges is
 used to factor A as A = L * U, where L is a product of permutation
 and unit lower triangular matrices with KL subdiagonals, and U is
 upper triangular with KL+KU superdiagonals.  The factored form of A
 is then used to solve the system of equations A * X = B.
Parameters
[in]N
          N is INTEGER
          The number of linear equations, i.e., the order of the
          matrix A.  N >= 0.
[in]KL
          KL is INTEGER
          The number of subdiagonals within the band of A.  KL >= 0.
[in]KU
          KU is INTEGER
          The number of superdiagonals within the band of A.  KU >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in,out]AB
          AB is REAL array, dimension (LDAB,N)
          On entry, the matrix A in band storage, in rows KL+1 to
          2*KL+KU+1; rows 1 to KL of the array need not be set.
          The j-th column of A is stored in the j-th column of the
          array AB as follows:
          AB(KL+KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+KL)
          On exit, details of the factorization: U is stored as an
          upper triangular band matrix with KL+KU superdiagonals in
          rows 1 to KL+KU+1, and the multipliers used during the
          factorization are stored in rows KL+KU+2 to 2*KL+KU+1.
          See below for further details.
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDAB >= 2*KL+KU+1.
[out]IPIV
          IPIV is INTEGER array, dimension (N)
          The pivot indices that define the permutation matrix P;
          row i of the matrix was interchanged with row IPIV(i).
[in,out]B
          B is REAL array, dimension (LDB,NRHS)
          On entry, the N-by-NRHS right hand side matrix B.
          On exit, if INFO = 0, the N-by-NRHS solution matrix X.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, U(i,i) is exactly zero.  The factorization
                has been completed, but the factor U is exactly
                singular, and the solution has not been computed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
November 2011
Further Details:
  The band storage scheme is illustrated by the following example, when
  M = N = 6, KL = 2, KU = 1:

  On entry:                       On exit:

      *    *    *    +    +    +       *    *    *   u14  u25  u36
      *    *    +    +    +    +       *    *   u13  u24  u35  u46
      *   a12  a23  a34  a45  a56      *   u12  u23  u34  u45  u56
     a11  a22  a33  a44  a55  a66     u11  u22  u33  u44  u55  u66
     a21  a32  a43  a54  a65   *      m21  m32  m43  m54  m65   *
     a31  a42  a53  a64   *    *      m31  m42  m53  m64   *    *

  Array elements marked * are not used by the routine; elements marked
  + need not be set on entry, but are required by the routine to store
  elements of U because of fill-in resulting from the row interchanges.

Definition at line 164 of file sgbsv.f.

164 *
165 * -- LAPACK driver routine (version 3.4.0) --
166 * -- LAPACK is a software package provided by Univ. of Tennessee, --
167 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
168 * November 2011
169 *
170 * .. Scalar Arguments ..
171  INTEGER info, kl, ku, ldab, ldb, n, nrhs
172 * ..
173 * .. Array Arguments ..
174  INTEGER ipiv( * )
175  REAL ab( ldab, * ), b( ldb, * )
176 * ..
177 *
178 * =====================================================================
179 *
180 * .. External Subroutines ..
181  EXTERNAL sgbtrf, sgbtrs, xerbla
182 * ..
183 * .. Intrinsic Functions ..
184  INTRINSIC max
185 * ..
186 * .. Executable Statements ..
187 *
188 * Test the input parameters.
189 *
190  info = 0
191  IF( n.LT.0 ) THEN
192  info = -1
193  ELSE IF( kl.LT.0 ) THEN
194  info = -2
195  ELSE IF( ku.LT.0 ) THEN
196  info = -3
197  ELSE IF( nrhs.LT.0 ) THEN
198  info = -4
199  ELSE IF( ldab.LT.2*kl+ku+1 ) THEN
200  info = -6
201  ELSE IF( ldb.LT.max( n, 1 ) ) THEN
202  info = -9
203  END IF
204  IF( info.NE.0 ) THEN
205  CALL xerbla( 'SGBSV ', -info )
206  RETURN
207  END IF
208 *
209 * Compute the LU factorization of the band matrix A.
210 *
211  CALL sgbtrf( n, n, kl, ku, ab, ldab, ipiv, info )
212  IF( info.EQ.0 ) THEN
213 *
214 * Solve the system A*X = B, overwriting B with X.
215 *
216  CALL sgbtrs( 'No transpose', n, kl, ku, nrhs, ab, ldab, ipiv,
217  $ b, ldb, info )
218  END IF
219  RETURN
220 *
221 * End of SGBSV
222 *
subroutine sgbtrf(M, N, KL, KU, AB, LDAB, IPIV, INFO)
SGBTRF
Definition: sgbtrf.f:146
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine sgbtrs(TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
SGBTRS
Definition: sgbtrs.f:140

Here is the call graph for this function:

Here is the caller graph for this function:

subroutine sgbsvx ( character  FACT,
character  TRANS,
integer  N,
integer  KL,
integer  KU,
integer  NRHS,
real, dimension( ldab, * )  AB,
integer  LDAB,
real, dimension( ldafb, * )  AFB,
integer  LDAFB,
integer, dimension( * )  IPIV,
character  EQUED,
real, dimension( * )  R,
real, dimension( * )  C,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( ldx, * )  X,
integer  LDX,
real  RCOND,
real, dimension( * )  FERR,
real, dimension( * )  BERR,
real, dimension( * )  WORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

SGBSVX computes the solution to system of linear equations A * X = B for GB matrices

Download SGBSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGBSVX uses the LU factorization to compute the solution to a real
 system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
 where A is a band matrix of order N with KL subdiagonals and KU
 superdiagonals, and X and B are N-by-NRHS matrices.

 Error bounds on the solution and a condition estimate are also
 provided.
Description:
 The following steps are performed by this subroutine:

 1. If FACT = 'E', real scaling factors are computed to equilibrate
    the system:
       TRANS = 'N':  diag(R)*A*diag(C)     *inv(diag(C))*X = diag(R)*B
       TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
       TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B
    Whether or not the system will be equilibrated depends on the
    scaling of the matrix A, but if equilibration is used, A is
    overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
    or diag(C)*B (if TRANS = 'T' or 'C').

 2. If FACT = 'N' or 'E', the LU decomposition is used to factor the
    matrix A (after equilibration if FACT = 'E') as
       A = L * U,
    where L is a product of permutation and unit lower triangular
    matrices with KL subdiagonals, and U is upper triangular with
    KL+KU superdiagonals.

 3. If some U(i,i)=0, so that U is exactly singular, then the routine
    returns with INFO = i. Otherwise, the factored form of A is used
    to estimate the condition number of the matrix A.  If the
    reciprocal of the condition number is less than machine precision,
    INFO = N+1 is returned as a warning, but the routine still goes on
    to solve for X and compute error bounds as described below.

 4. The system of equations is solved for X using the factored form
    of A.

 5. Iterative refinement is applied to improve the computed solution
    matrix and calculate error bounds and backward error estimates
    for it.

 6. If equilibration was used, the matrix X is premultiplied by
    diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
    that it solves the original system before equilibration.
Parameters
[in]FACT
          FACT is CHARACTER*1
          Specifies whether or not the factored form of the matrix A is
          supplied on entry, and if not, whether the matrix A should be
          equilibrated before it is factored.
          = 'F':  On entry, AFB and IPIV contain the factored form of
                  A.  If EQUED is not 'N', the matrix A has been
                  equilibrated with scaling factors given by R and C.
                  AB, AFB, and IPIV are not modified.
          = 'N':  The matrix A will be copied to AFB and factored.
          = 'E':  The matrix A will be equilibrated if necessary, then
                  copied to AFB and factored.
[in]TRANS
          TRANS is CHARACTER*1
          Specifies the form of the system of equations.
          = 'N':  A * X = B     (No transpose)
          = 'T':  A**T * X = B  (Transpose)
          = 'C':  A**H * X = B  (Transpose)
[in]N
          N is INTEGER
          The number of linear equations, i.e., the order of the
          matrix A.  N >= 0.
[in]KL
          KL is INTEGER
          The number of subdiagonals within the band of A.  KL >= 0.
[in]KU
          KU is INTEGER
          The number of superdiagonals within the band of A.  KU >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrices B and X.  NRHS >= 0.
[in,out]AB
          AB is REAL array, dimension (LDAB,N)
          On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
          The j-th column of A is stored in the j-th column of the
          array AB as follows:
          AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)

          If FACT = 'F' and EQUED is not 'N', then A must have been
          equilibrated by the scaling factors in R and/or C.  AB is not
          modified if FACT = 'F' or 'N', or if FACT = 'E' and
          EQUED = 'N' on exit.

          On exit, if EQUED .ne. 'N', A is scaled as follows:
          EQUED = 'R':  A := diag(R) * A
          EQUED = 'C':  A := A * diag(C)
          EQUED = 'B':  A := diag(R) * A * diag(C).
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDAB >= KL+KU+1.
[in,out]AFB
          AFB is REAL array, dimension (LDAFB,N)
          If FACT = 'F', then AFB is an input argument and on entry
          contains details of the LU factorization of the band matrix
          A, as computed by SGBTRF.  U is stored as an upper triangular
          band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
          and the multipliers used during the factorization are stored
          in rows KL+KU+2 to 2*KL+KU+1.  If EQUED .ne. 'N', then AFB is
          the factored form of the equilibrated matrix A.

          If FACT = 'N', then AFB is an output argument and on exit
          returns details of the LU factorization of A.

          If FACT = 'E', then AFB is an output argument and on exit
          returns details of the LU factorization of the equilibrated
          matrix A (see the description of AB for the form of the
          equilibrated matrix).
[in]LDAFB
          LDAFB is INTEGER
          The leading dimension of the array AFB.  LDAFB >= 2*KL+KU+1.
[in,out]IPIV
          IPIV is INTEGER array, dimension (N)
          If FACT = 'F', then IPIV is an input argument and on entry
          contains the pivot indices from the factorization A = L*U
          as computed by SGBTRF; row i of the matrix was interchanged
          with row IPIV(i).

          If FACT = 'N', then IPIV is an output argument and on exit
          contains the pivot indices from the factorization A = L*U
          of the original matrix A.

          If FACT = 'E', then IPIV is an output argument and on exit
          contains the pivot indices from the factorization A = L*U
          of the equilibrated matrix A.
[in,out]EQUED
          EQUED is CHARACTER*1
          Specifies the form of equilibration that was done.
          = 'N':  No equilibration (always true if FACT = 'N').
          = 'R':  Row equilibration, i.e., A has been premultiplied by
                  diag(R).
          = 'C':  Column equilibration, i.e., A has been postmultiplied
                  by diag(C).
          = 'B':  Both row and column equilibration, i.e., A has been
                  replaced by diag(R) * A * diag(C).
          EQUED is an input argument if FACT = 'F'; otherwise, it is an
          output argument.
[in,out]R
          R is REAL array, dimension (N)
          The row scale factors for A.  If EQUED = 'R' or 'B', A is
          multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
          is not accessed.  R is an input argument if FACT = 'F';
          otherwise, R is an output argument.  If FACT = 'F' and
          EQUED = 'R' or 'B', each element of R must be positive.
[in,out]C
          C is REAL array, dimension (N)
          The column scale factors for A.  If EQUED = 'C' or 'B', A is
          multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
          is not accessed.  C is an input argument if FACT = 'F';
          otherwise, C is an output argument.  If FACT = 'F' and
          EQUED = 'C' or 'B', each element of C must be positive.
[in,out]B
          B is REAL array, dimension (LDB,NRHS)
          On entry, the right hand side matrix B.
          On exit,
          if EQUED = 'N', B is not modified;
          if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
          diag(R)*B;
          if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
          overwritten by diag(C)*B.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]X
          X is REAL array, dimension (LDX,NRHS)
          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X
          to the original system of equations.  Note that A and B are
          modified on exit if EQUED .ne. 'N', and the solution to the
          equilibrated system is inv(diag(C))*X if TRANS = 'N' and
          EQUED = 'C' or 'B', or inv(diag(R))*X if TRANS = 'T' or 'C'
          and EQUED = 'R' or 'B'.
[in]LDX
          LDX is INTEGER
          The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is REAL
          The estimate of the reciprocal condition number of the matrix
          A after equilibration (if done).  If RCOND is less than the
          machine precision (in particular, if RCOND = 0), the matrix
          is singular to working precision.  This condition is
          indicated by a return code of INFO > 0.
[out]FERR
          FERR is REAL array, dimension (NRHS)
          The estimated forward error bound for each solution vector
          X(j) (the j-th column of the solution matrix X).
          If XTRUE is the true solution corresponding to X(j), FERR(j)
          is an estimated upper bound for the magnitude of the largest
          element in (X(j) - XTRUE) divided by the magnitude of the
          largest element in X(j).  The estimate is as reliable as
          the estimate for RCOND, and is almost always a slight
          overestimate of the true error.
[out]BERR
          BERR is REAL array, dimension (NRHS)
          The componentwise relative backward error of each solution
          vector X(j) (i.e., the smallest relative change in
          any element of A or B that makes X(j) an exact solution).
[out]WORK
          WORK is REAL array, dimension (3*N)
          On exit, WORK(1) contains the reciprocal pivot growth
          factor norm(A)/norm(U). The "max absolute element" norm is
          used. If WORK(1) is much less than 1, then the stability
          of the LU factorization of the (equilibrated) matrix A
          could be poor. This also means that the solution X, condition
          estimator RCOND, and forward error bound FERR could be
          unreliable. If factorization fails with 0<INFO<=N, then
          WORK(1) contains the reciprocal pivot growth factor for the
          leading INFO columns of A.
[out]IWORK
          IWORK is INTEGER array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, and i is
                <= N:  U(i,i) is exactly zero.  The factorization
                       has been completed, but the factor U is exactly
                       singular, so the solution and error bounds
                       could not be computed. RCOND = 0 is returned.
                = N+1: U is nonsingular, but RCOND is less than machine
                       precision, meaning that the matrix is singular
                       to working precision.  Nevertheless, the
                       solution and error bounds are computed because
                       there are a number of situations where the
                       computed solution can be more accurate than the
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
April 2012

Definition at line 370 of file sgbsvx.f.

370 *
371 * -- LAPACK driver routine (version 3.4.1) --
372 * -- LAPACK is a software package provided by Univ. of Tennessee, --
373 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
374 * April 2012
375 *
376 * .. Scalar Arguments ..
377  CHARACTER equed, fact, trans
378  INTEGER info, kl, ku, ldab, ldafb, ldb, ldx, n, nrhs
379  REAL rcond
380 * ..
381 * .. Array Arguments ..
382  INTEGER ipiv( * ), iwork( * )
383  REAL ab( ldab, * ), afb( ldafb, * ), b( ldb, * ),
384  $ berr( * ), c( * ), ferr( * ), r( * ),
385  $ work( * ), x( ldx, * )
386 * ..
387 *
388 * =====================================================================
389 * Moved setting of INFO = N+1 so INFO does not subsequently get
390 * overwritten. Sven, 17 Mar 05.
391 * =====================================================================
392 *
393 * .. Parameters ..
394  REAL zero, one
395  parameter( zero = 0.0e+0, one = 1.0e+0 )
396 * ..
397 * .. Local Scalars ..
398  LOGICAL colequ, equil, nofact, notran, rowequ
399  CHARACTER norm
400  INTEGER i, infequ, j, j1, j2
401  REAL amax, anorm, bignum, colcnd, rcmax, rcmin,
402  $ rowcnd, rpvgrw, smlnum
403 * ..
404 * .. External Functions ..
405  LOGICAL lsame
406  REAL slamch, slangb, slantb
407  EXTERNAL lsame, slamch, slangb, slantb
408 * ..
409 * .. External Subroutines ..
410  EXTERNAL scopy, sgbcon, sgbequ, sgbrfs, sgbtrf, sgbtrs,
411  $ slacpy, slaqgb, xerbla
412 * ..
413 * .. Intrinsic Functions ..
414  INTRINSIC abs, max, min
415 * ..
416 * .. Executable Statements ..
417 *
418  info = 0
419  nofact = lsame( fact, 'N' )
420  equil = lsame( fact, 'E' )
421  notran = lsame( trans, 'N' )
422  IF( nofact .OR. equil ) THEN
423  equed = 'N'
424  rowequ = .false.
425  colequ = .false.
426  ELSE
427  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
428  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
429  smlnum = slamch( 'Safe minimum' )
430  bignum = one / smlnum
431  END IF
432 *
433 * Test the input parameters.
434 *
435  IF( .NOT.nofact .AND. .NOT.equil .AND. .NOT.lsame( fact, 'F' ) )
436  $ THEN
437  info = -1
438  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
439  $ lsame( trans, 'C' ) ) THEN
440  info = -2
441  ELSE IF( n.LT.0 ) THEN
442  info = -3
443  ELSE IF( kl.LT.0 ) THEN
444  info = -4
445  ELSE IF( ku.LT.0 ) THEN
446  info = -5
447  ELSE IF( nrhs.LT.0 ) THEN
448  info = -6
449  ELSE IF( ldab.LT.kl+ku+1 ) THEN
450  info = -8
451  ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
452  info = -10
453  ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
454  $ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
455  info = -12
456  ELSE
457  IF( rowequ ) THEN
458  rcmin = bignum
459  rcmax = zero
460  DO 10 j = 1, n
461  rcmin = min( rcmin, r( j ) )
462  rcmax = max( rcmax, r( j ) )
463  10 CONTINUE
464  IF( rcmin.LE.zero ) THEN
465  info = -13
466  ELSE IF( n.GT.0 ) THEN
467  rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
468  ELSE
469  rowcnd = one
470  END IF
471  END IF
472  IF( colequ .AND. info.EQ.0 ) THEN
473  rcmin = bignum
474  rcmax = zero
475  DO 20 j = 1, n
476  rcmin = min( rcmin, c( j ) )
477  rcmax = max( rcmax, c( j ) )
478  20 CONTINUE
479  IF( rcmin.LE.zero ) THEN
480  info = -14
481  ELSE IF( n.GT.0 ) THEN
482  colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
483  ELSE
484  colcnd = one
485  END IF
486  END IF
487  IF( info.EQ.0 ) THEN
488  IF( ldb.LT.max( 1, n ) ) THEN
489  info = -16
490  ELSE IF( ldx.LT.max( 1, n ) ) THEN
491  info = -18
492  END IF
493  END IF
494  END IF
495 *
496  IF( info.NE.0 ) THEN
497  CALL xerbla( 'SGBSVX', -info )
498  RETURN
499  END IF
500 *
501  IF( equil ) THEN
502 *
503 * Compute row and column scalings to equilibrate the matrix A.
504 *
505  CALL sgbequ( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
506  $ amax, infequ )
507  IF( infequ.EQ.0 ) THEN
508 *
509 * Equilibrate the matrix.
510 *
511  CALL slaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
512  $ amax, equed )
513  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
514  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
515  END IF
516  END IF
517 *
518 * Scale the right hand side.
519 *
520  IF( notran ) THEN
521  IF( rowequ ) THEN
522  DO 40 j = 1, nrhs
523  DO 30 i = 1, n
524  b( i, j ) = r( i )*b( i, j )
525  30 CONTINUE
526  40 CONTINUE
527  END IF
528  ELSE IF( colequ ) THEN
529  DO 60 j = 1, nrhs
530  DO 50 i = 1, n
531  b( i, j ) = c( i )*b( i, j )
532  50 CONTINUE
533  60 CONTINUE
534  END IF
535 *
536  IF( nofact .OR. equil ) THEN
537 *
538 * Compute the LU factorization of the band matrix A.
539 *
540  DO 70 j = 1, n
541  j1 = max( j-ku, 1 )
542  j2 = min( j+kl, n )
543  CALL scopy( j2-j1+1, ab( ku+1-j+j1, j ), 1,
544  $ afb( kl+ku+1-j+j1, j ), 1 )
545  70 CONTINUE
546 *
547  CALL sgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
548 *
549 * Return if INFO is non-zero.
550 *
551  IF( info.GT.0 ) THEN
552 *
553 * Compute the reciprocal pivot growth factor of the
554 * leading rank-deficient INFO columns of A.
555 *
556  anorm = zero
557  DO 90 j = 1, info
558  DO 80 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
559  anorm = max( anorm, abs( ab( i, j ) ) )
560  80 CONTINUE
561  90 CONTINUE
562  rpvgrw = slantb( 'M', 'U', 'N', info, min( info-1, kl+ku ),
563  $ afb( max( 1, kl+ku+2-info ), 1 ), ldafb,
564  $ work )
565  IF( rpvgrw.EQ.zero ) THEN
566  rpvgrw = one
567  ELSE
568  rpvgrw = anorm / rpvgrw
569  END IF
570  work( 1 ) = rpvgrw
571  rcond = zero
572  RETURN
573  END IF
574  END IF
575 *
576 * Compute the norm of the matrix A and the
577 * reciprocal pivot growth factor RPVGRW.
578 *
579  IF( notran ) THEN
580  norm = '1'
581  ELSE
582  norm = 'I'
583  END IF
584  anorm = slangb( norm, n, kl, ku, ab, ldab, work )
585  rpvgrw = slantb( 'M', 'U', 'N', n, kl+ku, afb, ldafb, work )
586  IF( rpvgrw.EQ.zero ) THEN
587  rpvgrw = one
588  ELSE
589  rpvgrw = slangb( 'M', n, kl, ku, ab, ldab, work ) / rpvgrw
590  END IF
591 *
592 * Compute the reciprocal of the condition number of A.
593 *
594  CALL sgbcon( norm, n, kl, ku, afb, ldafb, ipiv, anorm, rcond,
595  $ work, iwork, info )
596 *
597 * Compute the solution matrix X.
598 *
599  CALL slacpy( 'Full', n, nrhs, b, ldb, x, ldx )
600  CALL sgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
601  $ info )
602 *
603 * Use iterative refinement to improve the computed solution and
604 * compute error bounds and backward error estimates for it.
605 *
606  CALL sgbrfs( trans, n, kl, ku, nrhs, ab, ldab, afb, ldafb, ipiv,
607  $ b, ldb, x, ldx, ferr, berr, work, iwork, info )
608 *
609 * Transform the solution matrix X to a solution of the original
610 * system.
611 *
612  IF( notran ) THEN
613  IF( colequ ) THEN
614  DO 110 j = 1, nrhs
615  DO 100 i = 1, n
616  x( i, j ) = c( i )*x( i, j )
617  100 CONTINUE
618  110 CONTINUE
619  DO 120 j = 1, nrhs
620  ferr( j ) = ferr( j ) / colcnd
621  120 CONTINUE
622  END IF
623  ELSE IF( rowequ ) THEN
624  DO 140 j = 1, nrhs
625  DO 130 i = 1, n
626  x( i, j ) = r( i )*x( i, j )
627  130 CONTINUE
628  140 CONTINUE
629  DO 150 j = 1, nrhs
630  ferr( j ) = ferr( j ) / rowcnd
631  150 CONTINUE
632  END IF
633 *
634 * Set INFO = N+1 if the matrix is singular to working precision.
635 *
636  IF( rcond.LT.slamch( 'Epsilon' ) )
637  $ info = n + 1
638 *
639  work( 1 ) = rpvgrw
640  RETURN
641 *
642 * End of SGBSVX
643 *
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
real function slantb(NORM, UPLO, DIAG, N, K, AB, LDAB, WORK)
SLANTB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a triangular band matrix.
Definition: slantb.f:142
subroutine sgbtrf(M, N, KL, KU, AB, LDAB, IPIV, INFO)
SGBTRF
Definition: sgbtrf.f:146
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:53
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine slaqgb(M, N, KL, KU, AB, LDAB, R, C, ROWCND, COLCND, AMAX, EQUED)
SLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ...
Definition: slaqgb.f:161
subroutine sgbequ(M, N, KL, KU, AB, LDAB, R, C, ROWCND, COLCND, AMAX, INFO)
SGBEQU
Definition: sgbequ.f:155
subroutine sgbtrs(TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
SGBTRS
Definition: sgbtrs.f:140
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine sgbrfs(TRANS, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, IWORK, INFO)
SGBRFS
Definition: sgbrfs.f:207
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:105
subroutine sgbcon(NORM, N, KL, KU, AB, LDAB, IPIV, ANORM, RCOND, WORK, IWORK, INFO)
SGBCON
Definition: sgbcon.f:148
real function slangb(NORM, N, KL, KU, AB, LDAB, WORK)
SLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: slangb.f:126

Here is the call graph for this function:

Here is the caller graph for this function:

subroutine sgbsvxx ( character  FACT,
character  TRANS,
integer  N,
integer  KL,
integer  KU,
integer  NRHS,
real, dimension( ldab, * )  AB,
integer  LDAB,
real, dimension( ldafb, * )  AFB,
integer  LDAFB,
integer, dimension( * )  IPIV,
character  EQUED,
real, dimension( * )  R,
real, dimension( * )  C,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( ldx , * )  X,
integer  LDX,
real  RCOND,
real  RPVGRW,
real, dimension( * )  BERR,
integer  N_ERR_BNDS,
real, dimension( nrhs, * )  ERR_BNDS_NORM,
real, dimension( nrhs, * )  ERR_BNDS_COMP,
integer  NPARAMS,
real, dimension( * )  PARAMS,
real, dimension( * )  WORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

SGBSVXX computes the solution to system of linear equations A * X = B for GB matrices

Download SGBSVXX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
    SGBSVXX uses the LU factorization to compute the solution to a
    real system of linear equations  A * X = B,  where A is an
    N-by-N matrix and X and B are N-by-NRHS matrices.

    If requested, both normwise and maximum componentwise error bounds
    are returned. SGBSVXX will return a solution with a tiny
    guaranteed error (O(eps) where eps is the working machine
    precision) unless the matrix is very ill-conditioned, in which
    case a warning is returned. Relevant condition numbers also are
    calculated and returned.

    SGBSVXX accepts user-provided factorizations and equilibration
    factors; see the definitions of the FACT and EQUED options.
    Solving with refinement and using a factorization from a previous
    SGBSVXX call will also produce a solution with either O(eps)
    errors or warnings, but we cannot make that claim for general
    user-provided factorizations and equilibration factors if they
    differ from what SGBSVXX would itself produce.
Description:
    The following steps are performed:

    1. If FACT = 'E', real scaling factors are computed to equilibrate
    the system:

      TRANS = 'N':  diag(R)*A*diag(C)     *inv(diag(C))*X = diag(R)*B
      TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
      TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B

    Whether or not the system will be equilibrated depends on the
    scaling of the matrix A, but if equilibration is used, A is
    overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
    or diag(C)*B (if TRANS = 'T' or 'C').

    2. If FACT = 'N' or 'E', the LU decomposition is used to factor
    the matrix A (after equilibration if FACT = 'E') as

      A = P * L * U,

    where P is a permutation matrix, L is a unit lower triangular
    matrix, and U is upper triangular.

    3. If some U(i,i)=0, so that U is exactly singular, then the
    routine returns with INFO = i. Otherwise, the factored form of A
    is used to estimate the condition number of the matrix A (see
    argument RCOND). If the reciprocal of the condition number is less
    than machine precision, the routine still goes on to solve for X
    and compute error bounds as described below.

    4. The system of equations is solved for X using the factored form
    of A.

    5. By default (unless PARAMS(LA_LINRX_ITREF_I) is set to zero),
    the routine will use iterative refinement to try to get a small
    error and error bounds.  Refinement calculates the residual to at
    least twice the working precision.

    6. If equilibration was used, the matrix X is premultiplied by
    diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
    that it solves the original system before equilibration.
     Some optional parameters are bundled in the PARAMS array.  These
     settings determine how refinement is performed, but often the
     defaults are acceptable.  If the defaults are acceptable, users
     can pass NPARAMS = 0 which prevents the source code from accessing
     the PARAMS argument.
Parameters
[in]FACT
          FACT is CHARACTER*1
     Specifies whether or not the factored form of the matrix A is
     supplied on entry, and if not, whether the matrix A should be
     equilibrated before it is factored.
       = 'F':  On entry, AF and IPIV contain the factored form of A.
               If EQUED is not 'N', the matrix A has been
               equilibrated with scaling factors given by R and C.
               A, AF, and IPIV are not modified.
       = 'N':  The matrix A will be copied to AF and factored.
       = 'E':  The matrix A will be equilibrated if necessary, then
               copied to AF and factored.
[in]TRANS
          TRANS is CHARACTER*1
     Specifies the form of the system of equations:
       = 'N':  A * X = B     (No transpose)
       = 'T':  A**T * X = B  (Transpose)
       = 'C':  A**H * X = B  (Conjugate Transpose = Transpose)
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]KL
          KL is INTEGER
     The number of subdiagonals within the band of A.  KL >= 0.
[in]KU
          KU is INTEGER
     The number of superdiagonals within the band of A.  KU >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right hand sides, i.e., the number of columns
     of the matrices B and X.  NRHS >= 0.
[in,out]AB
          AB is REAL array, dimension (LDAB,N)
     On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
     The j-th column of A is stored in the j-th column of the
     array AB as follows:
     AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)

     If FACT = 'F' and EQUED is not 'N', then AB must have been
     equilibrated by the scaling factors in R and/or C.  AB is not
     modified if FACT = 'F' or 'N', or if FACT = 'E' and
     EQUED = 'N' on exit.

     On exit, if EQUED .ne. 'N', A is scaled as follows:
     EQUED = 'R':  A := diag(R) * A
     EQUED = 'C':  A := A * diag(C)
     EQUED = 'B':  A := diag(R) * A * diag(C).
[in]LDAB
          LDAB is INTEGER
     The leading dimension of the array AB.  LDAB >= KL+KU+1.
[in,out]AFB
          AFB is REAL array, dimension (LDAFB,N)
     If FACT = 'F', then AFB is an input argument and on entry
     contains details of the LU factorization of the band matrix
     A, as computed by SGBTRF.  U is stored as an upper triangular
     band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
     and the multipliers used during the factorization are stored
     in rows KL+KU+2 to 2*KL+KU+1.  If EQUED .ne. 'N', then AFB is
     the factored form of the equilibrated matrix A.

     If FACT = 'N', then AF is an output argument and on exit
     returns the factors L and U from the factorization A = P*L*U
     of the original matrix A.

     If FACT = 'E', then AF is an output argument and on exit
     returns the factors L and U from the factorization A = P*L*U
     of the equilibrated matrix A (see the description of A for
     the form of the equilibrated matrix).
[in]LDAFB
          LDAFB is INTEGER
     The leading dimension of the array AFB.  LDAFB >= 2*KL+KU+1.
[in,out]IPIV
          IPIV is INTEGER array, dimension (N)
     If FACT = 'F', then IPIV is an input argument and on entry
     contains the pivot indices from the factorization A = P*L*U
     as computed by SGETRF; row i of the matrix was interchanged
     with row IPIV(i).

     If FACT = 'N', then IPIV is an output argument and on exit
     contains the pivot indices from the factorization A = P*L*U
     of the original matrix A.

     If FACT = 'E', then IPIV is an output argument and on exit
     contains the pivot indices from the factorization A = P*L*U
     of the equilibrated matrix A.
[in,out]EQUED
          EQUED is CHARACTER*1
     Specifies the form of equilibration that was done.
       = 'N':  No equilibration (always true if FACT = 'N').
       = 'R':  Row equilibration, i.e., A has been premultiplied by
               diag(R).
       = 'C':  Column equilibration, i.e., A has been postmultiplied
               by diag(C).
       = 'B':  Both row and column equilibration, i.e., A has been
               replaced by diag(R) * A * diag(C).
     EQUED is an input argument if FACT = 'F'; otherwise, it is an
     output argument.
[in,out]R
          R is REAL array, dimension (N)
     The row scale factors for A.  If EQUED = 'R' or 'B', A is
     multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
     is not accessed.  R is an input argument if FACT = 'F';
     otherwise, R is an output argument.  If FACT = 'F' and
     EQUED = 'R' or 'B', each element of R must be positive.
     If R is output, each element of R is a power of the radix.
     If R is input, each element of R should be a power of the radix
     to ensure a reliable solution and error estimates. Scaling by
     powers of the radix does not cause rounding errors unless the
     result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in,out]C
          C is REAL array, dimension (N)
     The column scale factors for A.  If EQUED = 'C' or 'B', A is
     multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
     is not accessed.  C is an input argument if FACT = 'F';
     otherwise, C is an output argument.  If FACT = 'F' and
     EQUED = 'C' or 'B', each element of C must be positive.
     If C is output, each element of C is a power of the radix.
     If C is input, each element of C should be a power of the radix
     to ensure a reliable solution and error estimates. Scaling by
     powers of the radix does not cause rounding errors unless the
     result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in,out]B
          B is REAL array, dimension (LDB,NRHS)
     On entry, the N-by-NRHS right hand side matrix B.
     On exit,
     if EQUED = 'N', B is not modified;
     if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by
        diag(R)*B;
     if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is
        overwritten by diag(C)*B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[out]X
          X is REAL array, dimension (LDX,NRHS)
     If INFO = 0, the N-by-NRHS solution matrix X to the original
     system of equations.  Note that A and B are modified on exit
     if EQUED .ne. 'N', and the solution to the equilibrated system is
     inv(diag(C))*X if TRANS = 'N' and EQUED = 'C' or 'B', or
     inv(diag(R))*X if TRANS = 'T' or 'C' and EQUED = 'R' or 'B'.
[in]LDX
          LDX is INTEGER
     The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is REAL
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[out]RPVGRW
          RPVGRW is REAL
     Reciprocal pivot growth.  On exit, this contains the reciprocal
     pivot growth factor norm(A)/norm(U). The "max absolute element"
     norm is used.  If this is much less than 1, then the stability of
     the LU factorization of the (equilibrated) matrix A could be poor.
     This also means that the solution X, estimated condition numbers,
     and error bounds could be unreliable. If factorization fails with
     0<INFO<=N, then this contains the reciprocal pivot growth factor
     for the leading INFO columns of A.  In SGESVX, this quantity is
     returned in WORK(1).
[out]BERR
          BERR is REAL array, dimension (NRHS)
     Componentwise relative backward error.  This is the
     componentwise relative backward error of each solution vector X(j)
     (i.e., the smallest relative change in any element of A or B that
     makes X(j) an exact solution).
[in]N_ERR_BNDS
          N_ERR_BNDS is INTEGER
     Number of error bounds to return for each right hand side
     and each type (normwise or componentwise).  See ERR_BNDS_NORM and
     ERR_BNDS_COMP below.
[out]ERR_BNDS_NORM
          ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[out]ERR_BNDS_COMP
          ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[in]NPARAMS
          NPARAMS is INTEGER
     Specifies the number of parameters set in PARAMS.  If .LE. 0, the
     PARAMS array is never referenced and default values are used.
[in,out]PARAMS
          PARAMS is REAL array, dimension NPARAMS
     Specifies algorithm parameters.  If an entry is .LT. 0.0, then
     that entry will be filled with default value used for that
     parameter.  Only positions up to NPARAMS are accessed; defaults
     are used for higher-numbered parameters.

       PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
            refinement or not.
         Default: 1.0
            = 0.0 : No refinement is performed, and no error bounds are
                    computed.
            = 1.0 : Use the double-precision refinement algorithm,
                    possibly with doubled-single computations if the
                    compilation environment does not support DOUBLE
                    PRECISION.
              (other values are reserved for future use)

       PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
            computations allowed for refinement.
         Default: 10
         Aggressive: Set to 100 to permit convergence using approximate
                     factorizations or factorizations other than LU. If
                     the factorization uses a technique other than
                     Gaussian elimination, the guarantees in
                     err_bnds_norm and err_bnds_comp may no longer be
                     trustworthy.

       PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
            will attempt to find a solution with small componentwise
            relative error in the double-precision algorithm.  Positive
            is true, 0.0 is false.
         Default: 1.0 (attempt componentwise convergence)
[out]WORK
          WORK is REAL array, dimension (4*N)
[out]IWORK
          IWORK is INTEGER array, dimension (N)
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit. The solution to every right-hand side is
         guaranteed.
       < 0:  If INFO = -i, the i-th argument had an illegal value
       > 0 and <= N:  U(INFO,INFO) is exactly zero.  The factorization
         has been completed, but the factor U is exactly singular, so
         the solution and error bounds could not be computed. RCOND = 0
         is returned.
       = N+J: The solution corresponding to the Jth right-hand side is
         not guaranteed. The solutions corresponding to other right-
         hand sides K with K > J may not be guaranteed as well, but
         only the first such right-hand side is reported. If a small
         componentwise error is not requested (PARAMS(3) = 0.0) then
         the Jth right-hand side is the first with a normwise error
         bound that is not guaranteed (the smallest J such
         that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
         the Jth right-hand side is the first with either a normwise or
         componentwise error bound that is not guaranteed (the smallest
         J such that either ERR_BNDS_NORM(J,1) = 0.0 or
         ERR_BNDS_COMP(J,1) = 0.0). See the definition of
         ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
         about all of the right-hand sides check ERR_BNDS_NORM or
         ERR_BNDS_COMP.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
April 2012

Definition at line 565 of file sgbsvxx.f.

565 *
566 * -- LAPACK driver routine (version 3.4.1) --
567 * -- LAPACK is a software package provided by Univ. of Tennessee, --
568 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
569 * April 2012
570 *
571 * .. Scalar Arguments ..
572  CHARACTER equed, fact, trans
573  INTEGER info, ldab, ldafb, ldb, ldx, n, nrhs, nparams,
574  $ n_err_bnds
575  REAL rcond, rpvgrw
576 * ..
577 * .. Array Arguments ..
578  INTEGER ipiv( * ), iwork( * )
579  REAL ab( ldab, * ), afb( ldafb, * ), b( ldb, * ),
580  $ x( ldx , * ),work( * )
581  REAL r( * ), c( * ), params( * ), berr( * ),
582  $ err_bnds_norm( nrhs, * ),
583  $ err_bnds_comp( nrhs, * )
584 * ..
585 *
586 * ==================================================================
587 *
588 * .. Parameters ..
589  REAL zero, one
590  parameter( zero = 0.0e+0, one = 1.0e+0 )
591  INTEGER final_nrm_err_i, final_cmp_err_i, berr_i
592  INTEGER rcond_i, nrm_rcond_i, nrm_err_i, cmp_rcond_i
593  INTEGER cmp_err_i, piv_growth_i
594  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
595  $ berr_i = 3 )
596  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
597  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
598  $ piv_growth_i = 9 )
599 * ..
600 * .. Local Scalars ..
601  LOGICAL colequ, equil, nofact, notran, rowequ
602  INTEGER infequ, i, j, kl, ku
603  REAL amax, bignum, colcnd, rcmax, rcmin,
604  $ rowcnd, smlnum
605 * ..
606 * .. External Functions ..
607  EXTERNAL lsame, slamch, sla_gbrpvgrw
608  LOGICAL lsame
609  REAL slamch, sla_gbrpvgrw
610 * ..
611 * .. External Subroutines ..
612  EXTERNAL sgbequb, sgbtrf, sgbtrs, slacpy, slaqgb,
614 * ..
615 * .. Intrinsic Functions ..
616  INTRINSIC max, min
617 * ..
618 * .. Executable Statements ..
619 *
620  info = 0
621  nofact = lsame( fact, 'N' )
622  equil = lsame( fact, 'E' )
623  notran = lsame( trans, 'N' )
624  smlnum = slamch( 'Safe minimum' )
625  bignum = one / smlnum
626  IF( nofact .OR. equil ) THEN
627  equed = 'N'
628  rowequ = .false.
629  colequ = .false.
630  ELSE
631  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
632  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
633  END IF
634 *
635 * Default is failure. If an input parameter is wrong or
636 * factorization fails, make everything look horrible. Only the
637 * pivot growth is set here, the rest is initialized in SGBRFSX.
638 *
639  rpvgrw = zero
640 *
641 * Test the input parameters. PARAMS is not tested until SGBRFSX.
642 *
643  IF( .NOT.nofact .AND. .NOT.equil .AND. .NOT.
644  $ lsame( fact, 'F' ) ) THEN
645  info = -1
646  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
647  $ lsame( trans, 'C' ) ) THEN
648  info = -2
649  ELSE IF( n.LT.0 ) THEN
650  info = -3
651  ELSE IF( kl.LT.0 ) THEN
652  info = -4
653  ELSE IF( ku.LT.0 ) THEN
654  info = -5
655  ELSE IF( nrhs.LT.0 ) THEN
656  info = -6
657  ELSE IF( ldab.LT.kl+ku+1 ) THEN
658  info = -8
659  ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
660  info = -10
661  ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
662  $ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
663  info = -12
664  ELSE
665  IF( rowequ ) THEN
666  rcmin = bignum
667  rcmax = zero
668  DO 10 j = 1, n
669  rcmin = min( rcmin, r( j ) )
670  rcmax = max( rcmax, r( j ) )
671  10 CONTINUE
672  IF( rcmin.LE.zero ) THEN
673  info = -13
674  ELSE IF( n.GT.0 ) THEN
675  rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
676  ELSE
677  rowcnd = one
678  END IF
679  END IF
680  IF( colequ .AND. info.EQ.0 ) THEN
681  rcmin = bignum
682  rcmax = zero
683  DO 20 j = 1, n
684  rcmin = min( rcmin, c( j ) )
685  rcmax = max( rcmax, c( j ) )
686  20 CONTINUE
687  IF( rcmin.LE.zero ) THEN
688  info = -14
689  ELSE IF( n.GT.0 ) THEN
690  colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
691  ELSE
692  colcnd = one
693  END IF
694  END IF
695  IF( info.EQ.0 ) THEN
696  IF( ldb.LT.max( 1, n ) ) THEN
697  info = -15
698  ELSE IF( ldx.LT.max( 1, n ) ) THEN
699  info = -16
700  END IF
701  END IF
702  END IF
703 *
704  IF( info.NE.0 ) THEN
705  CALL xerbla( 'SGBSVXX', -info )
706  RETURN
707  END IF
708 *
709  IF( equil ) THEN
710 *
711 * Compute row and column scalings to equilibrate the matrix A.
712 *
713  CALL sgbequb( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
714  $ amax, infequ )
715  IF( infequ.EQ.0 ) THEN
716 *
717 * Equilibrate the matrix.
718 *
719  CALL slaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
720  $ amax, equed )
721  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
722  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
723  END IF
724 *
725 * If the scaling factors are not applied, set them to 1.0.
726 *
727  IF ( .NOT.rowequ ) THEN
728  DO j = 1, n
729  r( j ) = 1.0
730  END DO
731  END IF
732  IF ( .NOT.colequ ) THEN
733  DO j = 1, n
734  c( j ) = 1.0
735  END DO
736  END IF
737  END IF
738 *
739 * Scale the right hand side.
740 *
741  IF( notran ) THEN
742  IF( rowequ ) CALL slascl2(n, nrhs, r, b, ldb)
743  ELSE
744  IF( colequ ) CALL slascl2(n, nrhs, c, b, ldb)
745  END IF
746 *
747  IF( nofact .OR. equil ) THEN
748 *
749 * Compute the LU factorization of A.
750 *
751  DO 40, j = 1, n
752  DO 30, i = kl+1, 2*kl+ku+1
753  afb( i, j ) = ab( i-kl, j )
754  30 CONTINUE
755  40 CONTINUE
756  CALL sgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
757 *
758 * Return if INFO is non-zero.
759 *
760  IF( info.GT.0 ) THEN
761 *
762 * Pivot in column INFO is exactly 0
763 * Compute the reciprocal pivot growth factor of the
764 * leading rank-deficient INFO columns of A.
765 *
766  rpvgrw = sla_gbrpvgrw( n, kl, ku, info, ab, ldab, afb,
767  $ ldafb )
768  RETURN
769  END IF
770  END IF
771 *
772 * Compute the reciprocal pivot growth factor RPVGRW.
773 *
774  rpvgrw = sla_gbrpvgrw( n, kl, ku, n, ab, ldab, afb, ldafb )
775 *
776 * Compute the solution matrix X.
777 *
778  CALL slacpy( 'Full', n, nrhs, b, ldb, x, ldx )
779  CALL sgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
780  $ info )
781 *
782 * Use iterative refinement to improve the computed solution and
783 * compute error bounds and backward error estimates for it.
784 *
785  CALL sgbrfsx( trans, equed, n, kl, ku, nrhs, ab, ldab, afb, ldafb,
786  $ ipiv, r, c, b, ldb, x, ldx, rcond, berr,
787  $ n_err_bnds, err_bnds_norm, err_bnds_comp, nparams, params,
788  $ work, iwork, info )
789 *
790 * Scale solutions.
791 *
792  IF ( colequ .AND. notran ) THEN
793  CALL slascl2 ( n, nrhs, c, x, ldx )
794  ELSE IF ( rowequ .AND. .NOT.notran ) THEN
795  CALL slascl2 ( n, nrhs, r, x, ldx )
796  END IF
797 *
798  RETURN
799 *
800 * End of SGBSVXX
801 *
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
subroutine sgbtrf(M, N, KL, KU, AB, LDAB, IPIV, INFO)
SGBTRF
Definition: sgbtrf.f:146
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine slaqgb(M, N, KL, KU, AB, LDAB, R, C, ROWCND, COLCND, AMAX, EQUED)
SLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ...
Definition: slaqgb.f:161
subroutine slascl2(M, N, D, X, LDX)
SLASCL2 performs diagonal scaling on a vector.
Definition: slascl2.f:92
subroutine sgbtrs(TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
SGBTRS
Definition: sgbtrs.f:140
subroutine sgbequb(M, N, KL, KU, AB, LDAB, R, C, ROWCND, COLCND, AMAX, INFO)
SGBEQUB
Definition: sgbequb.f:162
subroutine sgbrfsx(TRANS, EQUED, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB, IPIV, R, C, B, LDB, X, LDX, RCOND, BERR, N_ERR_BNDS, ERR_BNDS_NORM, ERR_BNDS_COMP, NPARAMS, PARAMS, WORK, IWORK, INFO)
SGBRFSX
Definition: sgbrfsx.f:442
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:105
real function sla_gbrpvgrw(N, KL, KU, NCOLS, AB, LDAB, AFB, LDAFB)
SLA_GBRPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a general banded matrix...
Definition: sla_gbrpvgrw.f:119

Here is the call graph for this function:

Here is the caller graph for this function: