 LAPACK  3.8.0 LAPACK: Linear Algebra PACKage

## ◆ zggsvp()

 subroutine zggsvp ( character JOBU, character JOBV, character JOBQ, integer M, integer P, integer N, complex*16, dimension( lda, * ) A, integer LDA, complex*16, dimension( ldb, * ) B, integer LDB, double precision TOLA, double precision TOLB, integer K, integer L, complex*16, dimension( ldu, * ) U, integer LDU, complex*16, dimension( ldv, * ) V, integer LDV, complex*16, dimension( ldq, * ) Q, integer LDQ, integer, dimension( * ) IWORK, double precision, dimension( * ) RWORK, complex*16, dimension( * ) TAU, complex*16, dimension( * ) WORK, integer INFO )

ZGGSVP

Purpose:
``` This routine is deprecated and has been replaced by routine ZGGSVP3.

ZGGSVP computes unitary matrices U, V and Q such that

N-K-L  K    L
U**H*A*Q =     K ( 0    A12  A13 )  if M-K-L >= 0;
L ( 0     0   A23 )
M-K-L ( 0     0    0  )

N-K-L  K    L
=     K ( 0    A12  A13 )  if M-K-L < 0;
M-K ( 0     0   A23 )

N-K-L  K    L
V**H*B*Q =   L ( 0     0   B13 )
P-L ( 0     0    0  )

where the K-by-K matrix A12 and L-by-L matrix B13 are nonsingular
upper triangular; A23 is L-by-L upper triangular if M-K-L >= 0,
otherwise A23 is (M-K)-by-L upper trapezoidal.  K+L = the effective
numerical rank of the (M+P)-by-N matrix (A**H,B**H)**H.

This decomposition is the preprocessing step for computing the
Generalized Singular Value Decomposition (GSVD), see subroutine
ZGGSVD.```
Parameters
 [in] JOBU ``` JOBU is CHARACTER*1 = 'U': Unitary matrix U is computed; = 'N': U is not computed.``` [in] JOBV ``` JOBV is CHARACTER*1 = 'V': Unitary matrix V is computed; = 'N': V is not computed.``` [in] JOBQ ``` JOBQ is CHARACTER*1 = 'Q': Unitary matrix Q is computed; = 'N': Q is not computed.``` [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] P ``` P is INTEGER The number of rows of the matrix B. P >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrices A and B. N >= 0.``` [in,out] A ``` A is COMPLEX*16 array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, A contains the triangular (or trapezoidal) matrix described in the Purpose section.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).``` [in,out] B ``` B is COMPLEX*16 array, dimension (LDB,N) On entry, the P-by-N matrix B. On exit, B contains the triangular matrix described in the Purpose section.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,P).``` [in] TOLA ` TOLA is DOUBLE PRECISION` [in] TOLB ``` TOLB is DOUBLE PRECISION TOLA and TOLB are the thresholds to determine the effective numerical rank of matrix B and a subblock of A. Generally, they are set to TOLA = MAX(M,N)*norm(A)*MAZHEPS, TOLB = MAX(P,N)*norm(B)*MAZHEPS. The size of TOLA and TOLB may affect the size of backward errors of the decomposition.``` [out] K ` K is INTEGER` [out] L ``` L is INTEGER On exit, K and L specify the dimension of the subblocks described in Purpose section. K + L = effective numerical rank of (A**H,B**H)**H.``` [out] U ``` U is COMPLEX*16 array, dimension (LDU,M) If JOBU = 'U', U contains the unitary matrix U. If JOBU = 'N', U is not referenced.``` [in] LDU ``` LDU is INTEGER The leading dimension of the array U. LDU >= max(1,M) if JOBU = 'U'; LDU >= 1 otherwise.``` [out] V ``` V is COMPLEX*16 array, dimension (LDV,P) If JOBV = 'V', V contains the unitary matrix V. If JOBV = 'N', V is not referenced.``` [in] LDV ``` LDV is INTEGER The leading dimension of the array V. LDV >= max(1,P) if JOBV = 'V'; LDV >= 1 otherwise.``` [out] Q ``` Q is COMPLEX*16 array, dimension (LDQ,N) If JOBQ = 'Q', Q contains the unitary matrix Q. If JOBQ = 'N', Q is not referenced.``` [in] LDQ ``` LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N) if JOBQ = 'Q'; LDQ >= 1 otherwise.``` [out] IWORK ` IWORK is INTEGER array, dimension (N)` [out] RWORK ` RWORK is DOUBLE PRECISION array, dimension (2*N)` [out] TAU ` TAU is COMPLEX*16 array, dimension (N)` [out] WORK ` WORK is COMPLEX*16 array, dimension (max(3*N,M,P))` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value.```
Date
December 2016
Further Details:
```  The subroutine uses LAPACK subroutine ZGEQPF for the QR factorization
with column pivoting to detect the effective numerical rank of the
a matrix. It may be replaced by a better rank determination strategy.```

Definition at line 267 of file zggsvp.f.

267 *
268 * -- LAPACK computational routine (version 3.7.0) --
269 * -- LAPACK is a software package provided by Univ. of Tennessee, --
270 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
271 * December 2016
272 *
273 * .. Scalar Arguments ..
274  CHARACTER jobq, jobu, jobv
275  INTEGER info, k, l, lda, ldb, ldq, ldu, ldv, m, n, p
276  DOUBLE PRECISION tola, tolb
277 * ..
278 * .. Array Arguments ..
279  INTEGER iwork( * )
280  DOUBLE PRECISION rwork( * )
281  COMPLEX*16 a( lda, * ), b( ldb, * ), q( ldq, * ),
282  \$ tau( * ), u( ldu, * ), v( ldv, * ), work( * )
283 * ..
284 *
285 * =====================================================================
286 *
287 * .. Parameters ..
288  COMPLEX*16 czero, cone
289  parameter( czero = ( 0.0d+0, 0.0d+0 ),
290  \$ cone = ( 1.0d+0, 0.0d+0 ) )
291 * ..
292 * .. Local Scalars ..
293  LOGICAL forwrd, wantq, wantu, wantv
294  INTEGER i, j
295  COMPLEX*16 t
296 * ..
297 * .. External Functions ..
298  LOGICAL lsame
299  EXTERNAL lsame
300 * ..
301 * .. External Subroutines ..
302  EXTERNAL xerbla, zgeqpf, zgeqr2, zgerq2, zlacpy, zlapmt,
304 * ..
305 * .. Intrinsic Functions ..
306  INTRINSIC abs, dble, dimag, max, min
307 * ..
308 * .. Statement Functions ..
309  DOUBLE PRECISION cabs1
310 * ..
311 * .. Statement Function definitions ..
312  cabs1( t ) = abs( dble( t ) ) + abs( dimag( t ) )
313 * ..
314 * .. Executable Statements ..
315 *
316 * Test the input parameters
317 *
318  wantu = lsame( jobu, 'U' )
319  wantv = lsame( jobv, 'V' )
320  wantq = lsame( jobq, 'Q' )
321  forwrd = .true.
322 *
323  info = 0
324  IF( .NOT.( wantu .OR. lsame( jobu, 'N' ) ) ) THEN
325  info = -1
326  ELSE IF( .NOT.( wantv .OR. lsame( jobv, 'N' ) ) ) THEN
327  info = -2
328  ELSE IF( .NOT.( wantq .OR. lsame( jobq, 'N' ) ) ) THEN
329  info = -3
330  ELSE IF( m.LT.0 ) THEN
331  info = -4
332  ELSE IF( p.LT.0 ) THEN
333  info = -5
334  ELSE IF( n.LT.0 ) THEN
335  info = -6
336  ELSE IF( lda.LT.max( 1, m ) ) THEN
337  info = -8
338  ELSE IF( ldb.LT.max( 1, p ) ) THEN
339  info = -10
340  ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
341  info = -16
342  ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
343  info = -18
344  ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
345  info = -20
346  END IF
347  IF( info.NE.0 ) THEN
348  CALL xerbla( 'ZGGSVP', -info )
349  RETURN
350  END IF
351 *
352 * QR with column pivoting of B: B*P = V*( S11 S12 )
353 * ( 0 0 )
354 *
355  DO 10 i = 1, n
356  iwork( i ) = 0
357  10 CONTINUE
358  CALL zgeqpf( p, n, b, ldb, iwork, tau, work, rwork, info )
359 *
360 * Update A := A*P
361 *
362  CALL zlapmt( forwrd, m, n, a, lda, iwork )
363 *
364 * Determine the effective rank of matrix B.
365 *
366  l = 0
367  DO 20 i = 1, min( p, n )
368  IF( cabs1( b( i, i ) ).GT.tolb )
369  \$ l = l + 1
370  20 CONTINUE
371 *
372  IF( wantv ) THEN
373 *
374 * Copy the details of V, and form V.
375 *
376  CALL zlaset( 'Full', p, p, czero, czero, v, ldv )
377  IF( p.GT.1 )
378  \$ CALL zlacpy( 'Lower', p-1, n, b( 2, 1 ), ldb, v( 2, 1 ),
379  \$ ldv )
380  CALL zung2r( p, p, min( p, n ), v, ldv, tau, work, info )
381  END IF
382 *
383 * Clean up B
384 *
385  DO 40 j = 1, l - 1
386  DO 30 i = j + 1, l
387  b( i, j ) = czero
388  30 CONTINUE
389  40 CONTINUE
390  IF( p.GT.l )
391  \$ CALL zlaset( 'Full', p-l, n, czero, czero, b( l+1, 1 ), ldb )
392 *
393  IF( wantq ) THEN
394 *
395 * Set Q = I and Update Q := Q*P
396 *
397  CALL zlaset( 'Full', n, n, czero, cone, q, ldq )
398  CALL zlapmt( forwrd, n, n, q, ldq, iwork )
399  END IF
400 *
401  IF( p.GE.l .AND. n.NE.l ) THEN
402 *
403 * RQ factorization of ( S11 S12 ) = ( 0 S12 )*Z
404 *
405  CALL zgerq2( l, n, b, ldb, tau, work, info )
406 *
407 * Update A := A*Z**H
408 *
409  CALL zunmr2( 'Right', 'Conjugate transpose', m, n, l, b, ldb,
410  \$ tau, a, lda, work, info )
411  IF( wantq ) THEN
412 *
413 * Update Q := Q*Z**H
414 *
415  CALL zunmr2( 'Right', 'Conjugate transpose', n, n, l, b,
416  \$ ldb, tau, q, ldq, work, info )
417  END IF
418 *
419 * Clean up B
420 *
421  CALL zlaset( 'Full', l, n-l, czero, czero, b, ldb )
422  DO 60 j = n - l + 1, n
423  DO 50 i = j - n + l + 1, l
424  b( i, j ) = czero
425  50 CONTINUE
426  60 CONTINUE
427 *
428  END IF
429 *
430 * Let N-L L
431 * A = ( A11 A12 ) M,
432 *
433 * then the following does the complete QR decomposition of A11:
434 *
435 * A11 = U*( 0 T12 )*P1**H
436 * ( 0 0 )
437 *
438  DO 70 i = 1, n - l
439  iwork( i ) = 0
440  70 CONTINUE
441  CALL zgeqpf( m, n-l, a, lda, iwork, tau, work, rwork, info )
442 *
443 * Determine the effective rank of A11
444 *
445  k = 0
446  DO 80 i = 1, min( m, n-l )
447  IF( cabs1( a( i, i ) ).GT.tola )
448  \$ k = k + 1
449  80 CONTINUE
450 *
451 * Update A12 := U**H*A12, where A12 = A( 1:M, N-L+1:N )
452 *
453  CALL zunm2r( 'Left', 'Conjugate transpose', m, l, min( m, n-l ),
454  \$ a, lda, tau, a( 1, n-l+1 ), lda, work, info )
455 *
456  IF( wantu ) THEN
457 *
458 * Copy the details of U, and form U
459 *
460  CALL zlaset( 'Full', m, m, czero, czero, u, ldu )
461  IF( m.GT.1 )
462  \$ CALL zlacpy( 'Lower', m-1, n-l, a( 2, 1 ), lda, u( 2, 1 ),
463  \$ ldu )
464  CALL zung2r( m, m, min( m, n-l ), u, ldu, tau, work, info )
465  END IF
466 *
467  IF( wantq ) THEN
468 *
469 * Update Q( 1:N, 1:N-L ) = Q( 1:N, 1:N-L )*P1
470 *
471  CALL zlapmt( forwrd, n, n-l, q, ldq, iwork )
472  END IF
473 *
474 * Clean up A: set the strictly lower triangular part of
475 * A(1:K, 1:K) = 0, and A( K+1:M, 1:N-L ) = 0.
476 *
477  DO 100 j = 1, k - 1
478  DO 90 i = j + 1, k
479  a( i, j ) = czero
480  90 CONTINUE
481  100 CONTINUE
482  IF( m.GT.k )
483  \$ CALL zlaset( 'Full', m-k, n-l, czero, czero, a( k+1, 1 ), lda )
484 *
485  IF( n-l.GT.k ) THEN
486 *
487 * RQ factorization of ( T11 T12 ) = ( 0 T12 )*Z1
488 *
489  CALL zgerq2( k, n-l, a, lda, tau, work, info )
490 *
491  IF( wantq ) THEN
492 *
493 * Update Q( 1:N,1:N-L ) = Q( 1:N,1:N-L )*Z1**H
494 *
495  CALL zunmr2( 'Right', 'Conjugate transpose', n, n-l, k, a,
496  \$ lda, tau, q, ldq, work, info )
497  END IF
498 *
499 * Clean up A
500 *
501  CALL zlaset( 'Full', k, n-l-k, czero, czero, a, lda )
502  DO 120 j = n - l - k + 1, n - l
503  DO 110 i = j - n + l + k + 1, k
504  a( i, j ) = czero
505  110 CONTINUE
506  120 CONTINUE
507 *
508  END IF
509 *
510  IF( m.GT.k ) THEN
511 *
512 * QR factorization of A( K+1:M,N-L+1:N )
513 *
514  CALL zgeqr2( m-k, l, a( k+1, n-l+1 ), lda, tau, work, info )
515 *
516  IF( wantu ) THEN
517 *
518 * Update U(:,K+1:M) := U(:,K+1:M)*U1
519 *
520  CALL zunm2r( 'Right', 'No transpose', m, m-k, min( m-k, l ),
521  \$ a( k+1, n-l+1 ), lda, tau, u( 1, k+1 ), ldu,
522  \$ work, info )
523  END IF
524 *
525 * Clean up
526 *
527  DO 140 j = n - l + 1, n
528  DO 130 i = j - n + k + l + 1, m
529  a( i, j ) = czero
530  130 CONTINUE
531  140 CONTINUE
532 *
533  END IF
534 *
535  RETURN
536 *
537 * End of ZGGSVP
538 *
subroutine zunm2r(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, INFO)
ZUNM2R multiplies a general matrix by the unitary matrix from a QR factorization determined by cgeqrf...
Definition: zunm2r.f:161
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine zunmr2(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, INFO)
ZUNMR2 multiplies a general matrix by the unitary matrix from a RQ factorization determined by cgerqf...
Definition: zunmr2.f:161
subroutine zlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
ZLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: zlaset.f:108
subroutine zgeqpf(M, N, A, LDA, JPVT, TAU, WORK, RWORK, INFO)
ZGEQPF
Definition: zgeqpf.f:150
subroutine zgerq2(M, N, A, LDA, TAU, WORK, INFO)
ZGERQ2 computes the RQ factorization of a general rectangular matrix using an unblocked algorithm...
Definition: zgerq2.f:125
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zgeqr2(M, N, A, LDA, TAU, WORK, INFO)
ZGEQR2 computes the QR factorization of a general rectangular matrix using an unblocked algorithm...
Definition: zgeqr2.f:123
subroutine zlapmt(FORWRD, M, N, X, LDX, K)
ZLAPMT performs a forward or backward permutation of the columns of a matrix.
Definition: zlapmt.f:106
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:105
subroutine zung2r(M, N, K, A, LDA, TAU, WORK, INFO)
ZUNG2R
Definition: zung2r.f:116
Here is the call graph for this function:
Here is the caller graph for this function: