chet01_aa.f

Go to the documentation of this file.

*> \brief \b CHET01_AA
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CHET01_AA( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV,
*                             C, LDC, RWORK, RESID )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            LDA, LDAFAC, LDC, N
*       REAL               RESID
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       REAL               RWORK( * )
*       COMPLEX            A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CHET01_AA reconstructs a hermitian indefinite matrix A from its
*> block L*D*L' or U*D*U' factorization and computes the residual
*>    norm( C - A ) / ( N * norm(A) * EPS ),
*> where C is the reconstructed matrix and EPS is the machine epsilon.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          hermitian matrix A is stored:
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows and columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          The original hermitian matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N)
*> \endverbatim
*>
*> \param[in] AFAC
*> \verbatim
*>          AFAC is COMPLEX array, dimension (LDAFAC,N)
*>          The factored form of the matrix A.  AFAC contains the block
*>          diagonal matrix D and the multipliers used to obtain the
*>          factor L or U from the block L*D*L' or U*D*U' factorization
*>          as computed by CHETRF.
*> \endverbatim
*>
*> \param[in] LDAFAC
*> \verbatim
*>          LDAFAC is INTEGER
*>          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          The pivot indices from CHETRF.
*> \endverbatim
*>
*> \param[out] C
*> \verbatim
*>          C is COMPLEX array, dimension (LDC,N)
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*>          LDC is INTEGER
*>          The leading dimension of the array C.  LDC >= max(1,N).
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is COMPLEX array, dimension (N)
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*>          RESID is COMPLEX
*>          If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
*>          If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE chet01_aa( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C,
     $                      LDC, RWORK, RESID )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDA, LDAFAC, LDC, N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      REAL               RWORK( * )
      COMPLEX            A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX         CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                     cone  = ( 1.0e+0, 0.0e+0 ) )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               ANORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, CLANHE
      EXTERNAL           lsame, slamch, clanhe
*     ..
*     .. External Subroutines ..
      EXTERNAL           claset, clavhe
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      anorm = clanhe( '1', uplo, n, a, lda, rwork )
*
*     Initialize C to the tridiagonal matrix T.
*
      CALL claset( 'Full', n, n, czero, czero, c, ldc )
      CALL clacpy( 'F', 1, n, afac( 1, 1 ), ldafac+1, c( 1, 1 ), ldc+1 )
      IF( n.GT.1 ) THEN
         IF( lsame( uplo, 'U' ) ) THEN
            CALL clacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 1, 2 ),
     $                   ldc+1 )
            CALL clacpy( 'F', 1, n-1, afac( 1, 2 ), ldafac+1, c( 2, 1 ),
     $                   ldc+1 )
            CALL clacgv( n-1, c( 2, 1 ), ldc+1 )
         ELSE
            CALL clacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 1, 2 ),
     $                   ldc+1 )
            CALL clacpy( 'F', 1, n-1, afac( 2, 1 ), ldafac+1, c( 2, 1 ),
     $                   ldc+1 )
            CALL clacgv( n-1, c( 1, 2 ), ldc+1 )
         ENDIF
*
*        Call CTRMM to form the product U' * D (or L * D ).
*
         IF( lsame( uplo, 'U' ) ) THEN
            CALL ctrmm( 'Left', uplo, 'Conjugate transpose', 'Unit',
     $                  n-1, n, cone, afac( 1, 2 ), ldafac, c( 2, 1 ),
     $                  ldc )
         ELSE
            CALL ctrmm( 'Left', uplo, 'No transpose', 'Unit', n-1, n,
     $                  cone, afac( 2, 1 ), ldafac, c( 2, 1 ), ldc )
         END IF
*
*        Call CTRMM again to multiply by U (or L ).
*
         IF( lsame( uplo, 'U' ) ) THEN
            CALL ctrmm( 'Right', uplo, 'No transpose', 'Unit', n, n-1,
     $                  cone, afac( 1, 2 ), ldafac, c( 1, 2 ), ldc )
         ELSE
            CALL ctrmm( 'Right', uplo, 'Conjugate transpose', 'Unit', n,
     $                  n-1, cone, afac( 2, 1 ), ldafac, c( 1, 2 ),
     $                  ldc )
         END IF
      ENDIF
*
*     Apply hermitian pivots
*
      DO j = n, 1, -1
         i = ipiv( j )
         IF( i.NE.j )
     $      CALL cswap( n, c( j, 1 ), ldc, c( i, 1 ), ldc )
      END DO
      DO j = n, 1, -1
         i = ipiv( j )
         IF( i.NE.j )
     $      CALL cswap( n, c( 1, j ), 1, c( 1, i ), 1 )
      END DO
*
*
*     Compute the difference  C - A .
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO j = 1, n
            DO i = 1, j
               c( i, j ) = c( i, j ) - a( i, j )
            END DO
         END DO
      ELSE
         DO j = 1, n
            DO i = j, n
               c( i, j ) = c( i, j ) - a( i, j )
            END DO
         END DO
      END IF
*
*     Compute norm( C - A ) / ( N * norm(A) * EPS )
*
      resid = clanhe( '1', uplo, n, c, ldc, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / real( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of CHET01_AA
*
      END