LAPACK  3.8.0
LAPACK: Linear Algebra PACKage
dsbev_2stage.f
Go to the documentation of this file.
1 *> \brief <b> DSBEV_2STAGE computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
2 *
3 * @precisions fortran d -> s
4 *
5 * =========== DOCUMENTATION ===========
6 *
7 * Online html documentation available at
8 * http://www.netlib.org/lapack/explore-html/
9 *
10 *> \htmlonly
11 *> Download DSBEV_2STAGE + dependencies
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsbev_2stage.f">
13 *> [TGZ]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsbev_2stage.f">
15 *> [ZIP]</a>
16 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsbev_2stage.f">
17 *> [TXT]</a>
18 *> \endhtmlonly
19 *
20 * Definition:
21 * ===========
22 *
23 * SUBROUTINE DSBEV_2STAGE( JOBZ, UPLO, N, KD, AB, LDAB, W, Z, LDZ,
24 * WORK, LWORK, INFO )
25 *
26 * IMPLICIT NONE
27 *
28 * .. Scalar Arguments ..
29 * CHARACTER JOBZ, UPLO
30 * INTEGER INFO, KD, LDAB, LDZ, N, LWORK
31 * ..
32 * .. Array Arguments ..
33 * DOUBLE PRECISION AB( LDAB, * ), W( * ), WORK( * ), Z( LDZ, * )
34 * ..
35 *
36 *
37 *> \par Purpose:
38 * =============
39 *>
40 *> \verbatim
41 *>
42 *> DSBEV_2STAGE computes all the eigenvalues and, optionally, eigenvectors of
43 *> a real symmetric band matrix A using the 2stage technique for
44 *> the reduction to tridiagonal.
45 *> \endverbatim
46 *
47 * Arguments:
48 * ==========
49 *
50 *> \param[in] JOBZ
51 *> \verbatim
52 *> JOBZ is CHARACTER*1
53 *> = 'N': Compute eigenvalues only;
54 *> = 'V': Compute eigenvalues and eigenvectors.
55 *> Not available in this release.
56 *> \endverbatim
57 *>
58 *> \param[in] UPLO
59 *> \verbatim
60 *> UPLO is CHARACTER*1
61 *> = 'U': Upper triangle of A is stored;
62 *> = 'L': Lower triangle of A is stored.
63 *> \endverbatim
64 *>
65 *> \param[in] N
66 *> \verbatim
67 *> N is INTEGER
68 *> The order of the matrix A. N >= 0.
69 *> \endverbatim
70 *>
71 *> \param[in] KD
72 *> \verbatim
73 *> KD is INTEGER
74 *> The number of superdiagonals of the matrix A if UPLO = 'U',
75 *> or the number of subdiagonals if UPLO = 'L'. KD >= 0.
76 *> \endverbatim
77 *>
78 *> \param[in,out] AB
79 *> \verbatim
80 *> AB is DOUBLE PRECISION array, dimension (LDAB, N)
81 *> On entry, the upper or lower triangle of the symmetric band
82 *> matrix A, stored in the first KD+1 rows of the array. The
83 *> j-th column of A is stored in the j-th column of the array AB
84 *> as follows:
85 *> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
86 *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
87 *>
88 *> On exit, AB is overwritten by values generated during the
89 *> reduction to tridiagonal form. If UPLO = 'U', the first
90 *> superdiagonal and the diagonal of the tridiagonal matrix T
91 *> are returned in rows KD and KD+1 of AB, and if UPLO = 'L',
92 *> the diagonal and first subdiagonal of T are returned in the
93 *> first two rows of AB.
94 *> \endverbatim
95 *>
96 *> \param[in] LDAB
97 *> \verbatim
98 *> LDAB is INTEGER
99 *> The leading dimension of the array AB. LDAB >= KD + 1.
100 *> \endverbatim
101 *>
102 *> \param[out] W
103 *> \verbatim
104 *> W is DOUBLE PRECISION array, dimension (N)
105 *> If INFO = 0, the eigenvalues in ascending order.
106 *> \endverbatim
107 *>
108 *> \param[out] Z
109 *> \verbatim
110 *> Z is DOUBLE PRECISION array, dimension (LDZ, N)
111 *> If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
112 *> eigenvectors of the matrix A, with the i-th column of Z
113 *> holding the eigenvector associated with W(i).
114 *> If JOBZ = 'N', then Z is not referenced.
115 *> \endverbatim
116 *>
117 *> \param[in] LDZ
118 *> \verbatim
119 *> LDZ is INTEGER
120 *> The leading dimension of the array Z. LDZ >= 1, and if
121 *> JOBZ = 'V', LDZ >= max(1,N).
122 *> \endverbatim
123 *>
124 *> \param[out] WORK
125 *> \verbatim
126 *> WORK is DOUBLE PRECISION array, dimension LWORK
127 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
128 *> \endverbatim
129 *>
130 *> \param[in] LWORK
131 *> \verbatim
132 *> LWORK is INTEGER
133 *> The length of the array WORK. LWORK >= 1, when N <= 1;
134 *> otherwise
135 *> If JOBZ = 'N' and N > 1, LWORK must be queried.
136 *> LWORK = MAX(1, dimension) where
137 *> dimension = (2KD+1)*N + KD*NTHREADS + N
138 *> where KD is the size of the band.
139 *> NTHREADS is the number of threads used when
140 *> openMP compilation is enabled, otherwise =1.
141 *> If JOBZ = 'V' and N > 1, LWORK must be queried. Not yet available.
142 *>
143 *> If LWORK = -1, then a workspace query is assumed; the routine
144 *> only calculates the optimal size of the WORK array, returns
145 *> this value as the first entry of the WORK array, and no error
146 *> message related to LWORK is issued by XERBLA.
147 *> \endverbatim
148 *>
149 *> \param[out] INFO
150 *> \verbatim
151 *> INFO is INTEGER
152 *> = 0: successful exit
153 *> < 0: if INFO = -i, the i-th argument had an illegal value
154 *> > 0: if INFO = i, the algorithm failed to converge; i
155 *> off-diagonal elements of an intermediate tridiagonal
156 *> form did not converge to zero.
157 *> \endverbatim
158 *
159 * Authors:
160 * ========
161 *
162 *> \author Univ. of Tennessee
163 *> \author Univ. of California Berkeley
164 *> \author Univ. of Colorado Denver
165 *> \author NAG Ltd.
166 *
167 *> \date November 2017
168 *
169 *> \ingroup doubleOTHEReigen
170 *
171 *> \par Further Details:
172 * =====================
173 *>
174 *> \verbatim
175 *>
176 *> All details about the 2stage techniques are available in:
177 *>
178 *> Azzam Haidar, Hatem Ltaief, and Jack Dongarra.
179 *> Parallel reduction to condensed forms for symmetric eigenvalue problems
180 *> using aggregated fine-grained and memory-aware kernels. In Proceedings
181 *> of 2011 International Conference for High Performance Computing,
182 *> Networking, Storage and Analysis (SC '11), New York, NY, USA,
183 *> Article 8 , 11 pages.
184 *> http://doi.acm.org/10.1145/2063384.2063394
185 *>
186 *> A. Haidar, J. Kurzak, P. Luszczek, 2013.
187 *> An improved parallel singular value algorithm and its implementation
188 *> for multicore hardware, In Proceedings of 2013 International Conference
189 *> for High Performance Computing, Networking, Storage and Analysis (SC '13).
190 *> Denver, Colorado, USA, 2013.
191 *> Article 90, 12 pages.
192 *> http://doi.acm.org/10.1145/2503210.2503292
193 *>
194 *> A. Haidar, R. Solca, S. Tomov, T. Schulthess and J. Dongarra.
195 *> A novel hybrid CPU-GPU generalized eigensolver for electronic structure
196 *> calculations based on fine-grained memory aware tasks.
197 *> International Journal of High Performance Computing Applications.
198 *> Volume 28 Issue 2, Pages 196-209, May 2014.
199 *> http://hpc.sagepub.com/content/28/2/196
200 *>
201 *> \endverbatim
202 *
203 * =====================================================================
204  SUBROUTINE dsbev_2stage( JOBZ, UPLO, N, KD, AB, LDAB, W, Z, LDZ,
205  $ WORK, LWORK, INFO )
206 *
207  IMPLICIT NONE
208 *
209 * -- LAPACK driver routine (version 3.8.0) --
210 * -- LAPACK is a software package provided by Univ. of Tennessee, --
211 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
212 * November 2017
213 *
214 * .. Scalar Arguments ..
215  CHARACTER JOBZ, UPLO
216  INTEGER INFO, KD, LDAB, LDZ, N, LWORK
217 * ..
218 * .. Array Arguments ..
219  DOUBLE PRECISION AB( ldab, * ), W( * ), WORK( * ), Z( ldz, * )
220 * ..
221 *
222 * =====================================================================
223 *
224 * .. Parameters ..
225  DOUBLE PRECISION ZERO, ONE
226  parameter( zero = 0.0d0, one = 1.0d0 )
227 * ..
228 * .. Local Scalars ..
229  LOGICAL LOWER, WANTZ, LQUERY
230  INTEGER IINFO, IMAX, INDE, INDWRK, ISCALE,
231  $ llwork, lwmin, lhtrd, lwtrd, ib, indhous
232  DOUBLE PRECISION ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
233  $ smlnum
234 * ..
235 * .. External Functions ..
236  LOGICAL LSAME
237  INTEGER ILAENV2STAGE
238  DOUBLE PRECISION DLAMCH, DLANSB
239  EXTERNAL lsame, dlamch, dlansb, ilaenv2stage
240 * ..
241 * .. External Subroutines ..
242  EXTERNAL dlascl, dscal, dsteqr, dsterf, xerbla,
243  $ dsytrd_sb2st
244 * ..
245 * .. Intrinsic Functions ..
246  INTRINSIC sqrt
247 * ..
248 * .. Executable Statements ..
249 *
250 * Test the input parameters.
251 *
252  wantz = lsame( jobz, 'V' )
253  lower = lsame( uplo, 'L' )
254  lquery = ( lwork.EQ.-1 )
255 *
256  info = 0
257  IF( .NOT.( lsame( jobz, 'N' ) ) ) THEN
258  info = -1
259  ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
260  info = -2
261  ELSE IF( n.LT.0 ) THEN
262  info = -3
263  ELSE IF( kd.LT.0 ) THEN
264  info = -4
265  ELSE IF( ldab.LT.kd+1 ) THEN
266  info = -6
267  ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
268  info = -9
269  END IF
270 *
271  IF( info.EQ.0 ) THEN
272  IF( n.LE.1 ) THEN
273  lwmin = 1
274  work( 1 ) = lwmin
275  ELSE
276  ib = ilaenv2stage( 2, 'DSYTRD_SB2ST', jobz,
277  $ n, kd, -1, -1 )
278  lhtrd = ilaenv2stage( 3, 'DSYTRD_SB2ST', jobz,
279  $ n, kd, ib, -1 )
280  lwtrd = ilaenv2stage( 4, 'DSYTRD_SB2ST', jobz,
281  $ n, kd, ib, -1 )
282  lwmin = n + lhtrd + lwtrd
283  work( 1 ) = lwmin
284  ENDIF
285 *
286  IF( lwork.LT.lwmin .AND. .NOT.lquery )
287  $ info = -11
288  END IF
289 *
290  IF( info.NE.0 ) THEN
291  CALL xerbla( 'DSBEV_2STAGE ', -info )
292  RETURN
293  ELSE IF( lquery ) THEN
294  RETURN
295  END IF
296 *
297 * Quick return if possible
298 *
299  IF( n.EQ.0 )
300  $ RETURN
301 *
302  IF( n.EQ.1 ) THEN
303  IF( lower ) THEN
304  w( 1 ) = ab( 1, 1 )
305  ELSE
306  w( 1 ) = ab( kd+1, 1 )
307  END IF
308  IF( wantz )
309  $ z( 1, 1 ) = one
310  RETURN
311  END IF
312 *
313 * Get machine constants.
314 *
315  safmin = dlamch( 'Safe minimum' )
316  eps = dlamch( 'Precision' )
317  smlnum = safmin / eps
318  bignum = one / smlnum
319  rmin = sqrt( smlnum )
320  rmax = sqrt( bignum )
321 *
322 * Scale matrix to allowable range, if necessary.
323 *
324  anrm = dlansb( 'M', uplo, n, kd, ab, ldab, work )
325  iscale = 0
326  IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
327  iscale = 1
328  sigma = rmin / anrm
329  ELSE IF( anrm.GT.rmax ) THEN
330  iscale = 1
331  sigma = rmax / anrm
332  END IF
333  IF( iscale.EQ.1 ) THEN
334  IF( lower ) THEN
335  CALL dlascl( 'B', kd, kd, one, sigma, n, n, ab, ldab, info )
336  ELSE
337  CALL dlascl( 'Q', kd, kd, one, sigma, n, n, ab, ldab, info )
338  END IF
339  END IF
340 *
341 * Call DSYTRD_SB2ST to reduce symmetric band matrix to tridiagonal form.
342 *
343  inde = 1
344  indhous = inde + n
345  indwrk = indhous + lhtrd
346  llwork = lwork - indwrk + 1
347 *
348  CALL dsytrd_sb2st( "N", jobz, uplo, n, kd, ab, ldab, w,
349  $ work( inde ), work( indhous ), lhtrd,
350  $ work( indwrk ), llwork, iinfo )
351 *
352 * For eigenvalues only, call DSTERF. For eigenvectors, call SSTEQR.
353 *
354  IF( .NOT.wantz ) THEN
355  CALL dsterf( n, w, work( inde ), info )
356  ELSE
357  CALL dsteqr( jobz, n, w, work( inde ), z, ldz, work( indwrk ),
358  $ info )
359  END IF
360 *
361 * If matrix was scaled, then rescale eigenvalues appropriately.
362 *
363  IF( iscale.EQ.1 ) THEN
364  IF( info.EQ.0 ) THEN
365  imax = n
366  ELSE
367  imax = info - 1
368  END IF
369  CALL dscal( imax, one / sigma, w, 1 )
370  END IF
371 *
372 * Set WORK(1) to optimal workspace size.
373 *
374  work( 1 ) = lwmin
375 *
376  RETURN
377 *
378 * End of DSBEV_2STAGE
379 *
380  END
subroutine dsterf(N, D, E, INFO)
DSTERF
Definition: dsterf.f:88
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:81
subroutine dsbev_2stage(JOBZ, UPLO, N, KD, AB, LDAB, W, Z, LDZ, WORK, LWORK, INFO)
DSBEV_2STAGE computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER ...
Definition: dsbev_2stage.f:206
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dlascl(TYPE, KL, KU, CFROM, CTO, M, N, A, LDA, INFO)
DLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition: dlascl.f:145
subroutine dsteqr(COMPZ, N, D, E, Z, LDZ, WORK, INFO)
DSTEQR
Definition: dsteqr.f:133