LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ sgbrfsx()

subroutine sgbrfsx ( character  TRANS,
character  EQUED,
integer  N,
integer  KL,
integer  KU,
integer  NRHS,
real, dimension( ldab, * )  AB,
integer  LDAB,
real, dimension( ldafb, * )  AFB,
integer  LDAFB,
integer, dimension( * )  IPIV,
real, dimension( * )  R,
real, dimension( * )  C,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( ldx , * )  X,
integer  LDX,
real  RCOND,
real, dimension( * )  BERR,
integer  N_ERR_BNDS,
real, dimension( nrhs, * )  ERR_BNDS_NORM,
real, dimension( nrhs, * )  ERR_BNDS_COMP,
integer  NPARAMS,
real, dimension( * )  PARAMS,
real, dimension( * )  WORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

SGBRFSX

Download SGBRFSX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
    SGBRFSX improves the computed solution to a system of linear
    equations and provides error bounds and backward error estimates
    for the solution.  In addition to normwise error bound, the code
    provides maximum componentwise error bound if possible.  See
    comments for ERR_BNDS_NORM and ERR_BNDS_COMP for details of the
    error bounds.

    The original system of linear equations may have been equilibrated
    before calling this routine, as described by arguments EQUED, R
    and C below. In this case, the solution and error bounds returned
    are for the original unequilibrated system.
     Some optional parameters are bundled in the PARAMS array.  These
     settings determine how refinement is performed, but often the
     defaults are acceptable.  If the defaults are acceptable, users
     can pass NPARAMS = 0 which prevents the source code from accessing
     the PARAMS argument.
Parameters
[in]TRANS
          TRANS is CHARACTER*1
     Specifies the form of the system of equations:
       = 'N':  A * X = B     (No transpose)
       = 'T':  A**T * X = B  (Transpose)
       = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
[in]EQUED
          EQUED is CHARACTER*1
     Specifies the form of equilibration that was done to A
     before calling this routine. This is needed to compute
     the solution and error bounds correctly.
       = 'N':  No equilibration
       = 'R':  Row equilibration, i.e., A has been premultiplied by
               diag(R).
       = 'C':  Column equilibration, i.e., A has been postmultiplied
               by diag(C).
       = 'B':  Both row and column equilibration, i.e., A has been
               replaced by diag(R) * A * diag(C).
               The right hand side B has been changed accordingly.
[in]N
          N is INTEGER
     The order of the matrix A.  N >= 0.
[in]KL
          KL is INTEGER
     The number of subdiagonals within the band of A.  KL >= 0.
[in]KU
          KU is INTEGER
     The number of superdiagonals within the band of A.  KU >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right hand sides, i.e., the number of columns
     of the matrices B and X.  NRHS >= 0.
[in]AB
          AB is REAL array, dimension (LDAB,N)
     The original band matrix A, stored in rows 1 to KL+KU+1.
     The j-th column of A is stored in the j-th column of the
     array AB as follows:
     AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
[in]LDAB
          LDAB is INTEGER
     The leading dimension of the array AB.  LDAB >= KL+KU+1.
[in]AFB
          AFB is REAL array, dimension (LDAFB,N)
     Details of the LU factorization of the band matrix A, as
     computed by DGBTRF.  U is stored as an upper triangular band
     matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, and
     the multipliers used during the factorization are stored in
     rows KL+KU+2 to 2*KL+KU+1.
[in]LDAFB
          LDAFB is INTEGER
     The leading dimension of the array AFB.  LDAFB >= 2*KL*KU+1.
[in]IPIV
          IPIV is INTEGER array, dimension (N)
     The pivot indices from SGETRF; for 1<=i<=N, row i of the
     matrix was interchanged with row IPIV(i).
[in,out]R
          R is REAL array, dimension (N)
     The row scale factors for A.  If EQUED = 'R' or 'B', A is
     multiplied on the left by diag(R); if EQUED = 'N' or 'C', R
     is not accessed.  R is an input argument if FACT = 'F';
     otherwise, R is an output argument.  If FACT = 'F' and
     EQUED = 'R' or 'B', each element of R must be positive.
     If R is output, each element of R is a power of the radix.
     If R is input, each element of R should be a power of the radix
     to ensure a reliable solution and error estimates. Scaling by
     powers of the radix does not cause rounding errors unless the
     result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in,out]C
          C is REAL array, dimension (N)
     The column scale factors for A.  If EQUED = 'C' or 'B', A is
     multiplied on the right by diag(C); if EQUED = 'N' or 'R', C
     is not accessed.  C is an input argument if FACT = 'F';
     otherwise, C is an output argument.  If FACT = 'F' and
     EQUED = 'C' or 'B', each element of C must be positive.
     If C is output, each element of C is a power of the radix.
     If C is input, each element of C should be a power of the radix
     to ensure a reliable solution and error estimates. Scaling by
     powers of the radix does not cause rounding errors unless the
     result underflows or overflows. Rounding errors during scaling
     lead to refining with a matrix that is not equivalent to the
     input matrix, producing error estimates that may not be
     reliable.
[in]B
          B is REAL array, dimension (LDB,NRHS)
     The right hand side matrix B.
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[in,out]X
          X is REAL array, dimension (LDX,NRHS)
     On entry, the solution matrix X, as computed by SGETRS.
     On exit, the improved solution matrix X.
[in]LDX
          LDX is INTEGER
     The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is REAL
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[out]BERR
          BERR is REAL array, dimension (NRHS)
     Componentwise relative backward error.  This is the
     componentwise relative backward error of each solution vector X(j)
     (i.e., the smallest relative change in any element of A or B that
     makes X(j) an exact solution).
[in]N_ERR_BNDS
          N_ERR_BNDS is INTEGER
     Number of error bounds to return for each right hand side
     and each type (normwise or componentwise).  See ERR_BNDS_NORM and
     ERR_BNDS_COMP below.
[out]ERR_BNDS_NORM
          ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[out]ERR_BNDS_COMP
          ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[in]NPARAMS
          NPARAMS is INTEGER
     Specifies the number of parameters set in PARAMS.  If .LE. 0, the
     PARAMS array is never referenced and default values are used.
[in,out]PARAMS
          PARAMS is REAL array, dimension NPARAMS
     Specifies algorithm parameters.  If an entry is .LT. 0.0, then
     that entry will be filled with default value used for that
     parameter.  Only positions up to NPARAMS are accessed; defaults
     are used for higher-numbered parameters.

       PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
            refinement or not.
         Default: 1.0
            = 0.0 : No refinement is performed, and no error bounds are
                    computed.
            = 1.0 : Use the double-precision refinement algorithm,
                    possibly with doubled-single computations if the
                    compilation environment does not support DOUBLE
                    PRECISION.
              (other values are reserved for future use)

       PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
            computations allowed for refinement.
         Default: 10
         Aggressive: Set to 100 to permit convergence using approximate
                     factorizations or factorizations other than LU. If
                     the factorization uses a technique other than
                     Gaussian elimination, the guarantees in
                     err_bnds_norm and err_bnds_comp may no longer be
                     trustworthy.

       PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
            will attempt to find a solution with small componentwise
            relative error in the double-precision algorithm.  Positive
            is true, 0.0 is false.
         Default: 1.0 (attempt componentwise convergence)
[out]WORK
          WORK is REAL array, dimension (4*N)
[out]IWORK
          IWORK is INTEGER array, dimension (N)
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit. The solution to every right-hand side is
         guaranteed.
       < 0:  If INFO = -i, the i-th argument had an illegal value
       > 0 and <= N:  U(INFO,INFO) is exactly zero.  The factorization
         has been completed, but the factor U is exactly singular, so
         the solution and error bounds could not be computed. RCOND = 0
         is returned.
       = N+J: The solution corresponding to the Jth right-hand side is
         not guaranteed. The solutions corresponding to other right-
         hand sides K with K > J may not be guaranteed as well, but
         only the first such right-hand side is reported. If a small
         componentwise error is not requested (PARAMS(3) = 0.0) then
         the Jth right-hand side is the first with a normwise error
         bound that is not guaranteed (the smallest J such
         that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
         the Jth right-hand side is the first with either a normwise or
         componentwise error bound that is not guaranteed (the smallest
         J such that either ERR_BNDS_NORM(J,1) = 0.0 or
         ERR_BNDS_COMP(J,1) = 0.0). See the definition of
         ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
         about all of the right-hand sides check ERR_BNDS_NORM or
         ERR_BNDS_COMP.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
April 2012

Definition at line 442 of file sgbrfsx.f.

442 *
443 * -- LAPACK computational routine (version 3.7.0) --
444 * -- LAPACK is a software package provided by Univ. of Tennessee, --
445 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
446 * April 2012
447 *
448 * .. Scalar Arguments ..
449  CHARACTER trans, equed
450  INTEGER info, ldab, ldafb, ldb, ldx, n, kl, ku, nrhs,
451  $ nparams, n_err_bnds
452  REAL rcond
453 * ..
454 * .. Array Arguments ..
455  INTEGER ipiv( * ), iwork( * )
456  REAL ab( ldab, * ), afb( ldafb, * ), b( ldb, * ),
457  $ x( ldx , * ),work( * )
458  REAL r( * ), c( * ), params( * ), berr( * ),
459  $ err_bnds_norm( nrhs, * ),
460  $ err_bnds_comp( nrhs, * )
461 * ..
462 *
463 * ==================================================================
464 *
465 * .. Parameters ..
466  REAL zero, one
467  parameter( zero = 0.0e+0, one = 1.0e+0 )
468  REAL itref_default, ithresh_default,
469  $ componentwise_default
470  REAL rthresh_default, dzthresh_default
471  parameter( itref_default = 1.0 )
472  parameter( ithresh_default = 10.0 )
473  parameter( componentwise_default = 1.0 )
474  parameter( rthresh_default = 0.5 )
475  parameter( dzthresh_default = 0.25 )
476  INTEGER la_linrx_itref_i, la_linrx_ithresh_i,
477  $ la_linrx_cwise_i
478  parameter( la_linrx_itref_i = 1,
479  $ la_linrx_ithresh_i = 2 )
480  parameter( la_linrx_cwise_i = 3 )
481  INTEGER la_linrx_trust_i, la_linrx_err_i,
482  $ la_linrx_rcond_i
483  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
484  parameter( la_linrx_rcond_i = 3 )
485 * ..
486 * .. Local Scalars ..
487  CHARACTER(1) norm
488  LOGICAL rowequ, colequ, notran
489  INTEGER j, trans_type, prec_type, ref_type
490  INTEGER n_norms
491  REAL anorm, rcond_tmp
492  REAL illrcond_thresh, err_lbnd, cwise_wrong
493  LOGICAL ignore_cwise
494  INTEGER ithresh
495  REAL rthresh, unstable_thresh
496 * ..
497 * .. External Subroutines ..
498  EXTERNAL xerbla, sgbcon
499  EXTERNAL sla_gbrfsx_extended
500 * ..
501 * .. Intrinsic Functions ..
502  INTRINSIC max, sqrt
503 * ..
504 * .. External Functions ..
505  EXTERNAL lsame, ilatrans, ilaprec
506  EXTERNAL slamch, slangb, sla_gbrcond
507  REAL slamch, slangb, sla_gbrcond
508  LOGICAL lsame
509  INTEGER ilatrans, ilaprec
510 * ..
511 * .. Executable Statements ..
512 *
513 * Check the input parameters.
514 *
515  info = 0
516  trans_type = ilatrans( trans )
517  ref_type = int( itref_default )
518  IF ( nparams .GE. la_linrx_itref_i ) THEN
519  IF ( params( la_linrx_itref_i ) .LT. 0.0 ) THEN
520  params( la_linrx_itref_i ) = itref_default
521  ELSE
522  ref_type = params( la_linrx_itref_i )
523  END IF
524  END IF
525 *
526 * Set default parameters.
527 *
528  illrcond_thresh = REAL( N ) * slamch( 'Epsilon' )
529  ithresh = int( ithresh_default )
530  rthresh = rthresh_default
531  unstable_thresh = dzthresh_default
532  ignore_cwise = componentwise_default .EQ. 0.0
533 *
534  IF ( nparams.GE.la_linrx_ithresh_i ) THEN
535  IF ( params( la_linrx_ithresh_i ).LT.0.0 ) THEN
536  params( la_linrx_ithresh_i ) = ithresh
537  ELSE
538  ithresh = int( params( la_linrx_ithresh_i ) )
539  END IF
540  END IF
541  IF ( nparams.GE.la_linrx_cwise_i ) THEN
542  IF ( params( la_linrx_cwise_i ).LT.0.0 ) THEN
543  IF ( ignore_cwise ) THEN
544  params( la_linrx_cwise_i ) = 0.0
545  ELSE
546  params( la_linrx_cwise_i ) = 1.0
547  END IF
548  ELSE
549  ignore_cwise = params( la_linrx_cwise_i ) .EQ. 0.0
550  END IF
551  END IF
552  IF ( ref_type .EQ. 0 .OR. n_err_bnds .EQ. 0 ) THEN
553  n_norms = 0
554  ELSE IF ( ignore_cwise ) THEN
555  n_norms = 1
556  ELSE
557  n_norms = 2
558  END IF
559 *
560  notran = lsame( trans, 'N' )
561  rowequ = lsame( equed, 'R' ) .OR. lsame( equed, 'B' )
562  colequ = lsame( equed, 'C' ) .OR. lsame( equed, 'B' )
563 *
564 * Test input parameters.
565 *
566  IF( trans_type.EQ.-1 ) THEN
567  info = -1
568  ELSE IF( .NOT.rowequ .AND. .NOT.colequ .AND.
569  $ .NOT.lsame( equed, 'N' ) ) THEN
570  info = -2
571  ELSE IF( n.LT.0 ) THEN
572  info = -3
573  ELSE IF( kl.LT.0 ) THEN
574  info = -4
575  ELSE IF( ku.LT.0 ) THEN
576  info = -5
577  ELSE IF( nrhs.LT.0 ) THEN
578  info = -6
579  ELSE IF( ldab.LT.kl+ku+1 ) THEN
580  info = -8
581  ELSE IF( ldafb.LT.2*kl+ku+1 ) THEN
582  info = -10
583  ELSE IF( ldb.LT.max( 1, n ) ) THEN
584  info = -13
585  ELSE IF( ldx.LT.max( 1, n ) ) THEN
586  info = -15
587  END IF
588  IF( info.NE.0 ) THEN
589  CALL xerbla( 'SGBRFSX', -info )
590  RETURN
591  END IF
592 *
593 * Quick return if possible.
594 *
595  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
596  rcond = 1.0
597  DO j = 1, nrhs
598  berr( j ) = 0.0
599  IF ( n_err_bnds .GE. 1 ) THEN
600  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
601  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
602  END IF
603  IF ( n_err_bnds .GE. 2 ) THEN
604  err_bnds_norm( j, la_linrx_err_i ) = 0.0
605  err_bnds_comp( j, la_linrx_err_i ) = 0.0
606  END IF
607  IF ( n_err_bnds .GE. 3 ) THEN
608  err_bnds_norm( j, la_linrx_rcond_i ) = 1.0
609  err_bnds_comp( j, la_linrx_rcond_i ) = 1.0
610  END IF
611  END DO
612  RETURN
613  END IF
614 *
615 * Default to failure.
616 *
617  rcond = 0.0
618  DO j = 1, nrhs
619  berr( j ) = 1.0
620  IF ( n_err_bnds .GE. 1 ) THEN
621  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
622  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
623  END IF
624  IF ( n_err_bnds .GE. 2 ) THEN
625  err_bnds_norm( j, la_linrx_err_i ) = 1.0
626  err_bnds_comp( j, la_linrx_err_i ) = 1.0
627  END IF
628  IF ( n_err_bnds .GE. 3 ) THEN
629  err_bnds_norm( j, la_linrx_rcond_i ) = 0.0
630  err_bnds_comp( j, la_linrx_rcond_i ) = 0.0
631  END IF
632  END DO
633 *
634 * Compute the norm of A and the reciprocal of the condition
635 * number of A.
636 *
637  IF( notran ) THEN
638  norm = 'I'
639  ELSE
640  norm = '1'
641  END IF
642  anorm = slangb( norm, n, kl, ku, ab, ldab, work )
643  CALL sgbcon( norm, n, kl, ku, afb, ldafb, ipiv, anorm, rcond,
644  $ work, iwork, info )
645 *
646 * Perform refinement on each right-hand side
647 *
648  IF ( ref_type .NE. 0 .AND. info .EQ. 0 ) THEN
649 
650  prec_type = ilaprec( 'D' )
651 
652  IF ( notran ) THEN
653  CALL sla_gbrfsx_extended( prec_type, trans_type, n, kl, ku,
654  $ nrhs, ab, ldab, afb, ldafb, ipiv, colequ, c, b,
655  $ ldb, x, ldx, berr, n_norms, err_bnds_norm,
656  $ err_bnds_comp, work( n+1 ), work( 1 ), work( 2*n+1 ),
657  $ work( 1 ), rcond, ithresh, rthresh, unstable_thresh,
658  $ ignore_cwise, info )
659  ELSE
660  CALL sla_gbrfsx_extended( prec_type, trans_type, n, kl, ku,
661  $ nrhs, ab, ldab, afb, ldafb, ipiv, rowequ, r, b,
662  $ ldb, x, ldx, berr, n_norms, err_bnds_norm,
663  $ err_bnds_comp, work( n+1 ), work( 1 ), work( 2*n+1 ),
664  $ work( 1 ), rcond, ithresh, rthresh, unstable_thresh,
665  $ ignore_cwise, info )
666  END IF
667  END IF
668 
669  err_lbnd = max( 10.0, sqrt( REAL( N ) ) ) * slamch( 'Epsilon' )
670  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 1 ) THEN
671 *
672 * Compute scaled normwise condition number cond(A*C).
673 *
674  IF ( colequ .AND. notran ) THEN
675  rcond_tmp = sla_gbrcond( trans, n, kl, ku, ab, ldab, afb,
676  $ ldafb, ipiv, -1, c, info, work, iwork )
677  ELSE IF ( rowequ .AND. .NOT. notran ) THEN
678  rcond_tmp = sla_gbrcond( trans, n, kl, ku, ab, ldab, afb,
679  $ ldafb, ipiv, -1, r, info, work, iwork )
680  ELSE
681  rcond_tmp = sla_gbrcond( trans, n, kl, ku, ab, ldab, afb,
682  $ ldafb, ipiv, 0, r, info, work, iwork )
683  END IF
684  DO j = 1, nrhs
685 *
686 * Cap the error at 1.0.
687 *
688  IF ( n_err_bnds .GE. la_linrx_err_i
689  $ .AND. err_bnds_norm( j, la_linrx_err_i ) .GT. 1.0 )
690  $ err_bnds_norm( j, la_linrx_err_i ) = 1.0
691 *
692 * Threshold the error (see LAWN).
693 *
694  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
695  err_bnds_norm( j, la_linrx_err_i ) = 1.0
696  err_bnds_norm( j, la_linrx_trust_i ) = 0.0
697  IF ( info .LE. n ) info = n + j
698  ELSE IF ( err_bnds_norm( j, la_linrx_err_i ) .LT. err_lbnd )
699  $ THEN
700  err_bnds_norm( j, la_linrx_err_i ) = err_lbnd
701  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
702  END IF
703 *
704 * Save the condition number.
705 *
706  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
707  err_bnds_norm( j, la_linrx_rcond_i ) = rcond_tmp
708  END IF
709 
710  END DO
711  END IF
712 
713  IF (n_err_bnds .GE. 1 .AND. n_norms .GE. 2) THEN
714 *
715 * Compute componentwise condition number cond(A*diag(Y(:,J))) for
716 * each right-hand side using the current solution as an estimate of
717 * the true solution. If the componentwise error estimate is too
718 * large, then the solution is a lousy estimate of truth and the
719 * estimated RCOND may be too optimistic. To avoid misleading users,
720 * the inverse condition number is set to 0.0 when the estimated
721 * cwise error is at least CWISE_WRONG.
722 *
723  cwise_wrong = sqrt( slamch( 'Epsilon' ) )
724  DO j = 1, nrhs
725  IF ( err_bnds_comp( j, la_linrx_err_i ) .LT. cwise_wrong )
726  $ THEN
727  rcond_tmp = sla_gbrcond( trans, n, kl, ku, ab, ldab, afb,
728  $ ldafb, ipiv, 1, x( 1, j ), info, work, iwork )
729  ELSE
730  rcond_tmp = 0.0
731  END IF
732 *
733 * Cap the error at 1.0.
734 *
735  IF ( n_err_bnds .GE. la_linrx_err_i
736  $ .AND. err_bnds_comp( j, la_linrx_err_i ) .GT. 1.0 )
737  $ err_bnds_comp( j, la_linrx_err_i ) = 1.0
738 *
739 * Threshold the error (see LAWN).
740 *
741  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
742  err_bnds_comp( j, la_linrx_err_i ) = 1.0
743  err_bnds_comp( j, la_linrx_trust_i ) = 0.0
744  IF ( params( la_linrx_cwise_i ) .EQ. 1.0
745  $ .AND. info.LT.n + j ) info = n + j
746  ELSE IF ( err_bnds_comp( j, la_linrx_err_i )
747  $ .LT. err_lbnd ) THEN
748  err_bnds_comp( j, la_linrx_err_i ) = err_lbnd
749  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
750  END IF
751 *
752 * Save the condition number.
753 *
754  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
755  err_bnds_comp( j, la_linrx_rcond_i ) = rcond_tmp
756  END IF
757 
758  END DO
759  END IF
760 *
761  RETURN
762 *
763 * End of SGBRFSX
764 *
real function sla_gbrcond(TRANS, N, KL, KU, AB, LDAB, AFB, LDAFB, IPIV, CMODE, C, INFO, WORK, IWORK)
SLA_GBRCOND estimates the Skeel condition number for a general banded matrix.
Definition: sla_gbrcond.f:170
subroutine sgbcon(NORM, N, KL, KU, AB, LDAB, IPIV, ANORM, RCOND, WORK, IWORK, INFO)
SGBCON
Definition: sgbcon.f:148
integer function ilatrans(TRANS)
ILATRANS
Definition: ilatrans.f:60
integer function ilaprec(PREC)
ILAPREC
Definition: ilaprec.f:60
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
real function slangb(NORM, N, KL, KU, AB, LDAB, WORK)
SLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: slangb.f:126
subroutine sla_gbrfsx_extended(PREC_TYPE, TRANS_TYPE, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB, IPIV, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
SLA_GBRFSX_EXTENDED improves the computed solution to a system of linear equations for general banded...
Here is the call graph for this function:
Here is the caller graph for this function: