 LAPACK  3.9.0 LAPACK: Linear Algebra PACKage

## ◆ zlangb()

 double precision function zlangb ( character NORM, integer N, integer KL, integer KU, complex*16, dimension( ldab, * ) AB, integer LDAB, double precision, dimension( * ) WORK )

ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.

Purpose:
``` ZLANGB  returns the value of the one norm,  or the Frobenius norm, or
the  infinity norm,  or the element of  largest absolute value  of an
n by n band matrix  A,  with kl sub-diagonals and ku super-diagonals.```
Returns
ZLANGB
```    ZLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
(
( norm1(A),         NORM = '1', 'O' or 'o'
(
( normI(A),         NORM = 'I' or 'i'
(
( normF(A),         NORM = 'F', 'f', 'E' or 'e'

where  norm1  denotes the  one norm of a matrix (maximum column sum),
normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
normF  denotes the  Frobenius norm of a matrix (square root of sum of
squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.```
Parameters
 [in] NORM ``` NORM is CHARACTER*1 Specifies the value to be returned in ZLANGB as described above.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0. When N = 0, ZLANGB is set to zero.``` [in] KL ``` KL is INTEGER The number of sub-diagonals of the matrix A. KL >= 0.``` [in] KU ``` KU is INTEGER The number of super-diagonals of the matrix A. KU >= 0.``` [in] AB ``` AB is COMPLEX*16 array, dimension (LDAB,N) The band matrix A, stored in rows 1 to KL+KU+1. The j-th column of A is stored in the j-th column of the array AB as follows: AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).``` [in] LDAB ``` LDAB is INTEGER The leading dimension of the array AB. LDAB >= KL+KU+1.``` [out] WORK ``` WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)), where LWORK >= N when NORM = 'I'; otherwise, WORK is not referenced.```
Date
December 2016

Definition at line 127 of file zlangb.f.

127 *
128 * -- LAPACK auxiliary routine (version 3.7.0) --
129 * -- LAPACK is a software package provided by Univ. of Tennessee, --
130 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
131 * December 2016
132 *
133  IMPLICIT NONE
134 * .. Scalar Arguments ..
135  CHARACTER NORM
136  INTEGER KL, KU, LDAB, N
137 * ..
138 * .. Array Arguments ..
139  DOUBLE PRECISION WORK( * )
140  COMPLEX*16 AB( LDAB, * )
141 * ..
142 *
143 * =====================================================================
144 *
145 * .. Parameters ..
146  DOUBLE PRECISION ONE, ZERO
147  parameter( one = 1.0d+0, zero = 0.0d+0 )
148 * ..
149 * .. Local Scalars ..
150  INTEGER I, J, K, L
151  DOUBLE PRECISION SUM, VALUE, TEMP
152 * ..
153 * .. Local Arrays ..
154  DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
155 * ..
156 * .. External Functions ..
157  LOGICAL LSAME, DISNAN
158  EXTERNAL lsame, disnan
159 * ..
160 * .. External Subroutines ..
161  EXTERNAL zlassq, dcombssq
162 * ..
163 * .. Intrinsic Functions ..
164  INTRINSIC abs, max, min, sqrt
165 * ..
166 * .. Executable Statements ..
167 *
168  IF( n.EQ.0 ) THEN
169  VALUE = zero
170  ELSE IF( lsame( norm, 'M' ) ) THEN
171 *
172 * Find max(abs(A(i,j))).
173 *
174  VALUE = zero
175  DO 20 j = 1, n
176  DO 10 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
177  temp = abs( ab( i, j ) )
178  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
179  10 CONTINUE
180  20 CONTINUE
181  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
182 *
183 * Find norm1(A).
184 *
185  VALUE = zero
186  DO 40 j = 1, n
187  sum = zero
188  DO 30 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
189  sum = sum + abs( ab( i, j ) )
190  30 CONTINUE
191  IF( VALUE.LT.sum .OR. disnan( sum ) ) VALUE = sum
192  40 CONTINUE
193  ELSE IF( lsame( norm, 'I' ) ) THEN
194 *
195 * Find normI(A).
196 *
197  DO 50 i = 1, n
198  work( i ) = zero
199  50 CONTINUE
200  DO 70 j = 1, n
201  k = ku + 1 - j
202  DO 60 i = max( 1, j-ku ), min( n, j+kl )
203  work( i ) = work( i ) + abs( ab( k+i, j ) )
204  60 CONTINUE
205  70 CONTINUE
206  VALUE = zero
207  DO 80 i = 1, n
208  temp = work( i )
209  IF( VALUE.LT.temp .OR. disnan( temp ) ) VALUE = temp
210  80 CONTINUE
211  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
212 *
213 * Find normF(A).
214 * SSQ(1) is scale
215 * SSQ(2) is sum-of-squares
216 * For better accuracy, sum each column separately.
217 *
218  ssq( 1 ) = zero
219  ssq( 2 ) = one
220  DO 90 j = 1, n
221  l = max( 1, j-ku )
222  k = ku + 1 - j + l
223  colssq( 1 ) = zero
224  colssq( 2 ) = one
225  CALL zlassq( min( n, j+kl )-l+1, ab( k, j ), 1,
226  \$ colssq( 1 ), colssq( 2 ) )
227  CALL dcombssq( ssq, colssq )
228  90 CONTINUE
229  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
230  END IF
231 *
232  zlangb = VALUE
233  RETURN
234 *
235 * End of ZLANGB
236 *
Here is the call graph for this function:
Here is the caller graph for this function:
zlassq
subroutine zlassq(N, X, INCX, SCALE, SUMSQ)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f:108
disnan
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:61
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
zlangb
double precision function zlangb(NORM, N, KL, KU, AB, LDAB, WORK)
ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlangb.f:127
dcombssq
subroutine dcombssq(V1, V2)
DCOMBSSQ adds two scaled sum of squares quantities.
Definition: dcombssq.f:62