LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
clansp.f
Go to the documentation of this file.
1*> \brief \b CLANSP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric matrix supplied in packed form.
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download CLANSP + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clansp.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clansp.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clansp.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* REAL FUNCTION CLANSP( NORM, UPLO, N, AP, WORK )
22*
23* .. Scalar Arguments ..
24* CHARACTER NORM, UPLO
25* INTEGER N
26* ..
27* .. Array Arguments ..
28* REAL WORK( * )
29* COMPLEX AP( * )
30* ..
31*
32*
33*> \par Purpose:
34* =============
35*>
36*> \verbatim
37*>
38*> CLANSP returns the value of the one norm, or the Frobenius norm, or
39*> the infinity norm, or the element of largest absolute value of a
40*> complex symmetric matrix A, supplied in packed form.
41*> \endverbatim
42*>
43*> \return CLANSP
44*> \verbatim
45*>
46*> CLANSP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47*> (
48*> ( norm1(A), NORM = '1', 'O' or 'o'
49*> (
50*> ( normI(A), NORM = 'I' or 'i'
51*> (
52*> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53*>
54*> where norm1 denotes the one norm of a matrix (maximum column sum),
55*> normI denotes the infinity norm of a matrix (maximum row sum) and
56*> normF denotes the Frobenius norm of a matrix (square root of sum of
57*> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58*> \endverbatim
59*
60* Arguments:
61* ==========
62*
63*> \param[in] NORM
64*> \verbatim
65*> NORM is CHARACTER*1
66*> Specifies the value to be returned in CLANSP as described
67*> above.
68*> \endverbatim
69*>
70*> \param[in] UPLO
71*> \verbatim
72*> UPLO is CHARACTER*1
73*> Specifies whether the upper or lower triangular part of the
74*> symmetric matrix A is supplied.
75*> = 'U': Upper triangular part of A is supplied
76*> = 'L': Lower triangular part of A is supplied
77*> \endverbatim
78*>
79*> \param[in] N
80*> \verbatim
81*> N is INTEGER
82*> The order of the matrix A. N >= 0. When N = 0, CLANSP is
83*> set to zero.
84*> \endverbatim
85*>
86*> \param[in] AP
87*> \verbatim
88*> AP is COMPLEX array, dimension (N*(N+1)/2)
89*> The upper or lower triangle of the symmetric matrix A, packed
90*> columnwise in a linear array. The j-th column of A is stored
91*> in the array AP as follows:
92*> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
93*> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
94*> \endverbatim
95*>
96*> \param[out] WORK
97*> \verbatim
98*> WORK is REAL array, dimension (MAX(1,LWORK)),
99*> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
100*> WORK is not referenced.
101*> \endverbatim
102*
103* Authors:
104* ========
105*
106*> \author Univ. of Tennessee
107*> \author Univ. of California Berkeley
108*> \author Univ. of Colorado Denver
109*> \author NAG Ltd.
110*
111*> \ingroup lanhp
112*
113* =====================================================================
114 REAL function clansp( norm, uplo, n, ap, work )
115*
116* -- LAPACK auxiliary routine --
117* -- LAPACK is a software package provided by Univ. of Tennessee, --
118* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
119*
120* .. Scalar Arguments ..
121 CHARACTER norm, uplo
122 INTEGER n
123* ..
124* .. Array Arguments ..
125 REAL work( * )
126 COMPLEX ap( * )
127* ..
128*
129* =====================================================================
130*
131* .. Parameters ..
132 REAL one, zero
133 parameter( one = 1.0e+0, zero = 0.0e+0 )
134* ..
135* .. Local Scalars ..
136 INTEGER i, j, k
137 REAL absa, scale, sum, value
138* ..
139* .. External Functions ..
140 LOGICAL lsame, sisnan
141 EXTERNAL lsame, sisnan
142* ..
143* .. External Subroutines ..
144 EXTERNAL classq
145* ..
146* .. Intrinsic Functions ..
147 INTRINSIC abs, aimag, real, sqrt
148* ..
149* .. Executable Statements ..
150*
151 IF( n.EQ.0 ) THEN
152 VALUE = zero
153 ELSE IF( lsame( norm, 'M' ) ) THEN
154*
155* Find max(abs(A(i,j))).
156*
157 VALUE = zero
158 IF( lsame( uplo, 'U' ) ) THEN
159 k = 1
160 DO 20 j = 1, n
161 DO 10 i = k, k + j - 1
162 sum = abs( ap( i ) )
163 IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
164 10 CONTINUE
165 k = k + j
166 20 CONTINUE
167 ELSE
168 k = 1
169 DO 40 j = 1, n
170 DO 30 i = k, k + n - j
171 sum = abs( ap( i ) )
172 IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
173 30 CONTINUE
174 k = k + n - j + 1
175 40 CONTINUE
176 END IF
177 ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
178 $ ( norm.EQ.'1' ) ) THEN
179*
180* Find normI(A) ( = norm1(A), since A is symmetric).
181*
182 VALUE = zero
183 k = 1
184 IF( lsame( uplo, 'U' ) ) THEN
185 DO 60 j = 1, n
186 sum = zero
187 DO 50 i = 1, j - 1
188 absa = abs( ap( k ) )
189 sum = sum + absa
190 work( i ) = work( i ) + absa
191 k = k + 1
192 50 CONTINUE
193 work( j ) = sum + abs( ap( k ) )
194 k = k + 1
195 60 CONTINUE
196 DO 70 i = 1, n
197 sum = work( i )
198 IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
199 70 CONTINUE
200 ELSE
201 DO 80 i = 1, n
202 work( i ) = zero
203 80 CONTINUE
204 DO 100 j = 1, n
205 sum = work( j ) + abs( ap( k ) )
206 k = k + 1
207 DO 90 i = j + 1, n
208 absa = abs( ap( k ) )
209 sum = sum + absa
210 work( i ) = work( i ) + absa
211 k = k + 1
212 90 CONTINUE
213 IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
214 100 CONTINUE
215 END IF
216 ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
217*
218* Find normF(A).
219*
220 scale = zero
221 sum = one
222 k = 2
223 IF( lsame( uplo, 'U' ) ) THEN
224 DO 110 j = 2, n
225 CALL classq( j-1, ap( k ), 1, scale, sum )
226 k = k + j
227 110 CONTINUE
228 ELSE
229 DO 120 j = 1, n - 1
230 CALL classq( n-j, ap( k ), 1, scale, sum )
231 k = k + n - j + 1
232 120 CONTINUE
233 END IF
234 sum = 2*sum
235 k = 1
236 DO 130 i = 1, n
237 IF( real( ap( k ) ).NE.zero ) THEN
238 absa = abs( real( ap( k ) ) )
239 IF( scale.LT.absa ) THEN
240 sum = one + sum*( scale / absa )**2
241 scale = absa
242 ELSE
243 sum = sum + ( absa / scale )**2
244 END IF
245 END IF
246 IF( aimag( ap( k ) ).NE.zero ) THEN
247 absa = abs( aimag( ap( k ) ) )
248 IF( scale.LT.absa ) THEN
249 sum = one + sum*( scale / absa )**2
250 scale = absa
251 ELSE
252 sum = sum + ( absa / scale )**2
253 END IF
254 END IF
255 IF( lsame( uplo, 'U' ) ) THEN
256 k = k + i + 1
257 ELSE
258 k = k + n - i + 1
259 END IF
260 130 CONTINUE
261 VALUE = scale*sqrt( sum )
262 END IF
263*
264 clansp = VALUE
265 RETURN
266*
267* End of CLANSP
268*
269 END
logical function sisnan(sin)
SISNAN tests input for NaN.
Definition sisnan.f:59
real function clansp(norm, uplo, n, ap, work)
CLANSP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition clansp.f:115
subroutine classq(n, x, incx, scale, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition classq.f90:124
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48