LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ zlansy()

double precision function zlansy ( character  NORM,
character  UPLO,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  WORK 
)

ZLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex symmetric matrix.

Download ZLANSY + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLANSY  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex symmetric matrix A.
Returns
ZLANSY
    ZLANSY = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in ZLANSY as described
          above.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          symmetric matrix A is to be referenced.
          = 'U':  Upper triangular part of A is referenced
          = 'L':  Lower triangular part of A is referenced
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, ZLANSY is
          set to zero.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The symmetric matrix A.  If UPLO = 'U', the leading n by n
          upper triangular part of A contains the upper triangular part
          of the matrix A, and the strictly lower triangular part of A
          is not referenced.  If UPLO = 'L', the leading n by n lower
          triangular part of A contains the lower triangular part of
          the matrix A, and the strictly upper triangular part of A is
          not referenced.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(N,1).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
          WORK is not referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 125 of file zlansy.f.

125 *
126 * -- LAPACK auxiliary routine (version 3.7.0) --
127 * -- LAPACK is a software package provided by Univ. of Tennessee, --
128 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
129 * December 2016
130 *
131 * .. Scalar Arguments ..
132  CHARACTER norm, uplo
133  INTEGER lda, n
134 * ..
135 * .. Array Arguments ..
136  DOUBLE PRECISION work( * )
137  COMPLEX*16 a( lda, * )
138 * ..
139 *
140 * =====================================================================
141 *
142 * .. Parameters ..
143  DOUBLE PRECISION one, zero
144  parameter( one = 1.0d+0, zero = 0.0d+0 )
145 * ..
146 * .. Local Scalars ..
147  INTEGER i, j
148  DOUBLE PRECISION absa, scale, sum, value
149 * ..
150 * .. External Functions ..
151  LOGICAL lsame, disnan
152  EXTERNAL lsame, disnan
153 * ..
154 * .. External Subroutines ..
155  EXTERNAL zlassq
156 * ..
157 * .. Intrinsic Functions ..
158  INTRINSIC abs, sqrt
159 * ..
160 * .. Executable Statements ..
161 *
162  IF( n.EQ.0 ) THEN
163  VALUE = zero
164  ELSE IF( lsame( norm, 'M' ) ) THEN
165 *
166 * Find max(abs(A(i,j))).
167 *
168  VALUE = zero
169  IF( lsame( uplo, 'U' ) ) THEN
170  DO 20 j = 1, n
171  DO 10 i = 1, j
172  sum = abs( a( i, j ) )
173  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
174  10 CONTINUE
175  20 CONTINUE
176  ELSE
177  DO 40 j = 1, n
178  DO 30 i = j, n
179  sum = abs( a( i, j ) )
180  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
181  30 CONTINUE
182  40 CONTINUE
183  END IF
184  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
185  $ ( norm.EQ.'1' ) ) THEN
186 *
187 * Find normI(A) ( = norm1(A), since A is symmetric).
188 *
189  VALUE = zero
190  IF( lsame( uplo, 'U' ) ) THEN
191  DO 60 j = 1, n
192  sum = zero
193  DO 50 i = 1, j - 1
194  absa = abs( a( i, j ) )
195  sum = sum + absa
196  work( i ) = work( i ) + absa
197  50 CONTINUE
198  work( j ) = sum + abs( a( j, j ) )
199  60 CONTINUE
200  DO 70 i = 1, n
201  sum = work( i )
202  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
203  70 CONTINUE
204  ELSE
205  DO 80 i = 1, n
206  work( i ) = zero
207  80 CONTINUE
208  DO 100 j = 1, n
209  sum = work( j ) + abs( a( j, j ) )
210  DO 90 i = j + 1, n
211  absa = abs( a( i, j ) )
212  sum = sum + absa
213  work( i ) = work( i ) + absa
214  90 CONTINUE
215  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
216  100 CONTINUE
217  END IF
218  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
219 *
220 * Find normF(A).
221 *
222  scale = zero
223  sum = one
224  IF( lsame( uplo, 'U' ) ) THEN
225  DO 110 j = 2, n
226  CALL zlassq( j-1, a( 1, j ), 1, scale, sum )
227  110 CONTINUE
228  ELSE
229  DO 120 j = 1, n - 1
230  CALL zlassq( n-j, a( j+1, j ), 1, scale, sum )
231  120 CONTINUE
232  END IF
233  sum = 2*sum
234  CALL zlassq( n, a, lda+1, scale, sum )
235  VALUE = scale*sqrt( sum )
236  END IF
237 *
238  zlansy = VALUE
239  RETURN
240 *
241 * End of ZLANSY
242 *
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:61
subroutine zlassq(N, X, INCX, SCALE, SUMSQ)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f:108
double precision function zlansy(NORM, UPLO, N, A, LDA, WORK)
ZLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex symmetric matrix.
Definition: zlansy.f:125
Here is the call graph for this function:
Here is the caller graph for this function: