LAPACK  3.10.1 LAPACK: Linear Algebra PACKage
slaed1.f
Go to the documentation of this file.
1 *> \brief \b SLAED1 used by SSTEDC. Computes the updated eigensystem of a diagonal matrix after modification by a rank-one symmetric matrix. Used when the original matrix is tridiagonal.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slaed1.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slaed1.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slaed1.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SLAED1( N, D, Q, LDQ, INDXQ, RHO, CUTPNT, WORK, IWORK,
22 * INFO )
23 *
24 * .. Scalar Arguments ..
25 * INTEGER CUTPNT, INFO, LDQ, N
26 * REAL RHO
27 * ..
28 * .. Array Arguments ..
29 * INTEGER INDXQ( * ), IWORK( * )
30 * REAL D( * ), Q( LDQ, * ), WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> SLAED1 computes the updated eigensystem of a diagonal
40 *> matrix after modification by a rank-one symmetric matrix. This
41 *> routine is used only for the eigenproblem which requires all
42 *> eigenvalues and eigenvectors of a tridiagonal matrix. SLAED7 handles
43 *> the case in which eigenvalues only or eigenvalues and eigenvectors
44 *> of a full symmetric matrix (which was reduced to tridiagonal form)
45 *> are desired.
46 *>
47 *> T = Q(in) ( D(in) + RHO * Z*Z**T ) Q**T(in) = Q(out) * D(out) * Q**T(out)
48 *>
49 *> where Z = Q**T*u, u is a vector of length N with ones in the
50 *> CUTPNT and CUTPNT + 1 th elements and zeros elsewhere.
51 *>
52 *> The eigenvectors of the original matrix are stored in Q, and the
53 *> eigenvalues are in D. The algorithm consists of three stages:
54 *>
55 *> The first stage consists of deflating the size of the problem
56 *> when there are multiple eigenvalues or if there is a zero in
57 *> the Z vector. For each such occurrence the dimension of the
58 *> secular equation problem is reduced by one. This stage is
59 *> performed by the routine SLAED2.
60 *>
61 *> The second stage consists of calculating the updated
62 *> eigenvalues. This is done by finding the roots of the secular
63 *> equation via the routine SLAED4 (as called by SLAED3).
64 *> This routine also calculates the eigenvectors of the current
65 *> problem.
66 *>
67 *> The final stage consists of computing the updated eigenvectors
68 *> directly using the updated eigenvalues. The eigenvectors for
69 *> the current problem are multiplied with the eigenvectors from
70 *> the overall problem.
71 *> \endverbatim
72 *
73 * Arguments:
74 * ==========
75 *
76 *> \param[in] N
77 *> \verbatim
78 *> N is INTEGER
79 *> The dimension of the symmetric tridiagonal matrix. N >= 0.
80 *> \endverbatim
81 *>
82 *> \param[in,out] D
83 *> \verbatim
84 *> D is REAL array, dimension (N)
85 *> On entry, the eigenvalues of the rank-1-perturbed matrix.
86 *> On exit, the eigenvalues of the repaired matrix.
87 *> \endverbatim
88 *>
89 *> \param[in,out] Q
90 *> \verbatim
91 *> Q is REAL array, dimension (LDQ,N)
92 *> On entry, the eigenvectors of the rank-1-perturbed matrix.
93 *> On exit, the eigenvectors of the repaired tridiagonal matrix.
94 *> \endverbatim
95 *>
96 *> \param[in] LDQ
97 *> \verbatim
98 *> LDQ is INTEGER
99 *> The leading dimension of the array Q. LDQ >= max(1,N).
100 *> \endverbatim
101 *>
102 *> \param[in,out] INDXQ
103 *> \verbatim
104 *> INDXQ is INTEGER array, dimension (N)
105 *> On entry, the permutation which separately sorts the two
106 *> subproblems in D into ascending order.
107 *> On exit, the permutation which will reintegrate the
108 *> subproblems back into sorted order,
109 *> i.e. D( INDXQ( I = 1, N ) ) will be in ascending order.
110 *> \endverbatim
111 *>
112 *> \param[in] RHO
113 *> \verbatim
114 *> RHO is REAL
115 *> The subdiagonal entry used to create the rank-1 modification.
116 *> \endverbatim
117 *>
118 *> \param[in] CUTPNT
119 *> \verbatim
120 *> CUTPNT is INTEGER
121 *> The location of the last eigenvalue in the leading sub-matrix.
122 *> min(1,N) <= CUTPNT <= N/2.
123 *> \endverbatim
124 *>
125 *> \param[out] WORK
126 *> \verbatim
127 *> WORK is REAL array, dimension (4*N + N**2)
128 *> \endverbatim
129 *>
130 *> \param[out] IWORK
131 *> \verbatim
132 *> IWORK is INTEGER array, dimension (4*N)
133 *> \endverbatim
134 *>
135 *> \param[out] INFO
136 *> \verbatim
137 *> INFO is INTEGER
138 *> = 0: successful exit.
139 *> < 0: if INFO = -i, the i-th argument had an illegal value.
140 *> > 0: if INFO = 1, an eigenvalue did not converge
141 *> \endverbatim
142 *
143 * Authors:
144 * ========
145 *
146 *> \author Univ. of Tennessee
147 *> \author Univ. of California Berkeley
148 *> \author Univ. of Colorado Denver
149 *> \author NAG Ltd.
150 *
151 *> \ingroup auxOTHERcomputational
152 *
153 *> \par Contributors:
154 * ==================
155 *>
156 *> Jeff Rutter, Computer Science Division, University of California
157 *> at Berkeley, USA \n
158 *> Modified by Francoise Tisseur, University of Tennessee
159 *>
160 * =====================================================================
161  SUBROUTINE slaed1( N, D, Q, LDQ, INDXQ, RHO, CUTPNT, WORK, IWORK,
162  \$ INFO )
163 *
164 * -- LAPACK computational routine --
165 * -- LAPACK is a software package provided by Univ. of Tennessee, --
166 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
167 *
168 * .. Scalar Arguments ..
169  INTEGER CUTPNT, INFO, LDQ, N
170  REAL RHO
171 * ..
172 * .. Array Arguments ..
173  INTEGER INDXQ( * ), IWORK( * )
174  REAL D( * ), Q( LDQ, * ), WORK( * )
175 * ..
176 *
177 * =====================================================================
178 *
179 * .. Local Scalars ..
180  INTEGER COLTYP, CPP1, I, IDLMDA, INDX, INDXC, INDXP,
181  \$ iq2, is, iw, iz, k, n1, n2
182 * ..
183 * .. External Subroutines ..
184  EXTERNAL scopy, slaed2, slaed3, slamrg, xerbla
185 * ..
186 * .. Intrinsic Functions ..
187  INTRINSIC max, min
188 * ..
189 * .. Executable Statements ..
190 *
191 * Test the input parameters.
192 *
193  info = 0
194 *
195  IF( n.LT.0 ) THEN
196  info = -1
197  ELSE IF( ldq.LT.max( 1, n ) ) THEN
198  info = -4
199  ELSE IF( min( 1, n / 2 ).GT.cutpnt .OR. ( n / 2 ).LT.cutpnt ) THEN
200  info = -7
201  END IF
202  IF( info.NE.0 ) THEN
203  CALL xerbla( 'SLAED1', -info )
204  RETURN
205  END IF
206 *
207 * Quick return if possible
208 *
209  IF( n.EQ.0 )
210  \$ RETURN
211 *
212 * The following values are integer pointers which indicate
213 * the portion of the workspace
214 * used by a particular array in SLAED2 and SLAED3.
215 *
216  iz = 1
217  idlmda = iz + n
218  iw = idlmda + n
219  iq2 = iw + n
220 *
221  indx = 1
222  indxc = indx + n
223  coltyp = indxc + n
224  indxp = coltyp + n
225 *
226 *
227 * Form the z-vector which consists of the last row of Q_1 and the
228 * first row of Q_2.
229 *
230  CALL scopy( cutpnt, q( cutpnt, 1 ), ldq, work( iz ), 1 )
231  cpp1 = cutpnt + 1
232  CALL scopy( n-cutpnt, q( cpp1, cpp1 ), ldq, work( iz+cutpnt ), 1 )
233 *
234 * Deflate eigenvalues.
235 *
236  CALL slaed2( k, n, cutpnt, d, q, ldq, indxq, rho, work( iz ),
237  \$ work( idlmda ), work( iw ), work( iq2 ),
238  \$ iwork( indx ), iwork( indxc ), iwork( indxp ),
239  \$ iwork( coltyp ), info )
240 *
241  IF( info.NE.0 )
242  \$ GO TO 20
243 *
244 * Solve Secular Equation.
245 *
246  IF( k.NE.0 ) THEN
247  is = ( iwork( coltyp )+iwork( coltyp+1 ) )*cutpnt +
248  \$ ( iwork( coltyp+1 )+iwork( coltyp+2 ) )*( n-cutpnt ) + iq2
249  CALL slaed3( k, n, cutpnt, d, q, ldq, rho, work( idlmda ),
250  \$ work( iq2 ), iwork( indxc ), iwork( coltyp ),
251  \$ work( iw ), work( is ), info )
252  IF( info.NE.0 )
253  \$ GO TO 20
254 *
255 * Prepare the INDXQ sorting permutation.
256 *
257  n1 = k
258  n2 = n - k
259  CALL slamrg( n1, n2, d, 1, -1, indxq )
260  ELSE
261  DO 10 i = 1, n
262  indxq( i ) = i
263  10 CONTINUE
264  END IF
265 *
266  20 CONTINUE
267  RETURN
268 *
269 * End of SLAED1
270 *
271  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slamrg(N1, N2, A, STRD1, STRD2, INDEX)
SLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition: slamrg.f:99
subroutine slaed3(K, N, N1, D, Q, LDQ, RHO, DLAMDA, Q2, INDX, CTOT, W, S, INFO)
SLAED3 used by SSTEDC. Finds the roots of the secular equation and updates the eigenvectors....
Definition: slaed3.f:185
subroutine slaed2(K, N, N1, D, Q, LDQ, INDXQ, RHO, Z, DLAMDA, W, Q2, INDX, INDXC, INDXP, COLTYP, INFO)
SLAED2 used by SSTEDC. Merges eigenvalues and deflates secular equation. Used when the original matri...
Definition: slaed2.f:212
subroutine slaed1(N, D, Q, LDQ, INDXQ, RHO, CUTPNT, WORK, IWORK, INFO)
SLAED1 used by SSTEDC. Computes the updated eigensystem of a diagonal matrix after modification by a ...
Definition: slaed1.f:163
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:82