LAPACK  3.8.0
LAPACK: Linear Algebra PACKage
zlanhp.f
Go to the documentation of this file.
1 *> \brief \b ZLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZLANHP + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhp.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhp.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhp.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * DOUBLE PRECISION FUNCTION ZLANHP( NORM, UPLO, N, AP, WORK )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM, UPLO
25 * INTEGER N
26 * ..
27 * .. Array Arguments ..
28 * DOUBLE PRECISION WORK( * )
29 * COMPLEX*16 AP( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> ZLANHP returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of a
40 *> complex hermitian matrix A, supplied in packed form.
41 *> \endverbatim
42 *>
43 *> \return ZLANHP
44 *> \verbatim
45 *>
46 *> ZLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in ZLANHP as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] UPLO
71 *> \verbatim
72 *> UPLO is CHARACTER*1
73 *> Specifies whether the upper or lower triangular part of the
74 *> hermitian matrix A is supplied.
75 *> = 'U': Upper triangular part of A is supplied
76 *> = 'L': Lower triangular part of A is supplied
77 *> \endverbatim
78 *>
79 *> \param[in] N
80 *> \verbatim
81 *> N is INTEGER
82 *> The order of the matrix A. N >= 0. When N = 0, ZLANHP is
83 *> set to zero.
84 *> \endverbatim
85 *>
86 *> \param[in] AP
87 *> \verbatim
88 *> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
89 *> The upper or lower triangle of the hermitian matrix A, packed
90 *> columnwise in a linear array. The j-th column of A is stored
91 *> in the array AP as follows:
92 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
93 *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
94 *> Note that the imaginary parts of the diagonal elements need
95 *> not be set and are assumed to be zero.
96 *> \endverbatim
97 *>
98 *> \param[out] WORK
99 *> \verbatim
100 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
101 *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
102 *> WORK is not referenced.
103 *> \endverbatim
104 *
105 * Authors:
106 * ========
107 *
108 *> \author Univ. of Tennessee
109 *> \author Univ. of California Berkeley
110 *> \author Univ. of Colorado Denver
111 *> \author NAG Ltd.
112 *
113 *> \date December 2016
114 *
115 *> \ingroup complex16OTHERauxiliary
116 *
117 * =====================================================================
118  DOUBLE PRECISION FUNCTION zlanhp( NORM, UPLO, N, AP, WORK )
119 *
120 * -- LAPACK auxiliary routine (version 3.7.0) --
121 * -- LAPACK is a software package provided by Univ. of Tennessee, --
122 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
123 * December 2016
124 *
125 * .. Scalar Arguments ..
126  CHARACTER NORM, UPLO
127  INTEGER N
128 * ..
129 * .. Array Arguments ..
130  DOUBLE PRECISION WORK( * )
131  COMPLEX*16 AP( * )
132 * ..
133 *
134 * =====================================================================
135 *
136 * .. Parameters ..
137  DOUBLE PRECISION ONE, ZERO
138  parameter( one = 1.0d+0, zero = 0.0d+0 )
139 * ..
140 * .. Local Scalars ..
141  INTEGER I, J, K
142  DOUBLE PRECISION ABSA, SCALE, SUM, VALUE
143 * ..
144 * .. External Functions ..
145  LOGICAL LSAME, DISNAN
146  EXTERNAL lsame, disnan
147 * ..
148 * .. External Subroutines ..
149  EXTERNAL zlassq
150 * ..
151 * .. Intrinsic Functions ..
152  INTRINSIC abs, dble, sqrt
153 * ..
154 * .. Executable Statements ..
155 *
156  IF( n.EQ.0 ) THEN
157  VALUE = zero
158  ELSE IF( lsame( norm, 'M' ) ) THEN
159 *
160 * Find max(abs(A(i,j))).
161 *
162  VALUE = zero
163  IF( lsame( uplo, 'U' ) ) THEN
164  k = 0
165  DO 20 j = 1, n
166  DO 10 i = k + 1, k + j - 1
167  sum = abs( ap( i ) )
168  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
169  10 CONTINUE
170  k = k + j
171  sum = abs( dble( ap( k ) ) )
172  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
173  20 CONTINUE
174  ELSE
175  k = 1
176  DO 40 j = 1, n
177  sum = abs( dble( ap( k ) ) )
178  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
179  DO 30 i = k + 1, k + n - j
180  sum = abs( ap( i ) )
181  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
182  30 CONTINUE
183  k = k + n - j + 1
184  40 CONTINUE
185  END IF
186  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
187  $ ( norm.EQ.'1' ) ) THEN
188 *
189 * Find normI(A) ( = norm1(A), since A is hermitian).
190 *
191  VALUE = zero
192  k = 1
193  IF( lsame( uplo, 'U' ) ) THEN
194  DO 60 j = 1, n
195  sum = zero
196  DO 50 i = 1, j - 1
197  absa = abs( ap( k ) )
198  sum = sum + absa
199  work( i ) = work( i ) + absa
200  k = k + 1
201  50 CONTINUE
202  work( j ) = sum + abs( dble( ap( k ) ) )
203  k = k + 1
204  60 CONTINUE
205  DO 70 i = 1, n
206  sum = work( i )
207  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
208  70 CONTINUE
209  ELSE
210  DO 80 i = 1, n
211  work( i ) = zero
212  80 CONTINUE
213  DO 100 j = 1, n
214  sum = work( j ) + abs( dble( ap( k ) ) )
215  k = k + 1
216  DO 90 i = j + 1, n
217  absa = abs( ap( k ) )
218  sum = sum + absa
219  work( i ) = work( i ) + absa
220  k = k + 1
221  90 CONTINUE
222  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
223  100 CONTINUE
224  END IF
225  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
226 *
227 * Find normF(A).
228 *
229  scale = zero
230  sum = one
231  k = 2
232  IF( lsame( uplo, 'U' ) ) THEN
233  DO 110 j = 2, n
234  CALL zlassq( j-1, ap( k ), 1, scale, sum )
235  k = k + j
236  110 CONTINUE
237  ELSE
238  DO 120 j = 1, n - 1
239  CALL zlassq( n-j, ap( k ), 1, scale, sum )
240  k = k + n - j + 1
241  120 CONTINUE
242  END IF
243  sum = 2*sum
244  k = 1
245  DO 130 i = 1, n
246  IF( dble( ap( k ) ).NE.zero ) THEN
247  absa = abs( dble( ap( k ) ) )
248  IF( scale.LT.absa ) THEN
249  sum = one + sum*( scale / absa )**2
250  scale = absa
251  ELSE
252  sum = sum + ( absa / scale )**2
253  END IF
254  END IF
255  IF( lsame( uplo, 'U' ) ) THEN
256  k = k + i + 1
257  ELSE
258  k = k + n - i + 1
259  END IF
260  130 CONTINUE
261  VALUE = scale*sqrt( sum )
262  END IF
263 *
264  zlanhp = VALUE
265  RETURN
266 *
267 * End of ZLANHP
268 *
269  END
subroutine zlassq(N, X, INCX, SCALE, SUMSQ)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f:108
double precision function zlanhp(NORM, UPLO, N, AP, WORK)
ZLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.
Definition: zlanhp.f:119