LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
slangb.f
Go to the documentation of this file.
1*> \brief \b SLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download SLANGB + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slangb.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slangb.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slangb.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* REAL FUNCTION SLANGB( NORM, N, KL, KU, AB, LDAB,
22* WORK )
23*
24* .. Scalar Arguments ..
25* CHARACTER NORM
26* INTEGER KL, KU, LDAB, N
27* ..
28* .. Array Arguments ..
29* REAL AB( LDAB, * ), WORK( * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> SLANGB returns the value of the one norm, or the Frobenius norm, or
39*> the infinity norm, or the element of largest absolute value of an
40*> n by n band matrix A, with kl sub-diagonals and ku super-diagonals.
41*> \endverbatim
42*>
43*> \return SLANGB
44*> \verbatim
45*>
46*> SLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47*> (
48*> ( norm1(A), NORM = '1', 'O' or 'o'
49*> (
50*> ( normI(A), NORM = 'I' or 'i'
51*> (
52*> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53*>
54*> where norm1 denotes the one norm of a matrix (maximum column sum),
55*> normI denotes the infinity norm of a matrix (maximum row sum) and
56*> normF denotes the Frobenius norm of a matrix (square root of sum of
57*> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58*> \endverbatim
59*
60* Arguments:
61* ==========
62*
63*> \param[in] NORM
64*> \verbatim
65*> NORM is CHARACTER*1
66*> Specifies the value to be returned in SLANGB as described
67*> above.
68*> \endverbatim
69*>
70*> \param[in] N
71*> \verbatim
72*> N is INTEGER
73*> The order of the matrix A. N >= 0. When N = 0, SLANGB is
74*> set to zero.
75*> \endverbatim
76*>
77*> \param[in] KL
78*> \verbatim
79*> KL is INTEGER
80*> The number of sub-diagonals of the matrix A. KL >= 0.
81*> \endverbatim
82*>
83*> \param[in] KU
84*> \verbatim
85*> KU is INTEGER
86*> The number of super-diagonals of the matrix A. KU >= 0.
87*> \endverbatim
88*>
89*> \param[in] AB
90*> \verbatim
91*> AB is REAL array, dimension (LDAB,N)
92*> The band matrix A, stored in rows 1 to KL+KU+1. The j-th
93*> column of A is stored in the j-th column of the array AB as
94*> follows:
95*> AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
96*> \endverbatim
97*>
98*> \param[in] LDAB
99*> \verbatim
100*> LDAB is INTEGER
101*> The leading dimension of the array AB. LDAB >= KL+KU+1.
102*> \endverbatim
103*>
104*> \param[out] WORK
105*> \verbatim
106*> WORK is REAL array, dimension (MAX(1,LWORK)),
107*> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
108*> referenced.
109*> \endverbatim
110*
111* Authors:
112* ========
113*
114*> \author Univ. of Tennessee
115*> \author Univ. of California Berkeley
116*> \author Univ. of Colorado Denver
117*> \author NAG Ltd.
118*
119*> \ingroup langb
120*
121* =====================================================================
122 REAL function slangb( norm, n, kl, ku, ab, ldab,
123 $ work )
124*
125* -- LAPACK auxiliary routine --
126* -- LAPACK is a software package provided by Univ. of Tennessee, --
127* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128*
129* .. Scalar Arguments ..
130 CHARACTER norm
131 INTEGER kl, ku, ldab, n
132* ..
133* .. Array Arguments ..
134 REAL ab( ldab, * ), work( * )
135* ..
136*
137* =====================================================================
138*
139*
140* .. Parameters ..
141 REAL one, zero
142 parameter( one = 1.0e+0, zero = 0.0e+0 )
143* ..
144* .. Local Scalars ..
145 INTEGER i, j, k, l
146 REAL scale, sum, VALUE, temp
147* ..
148* .. External Subroutines ..
149 EXTERNAL slassq
150* ..
151* .. External Functions ..
152 LOGICAL lsame, sisnan
153 EXTERNAL lsame, sisnan
154* ..
155* .. Intrinsic Functions ..
156 INTRINSIC abs, max, min, sqrt
157* ..
158* .. Executable Statements ..
159*
160 IF( n.EQ.0 ) THEN
161 VALUE = zero
162 ELSE IF( lsame( norm, 'M' ) ) THEN
163*
164* Find max(abs(A(i,j))).
165*
166 VALUE = zero
167 DO 20 j = 1, n
168 DO 10 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
169 temp = abs( ab( i, j ) )
170 IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
171 10 CONTINUE
172 20 CONTINUE
173 ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
174*
175* Find norm1(A).
176*
177 VALUE = zero
178 DO 40 j = 1, n
179 sum = zero
180 DO 30 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
181 sum = sum + abs( ab( i, j ) )
182 30 CONTINUE
183 IF( VALUE.LT.sum .OR. sisnan( sum ) ) VALUE = sum
184 40 CONTINUE
185 ELSE IF( lsame( norm, 'I' ) ) THEN
186*
187* Find normI(A).
188*
189 DO 50 i = 1, n
190 work( i ) = zero
191 50 CONTINUE
192 DO 70 j = 1, n
193 k = ku + 1 - j
194 DO 60 i = max( 1, j-ku ), min( n, j+kl )
195 work( i ) = work( i ) + abs( ab( k+i, j ) )
196 60 CONTINUE
197 70 CONTINUE
198 VALUE = zero
199 DO 80 i = 1, n
200 temp = work( i )
201 IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
202 80 CONTINUE
203 ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
204*
205* Find normF(A).
206*
207 scale = zero
208 sum = one
209 DO 90 j = 1, n
210 l = max( 1, j-ku )
211 k = ku + 1 - j + l
212 CALL slassq( min( n, j+kl )-l+1, ab( k, j ), 1, scale, sum )
213 90 CONTINUE
214 VALUE = scale*sqrt( sum )
215 END IF
216*
217 slangb = VALUE
218 RETURN
219*
220* End of SLANGB
221*
222 END
logical function sisnan(sin)
SISNAN tests input for NaN.
Definition sisnan.f:59
real function slangb(norm, n, kl, ku, ab, ldab, work)
SLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition slangb.f:124
subroutine slassq(n, x, incx, scale, sumsq)
SLASSQ updates a sum of squares represented in scaled form.
Definition slassq.f90:124
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48