LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ zgbsvxx()

 subroutine zgbsvxx ( character FACT, character TRANS, integer N, integer KL, integer KU, integer NRHS, complex*16, dimension( ldab, * ) AB, integer LDAB, complex*16, dimension( ldafb, * ) AFB, integer LDAFB, integer, dimension( * ) IPIV, character EQUED, double precision, dimension( * ) R, double precision, dimension( * ) C, complex*16, dimension( ldb, * ) B, integer LDB, complex*16, dimension( ldx , * ) X, integer LDX, double precision RCOND, double precision RPVGRW, double precision, dimension( * ) BERR, integer N_ERR_BNDS, double precision, dimension( nrhs, * ) ERR_BNDS_NORM, double precision, dimension( nrhs, * ) ERR_BNDS_COMP, integer NPARAMS, double precision, dimension( * ) PARAMS, complex*16, dimension( * ) WORK, double precision, dimension( * ) RWORK, integer INFO )

ZGBSVXX computes the solution to system of linear equations A * X = B for GB matrices

Purpose:
```    ZGBSVXX uses the LU factorization to compute the solution to a
complex*16 system of linear equations  A * X = B,  where A is an
N-by-N matrix and X and B are N-by-NRHS matrices.

If requested, both normwise and maximum componentwise error bounds
are returned. ZGBSVXX will return a solution with a tiny
guaranteed error (O(eps) where eps is the working machine
precision) unless the matrix is very ill-conditioned, in which
case a warning is returned. Relevant condition numbers also are
calculated and returned.

ZGBSVXX accepts user-provided factorizations and equilibration
factors; see the definitions of the FACT and EQUED options.
Solving with refinement and using a factorization from a previous
ZGBSVXX call will also produce a solution with either O(eps)
errors or warnings, but we cannot make that claim for general
user-provided factorizations and equilibration factors if they
differ from what ZGBSVXX would itself produce.```
Description:
```    The following steps are performed:

1. If FACT = 'E', double precision scaling factors are computed to equilibrate
the system:

TRANS = 'N':  diag(R)*A*diag(C)     *inv(diag(C))*X = diag(R)*B
TRANS = 'T': (diag(R)*A*diag(C))**T *inv(diag(R))*X = diag(C)*B
TRANS = 'C': (diag(R)*A*diag(C))**H *inv(diag(R))*X = diag(C)*B

Whether or not the system will be equilibrated depends on the
scaling of the matrix A, but if equilibration is used, A is
overwritten by diag(R)*A*diag(C) and B by diag(R)*B (if TRANS='N')
or diag(C)*B (if TRANS = 'T' or 'C').

2. If FACT = 'N' or 'E', the LU decomposition is used to factor
the matrix A (after equilibration if FACT = 'E') as

A = P * L * U,

where P is a permutation matrix, L is a unit lower triangular
matrix, and U is upper triangular.

3. If some U(i,i)=0, so that U is exactly singular, then the
routine returns with INFO = i. Otherwise, the factored form of A
is used to estimate the condition number of the matrix A (see
argument RCOND). If the reciprocal of the condition number is less
than machine precision, the routine still goes on to solve for X
and compute error bounds as described below.

4. The system of equations is solved for X using the factored form
of A.

5. By default (unless PARAMS(LA_LINRX_ITREF_I) is set to zero),
the routine will use iterative refinement to try to get a small
error and error bounds.  Refinement calculates the residual to at
least twice the working precision.

6. If equilibration was used, the matrix X is premultiplied by
diag(C) (if TRANS = 'N') or diag(R) (if TRANS = 'T' or 'C') so
that it solves the original system before equilibration.```
```     Some optional parameters are bundled in the PARAMS array.  These
settings determine how refinement is performed, but often the
defaults are acceptable.  If the defaults are acceptable, users
can pass NPARAMS = 0 which prevents the source code from accessing
the PARAMS argument.```
Parameters
 [in] FACT ``` FACT is CHARACTER*1 Specifies whether or not the factored form of the matrix A is supplied on entry, and if not, whether the matrix A should be equilibrated before it is factored. = 'F': On entry, AF and IPIV contain the factored form of A. If EQUED is not 'N', the matrix A has been equilibrated with scaling factors given by R and C. A, AF, and IPIV are not modified. = 'N': The matrix A will be copied to AF and factored. = 'E': The matrix A will be equilibrated if necessary, then copied to AF and factored.``` [in] TRANS ``` TRANS is CHARACTER*1 Specifies the form of the system of equations: = 'N': A * X = B (No transpose) = 'T': A**T * X = B (Transpose) = 'C': A**H * X = B (Conjugate Transpose = Transpose)``` [in] N ``` N is INTEGER The number of linear equations, i.e., the order of the matrix A. N >= 0.``` [in] KL ``` KL is INTEGER The number of subdiagonals within the band of A. KL >= 0.``` [in] KU ``` KU is INTEGER The number of superdiagonals within the band of A. KU >= 0.``` [in] NRHS ``` NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices B and X. NRHS >= 0.``` [in,out] AB ``` AB is COMPLEX*16 array, dimension (LDAB,N) On entry, the matrix A in band storage, in rows 1 to KL+KU+1. The j-th column of A is stored in the j-th column of the array AB as follows: AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl) If FACT = 'F' and EQUED is not 'N', then AB must have been equilibrated by the scaling factors in R and/or C. AB is not modified if FACT = 'F' or 'N', or if FACT = 'E' and EQUED = 'N' on exit. On exit, if EQUED .ne. 'N', A is scaled as follows: EQUED = 'R': A := diag(R) * A EQUED = 'C': A := A * diag(C) EQUED = 'B': A := diag(R) * A * diag(C).``` [in] LDAB ``` LDAB is INTEGER The leading dimension of the array AB. LDAB >= KL+KU+1.``` [in,out] AFB ``` AFB is COMPLEX*16 array, dimension (LDAFB,N) If FACT = 'F', then AFB is an input argument and on entry contains details of the LU factorization of the band matrix A, as computed by ZGBTRF. U is stored as an upper triangular band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, and the multipliers used during the factorization are stored in rows KL+KU+2 to 2*KL+KU+1. If EQUED .ne. 'N', then AFB is the factored form of the equilibrated matrix A. If FACT = 'N', then AF is an output argument and on exit returns the factors L and U from the factorization A = P*L*U of the original matrix A. If FACT = 'E', then AF is an output argument and on exit returns the factors L and U from the factorization A = P*L*U of the equilibrated matrix A (see the description of A for the form of the equilibrated matrix).``` [in] LDAFB ``` LDAFB is INTEGER The leading dimension of the array AFB. LDAFB >= 2*KL+KU+1.``` [in,out] IPIV ``` IPIV is INTEGER array, dimension (N) If FACT = 'F', then IPIV is an input argument and on entry contains the pivot indices from the factorization A = P*L*U as computed by ZGETRF; row i of the matrix was interchanged with row IPIV(i). If FACT = 'N', then IPIV is an output argument and on exit contains the pivot indices from the factorization A = P*L*U of the original matrix A. If FACT = 'E', then IPIV is an output argument and on exit contains the pivot indices from the factorization A = P*L*U of the equilibrated matrix A.``` [in,out] EQUED ``` EQUED is CHARACTER*1 Specifies the form of equilibration that was done. = 'N': No equilibration (always true if FACT = 'N'). = 'R': Row equilibration, i.e., A has been premultiplied by diag(R). = 'C': Column equilibration, i.e., A has been postmultiplied by diag(C). = 'B': Both row and column equilibration, i.e., A has been replaced by diag(R) * A * diag(C). EQUED is an input argument if FACT = 'F'; otherwise, it is an output argument.``` [in,out] R ``` R is DOUBLE PRECISION array, dimension (N) The row scale factors for A. If EQUED = 'R' or 'B', A is multiplied on the left by diag(R); if EQUED = 'N' or 'C', R is not accessed. R is an input argument if FACT = 'F'; otherwise, R is an output argument. If FACT = 'F' and EQUED = 'R' or 'B', each element of R must be positive. If R is output, each element of R is a power of the radix. If R is input, each element of R should be a power of the radix to ensure a reliable solution and error estimates. Scaling by powers of the radix does not cause rounding errors unless the result underflows or overflows. Rounding errors during scaling lead to refining with a matrix that is not equivalent to the input matrix, producing error estimates that may not be reliable.``` [in,out] C ``` C is DOUBLE PRECISION array, dimension (N) The column scale factors for A. If EQUED = 'C' or 'B', A is multiplied on the right by diag(C); if EQUED = 'N' or 'R', C is not accessed. C is an input argument if FACT = 'F'; otherwise, C is an output argument. If FACT = 'F' and EQUED = 'C' or 'B', each element of C must be positive. If C is output, each element of C is a power of the radix. If C is input, each element of C should be a power of the radix to ensure a reliable solution and error estimates. Scaling by powers of the radix does not cause rounding errors unless the result underflows or overflows. Rounding errors during scaling lead to refining with a matrix that is not equivalent to the input matrix, producing error estimates that may not be reliable.``` [in,out] B ``` B is COMPLEX*16 array, dimension (LDB,NRHS) On entry, the N-by-NRHS right hand side matrix B. On exit, if EQUED = 'N', B is not modified; if TRANS = 'N' and EQUED = 'R' or 'B', B is overwritten by diag(R)*B; if TRANS = 'T' or 'C' and EQUED = 'C' or 'B', B is overwritten by diag(C)*B.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [out] X ``` X is COMPLEX*16 array, dimension (LDX,NRHS) If INFO = 0, the N-by-NRHS solution matrix X to the original system of equations. Note that A and B are modified on exit if EQUED .ne. 'N', and the solution to the equilibrated system is inv(diag(C))*X if TRANS = 'N' and EQUED = 'C' or 'B', or inv(diag(R))*X if TRANS = 'T' or 'C' and EQUED = 'R' or 'B'.``` [in] LDX ``` LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).``` [out] RCOND ``` RCOND is DOUBLE PRECISION Reciprocal scaled condition number. This is an estimate of the reciprocal Skeel condition number of the matrix A after equilibration (if done). If this is less than the machine precision (in particular, if it is zero), the matrix is singular to working precision. Note that the error may still be small even if this number is very small and the matrix appears ill- conditioned.``` [out] RPVGRW ``` RPVGRW is DOUBLE PRECISION Reciprocal pivot growth. On exit, this contains the reciprocal pivot growth factor norm(A)/norm(U). The "max absolute element" norm is used. If this is much less than 1, then the stability of the LU factorization of the (equilibrated) matrix A could be poor. This also means that the solution X, estimated condition numbers, and error bounds could be unreliable. If factorization fails with 0 0 and <= N: U(INFO,INFO) is exactly zero. The factorization has been completed, but the factor U is exactly singular, so the solution and error bounds could not be computed. RCOND = 0 is returned. = N+J: The solution corresponding to the Jth right-hand side is not guaranteed. The solutions corresponding to other right- hand sides K with K > J may not be guaranteed as well, but only the first such right-hand side is reported. If a small componentwise error is not requested (PARAMS(3) = 0.0) then the Jth right-hand side is the first with a normwise error bound that is not guaranteed (the smallest J such that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0) the Jth right-hand side is the first with either a normwise or componentwise error bound that is not guaranteed (the smallest J such that either ERR_BNDS_NORM(J,1) = 0.0 or ERR_BNDS_COMP(J,1) = 0.0). See the definition of ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information about all of the right-hand sides check ERR_BNDS_NORM or ERR_BNDS_COMP.```

Definition at line 555 of file zgbsvxx.f.

560 *
561 * -- LAPACK driver routine --
562 * -- LAPACK is a software package provided by Univ. of Tennessee, --
563 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
564 *
565 * .. Scalar Arguments ..
566  CHARACTER EQUED, FACT, TRANS
567  INTEGER INFO, LDAB, LDAFB, LDB, LDX, N, NRHS, NPARAMS,
568  \$ N_ERR_BNDS
569  DOUBLE PRECISION RCOND, RPVGRW
570 * ..
571 * .. Array Arguments ..
572  INTEGER IPIV( * )
573  COMPLEX*16 AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
574  \$ X( LDX , * ),WORK( * )
575  DOUBLE PRECISION R( * ), C( * ), PARAMS( * ), BERR( * ),
576  \$ ERR_BNDS_NORM( NRHS, * ),
577  \$ ERR_BNDS_COMP( NRHS, * ), RWORK( * )
578 * ..
579 *
580 * ==================================================================
581 *
582 * .. Parameters ..
583  DOUBLE PRECISION ZERO, ONE
584  parameter( zero = 0.0d+0, one = 1.0d+0 )
585  INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
586  INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
587  INTEGER CMP_ERR_I, PIV_GROWTH_I
588  parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
589  \$ berr_i = 3 )
590  parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
591  parameter( cmp_rcond_i = 7, cmp_err_i = 8,
592  \$ piv_growth_i = 9 )
593 * ..
594 * .. Local Scalars ..
595  LOGICAL COLEQU, EQUIL, NOFACT, NOTRAN, ROWEQU
596  INTEGER INFEQU, I, J, KL, KU
597  DOUBLE PRECISION AMAX, BIGNUM, COLCND, RCMAX, RCMIN,
598  \$ ROWCND, SMLNUM
599 * ..
600 * .. External Functions ..
601  EXTERNAL lsame, dlamch, zla_gbrpvgrw
602  LOGICAL LSAME
603  DOUBLE PRECISION DLAMCH, ZLA_GBRPVGRW
604 * ..
605 * .. External Subroutines ..
606  EXTERNAL zgbequb, zgbtrf, zgbtrs, zlacpy, zlaqgb,
608 * ..
609 * .. Intrinsic Functions ..
610  INTRINSIC max, min
611 * ..
612 * .. Executable Statements ..
613 *
614  info = 0
615  nofact = lsame( fact, 'N' )
616  equil = lsame( fact, 'E' )
617  notran = lsame( trans, 'N' )
618  smlnum = dlamch( 'Safe minimum' )
619  bignum = one / smlnum
620  IF( nofact .OR. equil ) THEN
621  equed = 'N'
622  rowequ = .false.
623  colequ = .false.
624  ELSE
625  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
626  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
627  END IF
628 *
629 * Default is failure. If an input parameter is wrong or
630 * factorization fails, make everything look horrible. Only the
631 * pivot growth is set here, the rest is initialized in ZGBRFSX.
632 *
633  rpvgrw = zero
634 *
635 * Test the input parameters. PARAMS is not tested until ZGERFSX.
636 *
637  IF( .NOT.nofact .AND. .NOT.equil .AND. .NOT.
638  \$ lsame( fact, 'F' ) ) THEN
639  info = -1
640  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
641  \$ lsame( trans, 'C' ) ) THEN
642  info = -2
643  ELSE IF( n.LT.0 ) THEN
644  info = -3
645  ELSE IF( kl.LT.0 ) THEN
646  info = -4
647  ELSE IF( ku.LT.0 ) THEN
648  info = -5
649  ELSE IF( nrhs.LT.0 ) THEN
650  info = -6
651  ELSE IF( ldab.LT.kl+ku+1 ) THEN
652  info = -8
653  ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
654  info = -10
655  ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
656  \$ ( rowequ .OR. colequ .OR. lsame( equed, 'N' ) ) ) THEN
657  info = -12
658  ELSE
659  IF( rowequ ) THEN
660  rcmin = bignum
661  rcmax = zero
662  DO 10 j = 1, n
663  rcmin = min( rcmin, r( j ) )
664  rcmax = max( rcmax, r( j ) )
665  10 CONTINUE
666  IF( rcmin.LE.zero ) THEN
667  info = -13
668  ELSE IF( n.GT.0 ) THEN
669  rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
670  ELSE
671  rowcnd = one
672  END IF
673  END IF
674  IF( colequ .AND. info.EQ.0 ) THEN
675  rcmin = bignum
676  rcmax = zero
677  DO 20 j = 1, n
678  rcmin = min( rcmin, c( j ) )
679  rcmax = max( rcmax, c( j ) )
680  20 CONTINUE
681  IF( rcmin.LE.zero ) THEN
682  info = -14
683  ELSE IF( n.GT.0 ) THEN
684  colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
685  ELSE
686  colcnd = one
687  END IF
688  END IF
689  IF( info.EQ.0 ) THEN
690  IF( ldb.LT.max( 1, n ) ) THEN
691  info = -15
692  ELSE IF( ldx.LT.max( 1, n ) ) THEN
693  info = -16
694  END IF
695  END IF
696  END IF
697 *
698  IF( info.NE.0 ) THEN
699  CALL xerbla( 'ZGBSVXX', -info )
700  RETURN
701  END IF
702 *
703  IF( equil ) THEN
704 *
705 * Compute row and column scalings to equilibrate the matrix A.
706 *
707  CALL zgbequb( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
708  \$ amax, infequ )
709  IF( infequ.EQ.0 ) THEN
710 *
711 * Equilibrate the matrix.
712 *
713  CALL zlaqgb( n, n, kl, ku, ab, ldab, r, c, rowcnd, colcnd,
714  \$ amax, equed )
715  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
716  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
717  END IF
718 *
719 * If the scaling factors are not applied, set them to 1.0.
720 *
721  IF ( .NOT.rowequ ) THEN
722  DO j = 1, n
723  r( j ) = 1.0d+0
724  END DO
725  END IF
726  IF ( .NOT.colequ ) THEN
727  DO j = 1, n
728  c( j ) = 1.0d+0
729  END DO
730  END IF
731  END IF
732 *
733 * Scale the right-hand side.
734 *
735  IF( notran ) THEN
736  IF( rowequ ) CALL zlascl2( n, nrhs, r, b, ldb )
737  ELSE
738  IF( colequ ) CALL zlascl2( n, nrhs, c, b, ldb )
739  END IF
740 *
741  IF( nofact .OR. equil ) THEN
742 *
743 * Compute the LU factorization of A.
744 *
745  DO 40, j = 1, n
746  DO 30, i = kl+1, 2*kl+ku+1
747  afb( i, j ) = ab( i-kl, j )
748  30 CONTINUE
749  40 CONTINUE
750  CALL zgbtrf( n, n, kl, ku, afb, ldafb, ipiv, info )
751 *
752 * Return if INFO is non-zero.
753 *
754  IF( info.GT.0 ) THEN
755 *
756 * Pivot in column INFO is exactly 0
757 * Compute the reciprocal pivot growth factor of the
758 * leading rank-deficient INFO columns of A.
759 *
760  rpvgrw = zla_gbrpvgrw( n, kl, ku, info, ab, ldab, afb,
761  \$ ldafb )
762  RETURN
763  END IF
764  END IF
765 *
766 * Compute the reciprocal pivot growth factor RPVGRW.
767 *
768  rpvgrw = zla_gbrpvgrw( n, kl, ku, n, ab, ldab, afb, ldafb )
769 *
770 * Compute the solution matrix X.
771 *
772  CALL zlacpy( 'Full', n, nrhs, b, ldb, x, ldx )
773  CALL zgbtrs( trans, n, kl, ku, nrhs, afb, ldafb, ipiv, x, ldx,
774  \$ info )
775 *
776 * Use iterative refinement to improve the computed solution and
777 * compute error bounds and backward error estimates for it.
778 *
779  CALL zgbrfsx( trans, equed, n, kl, ku, nrhs, ab, ldab, afb, ldafb,
780  \$ ipiv, r, c, b, ldb, x, ldx, rcond, berr,
781  \$ n_err_bnds, err_bnds_norm, err_bnds_comp, nparams, params,
782  \$ work, rwork, info )
783
784 *
785 * Scale solutions.
786 *
787  IF ( colequ .AND. notran ) THEN
788  CALL zlascl2( n, nrhs, c, x, ldx )
789  ELSE IF ( rowequ .AND. .NOT.notran ) THEN
790  CALL zlascl2( n, nrhs, r, x, ldx )
791  END IF
792 *
793  RETURN
794 *
795 * End of ZGBSVXX
796 *
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine zlaqgb(M, N, KL, KU, AB, LDAB, R, C, ROWCND, COLCND, AMAX, EQUED)
ZLAQGB scales a general band matrix, using row and column scaling factors computed by sgbequ.
Definition: zlaqgb.f:160
subroutine zgbequb(M, N, KL, KU, AB, LDAB, R, C, ROWCND, COLCND, AMAX, INFO)
ZGBEQUB
Definition: zgbequb.f:161
subroutine zgbtrf(M, N, KL, KU, AB, LDAB, IPIV, INFO)
ZGBTRF
Definition: zgbtrf.f:144
double precision function zla_gbrpvgrw(N, KL, KU, NCOLS, AB, LDAB, AFB, LDAFB)
ZLA_GBRPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a general banded matrix.
Definition: zla_gbrpvgrw.f:117
subroutine zgbrfsx(TRANS, EQUED, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB, IPIV, R, C, B, LDB, X, LDX, RCOND, BERR, N_ERR_BNDS, ERR_BNDS_NORM, ERR_BNDS_COMP, NPARAMS, PARAMS, WORK, RWORK, INFO)
ZGBRFSX
Definition: zgbrfsx.f:440
subroutine zgbtrs(TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB, INFO)
ZGBTRS
Definition: zgbtrs.f:138
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:103
subroutine zlascl2(M, N, D, X, LDX)
ZLASCL2 performs diagonal scaling on a vector.
Definition: zlascl2.f:91
Here is the call graph for this function:
Here is the caller graph for this function: