LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ sgeqr2p()

 subroutine sgeqr2p ( integer M, integer N, real, dimension( lda, * ) A, integer LDA, real, dimension( * ) TAU, real, dimension( * ) WORK, integer INFO )

SGEQR2P computes the QR factorization of a general rectangular matrix with non-negative diagonal elements using an unblocked algorithm.

Purpose:
``` SGEQR2P computes a QR factorization of a real m-by-n matrix A:

A = Q * ( R ),
( 0 )

where:

Q is a m-by-m orthogonal matrix;
R is an upper-triangular n-by-n matrix with nonnegative diagonal
entries;
0 is a (m-n)-by-n zero matrix, if m > n.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix A. N >= 0.``` [in,out] A ``` A is REAL array, dimension (LDA,N) On entry, the m by n matrix A. On exit, the elements on and above the diagonal of the array contain the min(m,n) by n upper trapezoidal matrix R (R is upper triangular if m >= n). The diagonal entries of R are nonnegative; the elements below the diagonal, with the array TAU, represent the orthogonal matrix Q as a product of elementary reflectors (see Further Details).``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).``` [out] TAU ``` TAU is REAL array, dimension (min(M,N)) The scalar factors of the elementary reflectors (see Further Details).``` [out] WORK ` WORK is REAL array, dimension (N)` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value```
Further Details:
```  The matrix Q is represented as a product of elementary reflectors

Q = H(1) H(2) . . . H(k), where k = min(m,n).

Each H(i) has the form

H(i) = I - tau * v * v**T

where tau is a real scalar, and v is a real vector with
v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i),
and tau in TAU(i).

See Lapack Working Note 203 for details```

Definition at line 133 of file sgeqr2p.f.

134 *
135 * -- LAPACK computational routine --
136 * -- LAPACK is a software package provided by Univ. of Tennessee, --
137 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
138 *
139 * .. Scalar Arguments ..
140  INTEGER INFO, LDA, M, N
141 * ..
142 * .. Array Arguments ..
143  REAL A( LDA, * ), TAU( * ), WORK( * )
144 * ..
145 *
146 * =====================================================================
147 *
148 * .. Parameters ..
149  REAL ONE
150  parameter( one = 1.0e+0 )
151 * ..
152 * .. Local Scalars ..
153  INTEGER I, K
154  REAL AII
155 * ..
156 * .. External Subroutines ..
157  EXTERNAL slarf, slarfgp, xerbla
158 * ..
159 * .. Intrinsic Functions ..
160  INTRINSIC max, min
161 * ..
162 * .. Executable Statements ..
163 *
164 * Test the input arguments
165 *
166  info = 0
167  IF( m.LT.0 ) THEN
168  info = -1
169  ELSE IF( n.LT.0 ) THEN
170  info = -2
171  ELSE IF( lda.LT.max( 1, m ) ) THEN
172  info = -4
173  END IF
174  IF( info.NE.0 ) THEN
175  CALL xerbla( 'SGEQR2P', -info )
176  RETURN
177  END IF
178 *
179  k = min( m, n )
180 *
181  DO 10 i = 1, k
182 *
183 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
184 *
185  CALL slarfgp( m-i+1, a( i, i ), a( min( i+1, m ), i ), 1,
186  \$ tau( i ) )
187  IF( i.LT.n ) THEN
188 *
189 * Apply H(i) to A(i:m,i+1:n) from the left
190 *
191  aii = a( i, i )
192  a( i, i ) = one
193  CALL slarf( 'Left', m-i+1, n-i, a( i, i ), 1, tau( i ),
194  \$ a( i, i+1 ), lda, work )
195  a( i, i ) = aii
196  END IF
197  10 CONTINUE
198  RETURN
199 *
200 * End of SGEQR2P
201 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slarfgp(N, ALPHA, X, INCX, TAU)
SLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: slarfgp.f:104
subroutine slarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition: slarf.f:124
Here is the call graph for this function:
Here is the caller graph for this function: