slasdt()

subroutine slasdt	(	integer	n,
		integer	lvl,
		integer	nd,
		integer, dimension( * )	inode,
		integer, dimension( * )	ndiml,
		integer, dimension( * )	ndimr,
		integer	msub
	)

SLASDT creates a tree of subproblems for bidiagonal divide and conquer. Used by sbdsdc.

Download SLASDT + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SLASDT creates a tree of subproblems for bidiagonal divide and
 conquer.

Parameters

[in]	N	N is INTEGER On entry, the number of diagonal elements of the bidiagonal matrix.
[out]	LVL	LVL is INTEGER On exit, the number of levels on the computation tree.
[out]	ND	ND is INTEGER On exit, the number of nodes on the tree.
[out]	INODE	INODE is INTEGER array, dimension ( N ) On exit, centers of subproblems.
[out]	NDIML	NDIML is INTEGER array, dimension ( N ) On exit, row dimensions of left children.
[out]	NDIMR	NDIMR is INTEGER array, dimension ( N ) On exit, row dimensions of right children.
[in]	MSUB	MSUB is INTEGER On entry, the maximum row dimension each subproblem at the bottom of the tree can be of.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA

Definition at line 104 of file slasdt.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LVL, MSUB, N, ND
*     ..
*     .. Array Arguments ..
      INTEGER            INODE( * ), NDIML( * ), NDIMR( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               TWO
      parameter( two = 2.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IL, IR, LLST, MAXN, NCRNT, NLVL
      REAL               TEMP
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          int, log, max, real
*     ..
*     .. Executable Statements ..
*
*     Find the number of levels on the tree.
*
      maxn = max( 1, n )
      temp = log( real( maxn ) / real( msub+1 ) ) / log( two )
      lvl = int( temp ) + 1
*
      i = n / 2
      inode( 1 ) = i + 1
      ndiml( 1 ) = i
      ndimr( 1 ) = n - i - 1
      il = 0
      ir = 1
      llst = 1
      DO 20 nlvl = 1, lvl - 1
*
*        Constructing the tree at (NLVL+1)-st level. The number of
*        nodes created on this level is LLST * 2.
*
         DO 10 i = 0, llst - 1
            il = il + 2
            ir = ir + 2
            ncrnt = llst + i
            ndiml( il ) = ndiml( ncrnt ) / 2
            ndimr( il ) = ndiml( ncrnt ) - ndiml( il ) - 1
            inode( il ) = inode( ncrnt ) - ndimr( il ) - 1
            ndiml( ir ) = ndimr( ncrnt ) / 2
            ndimr( ir ) = ndimr( ncrnt ) - ndiml( ir ) - 1
            inode( ir ) = inode( ncrnt ) + ndiml( ir ) + 1
   10    CONTINUE
         llst = llst*2
   20 CONTINUE
      nd = llst*2 - 1
*
      RETURN
*
*     End of SLASDT
*

Here is the caller graph for this function: