LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dpptrf()

subroutine dpptrf ( character  UPLO,
integer  N,
double precision, dimension( * )  AP,
integer  INFO 
)

DPPTRF

Download DPPTRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DPPTRF computes the Cholesky factorization of a real symmetric
 positive definite matrix A stored in packed format.

 The factorization has the form
    A = U**T * U,  if UPLO = 'U', or
    A = L  * L**T,  if UPLO = 'L',
 where U is an upper triangular matrix and L is lower triangular.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangle of A is stored;
          = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in,out]AP
          AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
          On entry, the upper or lower triangle of the symmetric matrix
          A, packed columnwise in a linear array.  The j-th column of A
          is stored in the array AP as follows:
          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
          See below for further details.

          On exit, if INFO = 0, the triangular factor U or L from the
          Cholesky factorization A = U**T*U or A = L*L**T, in the same
          storage format as A.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, the leading minor of order i is not
                positive definite, and the factorization could not be
                completed.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016
Further Details:
  The packed storage scheme is illustrated by the following example
  when N = 4, UPLO = 'U':

  Two-dimensional storage of the symmetric matrix A:

     a11 a12 a13 a14
         a22 a23 a24
             a33 a34     (aij = aji)
                 a44

  Packed storage of the upper triangle of A:

  AP = [ a11, a12, a22, a13, a23, a33, a14, a24, a34, a44 ]

Definition at line 121 of file dpptrf.f.

121 *
122 * -- LAPACK computational routine (version 3.7.0) --
123 * -- LAPACK is a software package provided by Univ. of Tennessee, --
124 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
125 * December 2016
126 *
127 * .. Scalar Arguments ..
128  CHARACTER uplo
129  INTEGER info, n
130 * ..
131 * .. Array Arguments ..
132  DOUBLE PRECISION ap( * )
133 * ..
134 *
135 * =====================================================================
136 *
137 * .. Parameters ..
138  DOUBLE PRECISION one, zero
139  parameter( one = 1.0d+0, zero = 0.0d+0 )
140 * ..
141 * .. Local Scalars ..
142  LOGICAL upper
143  INTEGER j, jc, jj
144  DOUBLE PRECISION ajj
145 * ..
146 * .. External Functions ..
147  LOGICAL lsame
148  DOUBLE PRECISION ddot
149  EXTERNAL lsame, ddot
150 * ..
151 * .. External Subroutines ..
152  EXTERNAL dscal, dspr, dtpsv, xerbla
153 * ..
154 * .. Intrinsic Functions ..
155  INTRINSIC sqrt
156 * ..
157 * .. Executable Statements ..
158 *
159 * Test the input parameters.
160 *
161  info = 0
162  upper = lsame( uplo, 'U' )
163  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
164  info = -1
165  ELSE IF( n.LT.0 ) THEN
166  info = -2
167  END IF
168  IF( info.NE.0 ) THEN
169  CALL xerbla( 'DPPTRF', -info )
170  RETURN
171  END IF
172 *
173 * Quick return if possible
174 *
175  IF( n.EQ.0 )
176  $ RETURN
177 *
178  IF( upper ) THEN
179 *
180 * Compute the Cholesky factorization A = U**T*U.
181 *
182  jj = 0
183  DO 10 j = 1, n
184  jc = jj + 1
185  jj = jj + j
186 *
187 * Compute elements 1:J-1 of column J.
188 *
189  IF( j.GT.1 )
190  $ CALL dtpsv( 'Upper', 'Transpose', 'Non-unit', j-1, ap,
191  $ ap( jc ), 1 )
192 *
193 * Compute U(J,J) and test for non-positive-definiteness.
194 *
195  ajj = ap( jj ) - ddot( j-1, ap( jc ), 1, ap( jc ), 1 )
196  IF( ajj.LE.zero ) THEN
197  ap( jj ) = ajj
198  GO TO 30
199  END IF
200  ap( jj ) = sqrt( ajj )
201  10 CONTINUE
202  ELSE
203 *
204 * Compute the Cholesky factorization A = L*L**T.
205 *
206  jj = 1
207  DO 20 j = 1, n
208 *
209 * Compute L(J,J) and test for non-positive-definiteness.
210 *
211  ajj = ap( jj )
212  IF( ajj.LE.zero ) THEN
213  ap( jj ) = ajj
214  GO TO 30
215  END IF
216  ajj = sqrt( ajj )
217  ap( jj ) = ajj
218 *
219 * Compute elements J+1:N of column J and update the trailing
220 * submatrix.
221 *
222  IF( j.LT.n ) THEN
223  CALL dscal( n-j, one / ajj, ap( jj+1 ), 1 )
224  CALL dspr( 'Lower', n-j, -one, ap( jj+1 ), 1,
225  $ ap( jj+n-j+1 ) )
226  jj = jj + n - j + 1
227  END IF
228  20 CONTINUE
229  END IF
230  GO TO 40
231 *
232  30 CONTINUE
233  info = j
234 *
235  40 CONTINUE
236  RETURN
237 *
238 * End of DPPTRF
239 *
double precision function ddot(N, DX, INCX, DY, INCY)
DDOT
Definition: ddot.f:84
subroutine dtpsv(UPLO, TRANS, DIAG, N, AP, X, INCX)
DTPSV
Definition: dtpsv.f:146
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:81
subroutine dspr(UPLO, N, ALPHA, X, INCX, AP)
DSPR
Definition: dspr.f:129
Here is the call graph for this function:
Here is the caller graph for this function: