LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ dqlt02()

subroutine dqlt02 ( integer  M,
integer  N,
integer  K,
double precision, dimension( lda, * )  A,
double precision, dimension( lda, * )  AF,
double precision, dimension( lda, * )  Q,
double precision, dimension( lda, * )  L,
integer  LDA,
double precision, dimension( * )  TAU,
double precision, dimension( lwork )  WORK,
integer  LWORK,
double precision, dimension( * )  RWORK,
double precision, dimension( * )  RESULT 
)

DQLT02

Purpose:
 DQLT02 tests DORGQL, which generates an m-by-n matrix Q with
 orthonornmal columns that is defined as the product of k elementary
 reflectors.

 Given the QL factorization of an m-by-n matrix A, DQLT02 generates
 the orthogonal matrix Q defined by the factorization of the last k
 columns of A; it compares L(m-n+1:m,n-k+1:n) with
 Q(1:m,m-n+1:m)'*A(1:m,n-k+1:n), and checks that the columns of Q are
 orthonormal.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix Q to be generated.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix Q to be generated.
          M >= N >= 0.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines the
          matrix Q. N >= K >= 0.
[in]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          The m-by-n matrix A which was factorized by DQLT01.
[in]AF
          AF is DOUBLE PRECISION array, dimension (LDA,N)
          Details of the QL factorization of A, as returned by DGEQLF.
          See DGEQLF for further details.
[out]Q
          Q is DOUBLE PRECISION array, dimension (LDA,N)
[out]L
          L is DOUBLE PRECISION array, dimension (LDA,N)
[in]LDA
          LDA is INTEGER
          The leading dimension of the arrays A, AF, Q and L. LDA >= M.
[in]TAU
          TAU is DOUBLE PRECISION array, dimension (N)
          The scalar factors of the elementary reflectors corresponding
          to the QL factorization in AF.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.
[out]RWORK
          RWORK is DOUBLE PRECISION array, dimension (M)
[out]RESULT
          RESULT is DOUBLE PRECISION array, dimension (2)
          The test ratios:
          RESULT(1) = norm( L - Q'*A ) / ( M * norm(A) * EPS )
          RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 138 of file dqlt02.f.

138 *
139 * -- LAPACK test routine (version 3.7.0) --
140 * -- LAPACK is a software package provided by Univ. of Tennessee, --
141 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
142 * December 2016
143 *
144 * .. Scalar Arguments ..
145  INTEGER k, lda, lwork, m, n
146 * ..
147 * .. Array Arguments ..
148  DOUBLE PRECISION a( lda, * ), af( lda, * ), l( lda, * ),
149  $ q( lda, * ), result( * ), rwork( * ), tau( * ),
150  $ work( lwork )
151 * ..
152 *
153 * =====================================================================
154 *
155 * .. Parameters ..
156  DOUBLE PRECISION zero, one
157  parameter( zero = 0.0d+0, one = 1.0d+0 )
158  DOUBLE PRECISION rogue
159  parameter( rogue = -1.0d+10 )
160 * ..
161 * .. Local Scalars ..
162  INTEGER info
163  DOUBLE PRECISION anorm, eps, resid
164 * ..
165 * .. External Functions ..
166  DOUBLE PRECISION dlamch, dlange, dlansy
167  EXTERNAL dlamch, dlange, dlansy
168 * ..
169 * .. External Subroutines ..
170  EXTERNAL dgemm, dlacpy, dlaset, dorgql, dsyrk
171 * ..
172 * .. Intrinsic Functions ..
173  INTRINSIC dble, max
174 * ..
175 * .. Scalars in Common ..
176  CHARACTER*32 srnamt
177 * ..
178 * .. Common blocks ..
179  COMMON / srnamc / srnamt
180 * ..
181 * .. Executable Statements ..
182 *
183 * Quick return if possible
184 *
185  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
186  result( 1 ) = zero
187  result( 2 ) = zero
188  RETURN
189  END IF
190 *
191  eps = dlamch( 'Epsilon' )
192 *
193 * Copy the last k columns of the factorization to the array Q
194 *
195  CALL dlaset( 'Full', m, n, rogue, rogue, q, lda )
196  IF( k.LT.m )
197  $ CALL dlacpy( 'Full', m-k, k, af( 1, n-k+1 ), lda,
198  $ q( 1, n-k+1 ), lda )
199  IF( k.GT.1 )
200  $ CALL dlacpy( 'Upper', k-1, k-1, af( m-k+1, n-k+2 ), lda,
201  $ q( m-k+1, n-k+2 ), lda )
202 *
203 * Generate the last n columns of the matrix Q
204 *
205  srnamt = 'DORGQL'
206  CALL dorgql( m, n, k, q, lda, tau( n-k+1 ), work, lwork, info )
207 *
208 * Copy L(m-n+1:m,n-k+1:n)
209 *
210  CALL dlaset( 'Full', n, k, zero, zero, l( m-n+1, n-k+1 ), lda )
211  CALL dlacpy( 'Lower', k, k, af( m-k+1, n-k+1 ), lda,
212  $ l( m-k+1, n-k+1 ), lda )
213 *
214 * Compute L(m-n+1:m,n-k+1:n) - Q(1:m,m-n+1:m)' * A(1:m,n-k+1:n)
215 *
216  CALL dgemm( 'Transpose', 'No transpose', n, k, m, -one, q, lda,
217  $ a( 1, n-k+1 ), lda, one, l( m-n+1, n-k+1 ), lda )
218 *
219 * Compute norm( L - Q'*A ) / ( M * norm(A) * EPS ) .
220 *
221  anorm = dlange( '1', m, k, a( 1, n-k+1 ), lda, rwork )
222  resid = dlange( '1', n, k, l( m-n+1, n-k+1 ), lda, rwork )
223  IF( anorm.GT.zero ) THEN
224  result( 1 ) = ( ( resid / dble( max( 1, m ) ) ) / anorm ) / eps
225  ELSE
226  result( 1 ) = zero
227  END IF
228 *
229 * Compute I - Q'*Q
230 *
231  CALL dlaset( 'Full', n, n, zero, one, l, lda )
232  CALL dsyrk( 'Upper', 'Transpose', n, m, -one, q, lda, one, l,
233  $ lda )
234 *
235 * Compute norm( I - Q'*Q ) / ( M * EPS ) .
236 *
237  resid = dlansy( '1', 'Upper', n, l, lda, rwork )
238 *
239  result( 2 ) = ( resid / dble( max( 1, m ) ) ) / eps
240 *
241  RETURN
242 *
243 * End of DQLT02
244 *
subroutine dlacpy(UPLO, M, N, A, LDA, B, LDB)
DLACPY copies all or part of one two-dimensional array to another.
Definition: dlacpy.f:105
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
double precision function dlansy(NORM, UPLO, N, A, LDA, WORK)
DLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric matrix.
Definition: dlansy.f:124
subroutine dorgql(M, N, K, A, LDA, TAU, WORK, LWORK, INFO)
DORGQL
Definition: dorgql.f:130
subroutine dlaset(UPLO, M, N, ALPHA, BETA, A, LDA)
DLASET initializes the off-diagonal elements and the diagonal elements of a matrix to given values...
Definition: dlaset.f:112
subroutine dgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
DGEMM
Definition: dgemm.f:189
subroutine dsyrk(UPLO, TRANS, N, K, ALPHA, A, LDA, BETA, C, LDC)
DSYRK
Definition: dsyrk.f:171
double precision function dlange(NORM, M, N, A, LDA, WORK)
DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: dlange.f:116
Here is the call graph for this function:
Here is the caller graph for this function: