 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ dorg2r()

 subroutine dorg2r ( integer M, integer N, integer K, double precision, dimension( lda, * ) A, integer LDA, double precision, dimension( * ) TAU, double precision, dimension( * ) WORK, integer INFO )

DORG2R generates all or part of the orthogonal matrix Q from a QR factorization determined by sgeqrf (unblocked algorithm).

Purpose:
``` DORG2R generates an m by n real matrix Q with orthonormal columns,
which is defined as the first n columns of a product of k elementary
reflectors of order m

Q  =  H(1) H(2) . . . H(k)

as returned by DGEQRF.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix Q. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix Q. M >= N >= 0.``` [in] K ``` K is INTEGER The number of elementary reflectors whose product defines the matrix Q. N >= K >= 0.``` [in,out] A ``` A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the i-th column must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by DGEQRF in the first k columns of its array argument A. On exit, the m-by-n matrix Q.``` [in] LDA ``` LDA is INTEGER The first dimension of the array A. LDA >= max(1,M).``` [in] TAU ``` TAU is DOUBLE PRECISION array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by DGEQRF.``` [out] WORK ` WORK is DOUBLE PRECISION array, dimension (N)` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value```

Definition at line 113 of file dorg2r.f.

114 *
115 * -- LAPACK computational routine --
116 * -- LAPACK is a software package provided by Univ. of Tennessee, --
117 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118 *
119 * .. Scalar Arguments ..
120  INTEGER INFO, K, LDA, M, N
121 * ..
122 * .. Array Arguments ..
123  DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
124 * ..
125 *
126 * =====================================================================
127 *
128 * .. Parameters ..
129  DOUBLE PRECISION ONE, ZERO
130  parameter( one = 1.0d+0, zero = 0.0d+0 )
131 * ..
132 * .. Local Scalars ..
133  INTEGER I, J, L
134 * ..
135 * .. External Subroutines ..
136  EXTERNAL dlarf, dscal, xerbla
137 * ..
138 * .. Intrinsic Functions ..
139  INTRINSIC max
140 * ..
141 * .. Executable Statements ..
142 *
143 * Test the input arguments
144 *
145  info = 0
146  IF( m.LT.0 ) THEN
147  info = -1
148  ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
149  info = -2
150  ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
151  info = -3
152  ELSE IF( lda.LT.max( 1, m ) ) THEN
153  info = -5
154  END IF
155  IF( info.NE.0 ) THEN
156  CALL xerbla( 'DORG2R', -info )
157  RETURN
158  END IF
159 *
160 * Quick return if possible
161 *
162  IF( n.LE.0 )
163  \$ RETURN
164 *
165 * Initialise columns k+1:n to columns of the unit matrix
166 *
167  DO 20 j = k + 1, n
168  DO 10 l = 1, m
169  a( l, j ) = zero
170  10 CONTINUE
171  a( j, j ) = one
172  20 CONTINUE
173 *
174  DO 40 i = k, 1, -1
175 *
176 * Apply H(i) to A(i:m,i:n) from the left
177 *
178  IF( i.LT.n ) THEN
179  a( i, i ) = one
180  CALL dlarf( 'Left', m-i+1, n-i, a( i, i ), 1, tau( i ),
181  \$ a( i, i+1 ), lda, work )
182  END IF
183  IF( i.LT.m )
184  \$ CALL dscal( m-i, -tau( i ), a( i+1, i ), 1 )
185  a( i, i ) = one - tau( i )
186 *
187 * Set A(1:i-1,i) to zero
188 *
189  DO 30 l = 1, i - 1
190  a( l, i ) = zero
191  30 CONTINUE
192  40 CONTINUE
193  RETURN
194 *
195 * End of DORG2R
196 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:79
subroutine dlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition: dlarf.f:124
Here is the call graph for this function:
Here is the caller graph for this function: