LAPACK  3.10.1 LAPACK: Linear Algebra PACKage
zlanht.f
Go to the documentation of this file.
1 *> \brief \b ZLANHT returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian tridiagonal matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanht.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanht.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanht.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * DOUBLE PRECISION FUNCTION ZLANHT( NORM, N, D, E )
22 *
23 * .. Scalar Arguments ..
24 * CHARACTER NORM
25 * INTEGER N
26 * ..
27 * .. Array Arguments ..
28 * DOUBLE PRECISION D( * )
29 * COMPLEX*16 E( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> ZLANHT returns the value of the one norm, or the Frobenius norm, or
39 *> the infinity norm, or the element of largest absolute value of a
40 *> complex Hermitian tridiagonal matrix A.
41 *> \endverbatim
42 *>
43 *> \return ZLANHT
44 *> \verbatim
45 *>
46 *> ZLANHT = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47 *> (
48 *> ( norm1(A), NORM = '1', 'O' or 'o'
49 *> (
50 *> ( normI(A), NORM = 'I' or 'i'
51 *> (
52 *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53 *>
54 *> where norm1 denotes the one norm of a matrix (maximum column sum),
55 *> normI denotes the infinity norm of a matrix (maximum row sum) and
56 *> normF denotes the Frobenius norm of a matrix (square root of sum of
57 *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58 *> \endverbatim
59 *
60 * Arguments:
61 * ==========
62 *
63 *> \param[in] NORM
64 *> \verbatim
65 *> NORM is CHARACTER*1
66 *> Specifies the value to be returned in ZLANHT as described
67 *> above.
68 *> \endverbatim
69 *>
70 *> \param[in] N
71 *> \verbatim
72 *> N is INTEGER
73 *> The order of the matrix A. N >= 0. When N = 0, ZLANHT is
74 *> set to zero.
75 *> \endverbatim
76 *>
77 *> \param[in] D
78 *> \verbatim
79 *> D is DOUBLE PRECISION array, dimension (N)
80 *> The diagonal elements of A.
81 *> \endverbatim
82 *>
83 *> \param[in] E
84 *> \verbatim
85 *> E is COMPLEX*16 array, dimension (N-1)
86 *> The (n-1) sub-diagonal or super-diagonal elements of A.
87 *> \endverbatim
88 *
89 * Authors:
90 * ========
91 *
92 *> \author Univ. of Tennessee
93 *> \author Univ. of California Berkeley
94 *> \author Univ. of Colorado Denver
95 *> \author NAG Ltd.
96 *
97 *> \ingroup complex16OTHERauxiliary
98 *
99 * =====================================================================
100  DOUBLE PRECISION FUNCTION zlanht( NORM, N, D, E )
101 *
102 * -- LAPACK auxiliary routine --
103 * -- LAPACK is a software package provided by Univ. of Tennessee, --
104 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
105 *
106 * .. Scalar Arguments ..
107  CHARACTER norm
108  INTEGER n
109 * ..
110 * .. Array Arguments ..
111  DOUBLE PRECISION d( * )
112  COMPLEX*16 e( * )
113 * ..
114 *
115 * =====================================================================
116 *
117 * .. Parameters ..
118  DOUBLE PRECISION one, zero
119  parameter( one = 1.0d+0, zero = 0.0d+0 )
120 * ..
121 * .. Local Scalars ..
122  INTEGER i
123  DOUBLE PRECISION anorm, scale, sum
124 * ..
125 * .. External Functions ..
126  LOGICAL lsame, disnan
127  EXTERNAL lsame, disnan
128 * ..
129 * .. External Subroutines ..
130  EXTERNAL dlassq, zlassq
131 * ..
132 * .. Intrinsic Functions ..
133  INTRINSIC abs, max, sqrt
134 * ..
135 * .. Executable Statements ..
136 *
137  IF( n.LE.0 ) THEN
138  anorm = zero
139  ELSE IF( lsame( norm, 'M' ) ) THEN
140 *
141 * Find max(abs(A(i,j))).
142 *
143  anorm = abs( d( n ) )
144  DO 10 i = 1, n - 1
145  sum = abs( d( i ) )
146  IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
147  sum = abs( e( i ) )
148  IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
149  10 CONTINUE
150  ELSE IF( lsame( norm, 'O' ) .OR. norm.EQ.'1' .OR.
151  \$ lsame( norm, 'I' ) ) THEN
152 *
153 * Find norm1(A).
154 *
155  IF( n.EQ.1 ) THEN
156  anorm = abs( d( 1 ) )
157  ELSE
158  anorm = abs( d( 1 ) )+abs( e( 1 ) )
159  sum = abs( e( n-1 ) )+abs( d( n ) )
160  IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
161  DO 20 i = 2, n - 1
162  sum = abs( d( i ) )+abs( e( i ) )+abs( e( i-1 ) )
163  IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
164  20 CONTINUE
165  END IF
166  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
167 *
168 * Find normF(A).
169 *
170  scale = zero
171  sum = one
172  IF( n.GT.1 ) THEN
173  CALL zlassq( n-1, e, 1, scale, sum )
174  sum = 2*sum
175  END IF
176  CALL dlassq( n, d, 1, scale, sum )
177  anorm = scale*sqrt( sum )
178  END IF
179 *
180  zlanht = anorm
181  RETURN
182 *
183 * End of ZLANHT
184 *
185  END
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine dlassq(n, x, incx, scl, sumsq)
DLASSQ updates a sum of squares represented in scaled form.
Definition: dlassq.f90:137
subroutine zlassq(n, x, incx, scl, sumsq)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f90:137
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function zlanht(NORM, N, D, E)
ZLANHT returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: zlanht.f:101