LAPACK  3.8.0
LAPACK: Linear Algebra PACKage

◆ clangb()

real function clangb ( character  NORM,
integer  N,
integer  KL,
integer  KU,
complex, dimension( ldab, * )  AB,
integer  LDAB,
real, dimension( * )  WORK 
)

CLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.

Download CLANGB + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CLANGB  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the element of  largest absolute value  of an
 n by n band matrix  A,  with kl sub-diagonals and ku super-diagonals.
Returns
CLANGB
    CLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in CLANGB as described
          above.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, CLANGB is
          set to zero.
[in]KL
          KL is INTEGER
          The number of sub-diagonals of the matrix A.  KL >= 0.
[in]KU
          KU is INTEGER
          The number of super-diagonals of the matrix A.  KU >= 0.
[in]AB
          AB is COMPLEX array, dimension (LDAB,N)
          The band matrix A, stored in rows 1 to KL+KU+1.  The j-th
          column of A is stored in the j-th column of the array AB as
          follows:
          AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
[in]LDAB
          LDAB is INTEGER
          The leading dimension of the array AB.  LDAB >= KL+KU+1.
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 127 of file clangb.f.

127 *
128 * -- LAPACK auxiliary routine (version 3.7.0) --
129 * -- LAPACK is a software package provided by Univ. of Tennessee, --
130 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
131 * December 2016
132 *
133 * .. Scalar Arguments ..
134  CHARACTER norm
135  INTEGER kl, ku, ldab, n
136 * ..
137 * .. Array Arguments ..
138  REAL work( * )
139  COMPLEX ab( ldab, * )
140 * ..
141 *
142 * =====================================================================
143 *
144 * .. Parameters ..
145  REAL one, zero
146  parameter( one = 1.0e+0, zero = 0.0e+0 )
147 * ..
148 * .. Local Scalars ..
149  INTEGER i, j, k, l
150  REAL scale, sum, VALUE, temp
151 * ..
152 * .. External Functions ..
153  LOGICAL lsame, sisnan
154  EXTERNAL lsame, sisnan
155 * ..
156 * .. External Subroutines ..
157  EXTERNAL classq
158 * ..
159 * .. Intrinsic Functions ..
160  INTRINSIC abs, max, min, sqrt
161 * ..
162 * .. Executable Statements ..
163 *
164  IF( n.EQ.0 ) THEN
165  VALUE = zero
166  ELSE IF( lsame( norm, 'M' ) ) THEN
167 *
168 * Find max(abs(A(i,j))).
169 *
170  VALUE = zero
171  DO 20 j = 1, n
172  DO 10 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
173  temp = abs( ab( i, j ) )
174  IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
175  10 CONTINUE
176  20 CONTINUE
177  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
178 *
179 * Find norm1(A).
180 *
181  VALUE = zero
182  DO 40 j = 1, n
183  sum = zero
184  DO 30 i = max( ku+2-j, 1 ), min( n+ku+1-j, kl+ku+1 )
185  sum = sum + abs( ab( i, j ) )
186  30 CONTINUE
187  IF( VALUE.LT.sum .OR. sisnan( sum ) ) VALUE = sum
188  40 CONTINUE
189  ELSE IF( lsame( norm, 'I' ) ) THEN
190 *
191 * Find normI(A).
192 *
193  DO 50 i = 1, n
194  work( i ) = zero
195  50 CONTINUE
196  DO 70 j = 1, n
197  k = ku + 1 - j
198  DO 60 i = max( 1, j-ku ), min( n, j+kl )
199  work( i ) = work( i ) + abs( ab( k+i, j ) )
200  60 CONTINUE
201  70 CONTINUE
202  VALUE = zero
203  DO 80 i = 1, n
204  temp = work( i )
205  IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
206  80 CONTINUE
207  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
208 *
209 * Find normF(A).
210 *
211  scale = zero
212  sum = one
213  DO 90 j = 1, n
214  l = max( 1, j-ku )
215  k = ku + 1 - j + l
216  CALL classq( min( n, j+kl )-l+1, ab( k, j ), 1, scale, sum )
217  90 CONTINUE
218  VALUE = scale*sqrt( sum )
219  END IF
220 *
221  clangb = VALUE
222  RETURN
223 *
224 * End of CLANGB
225 *
real function clangb(NORM, N, KL, KU, AB, LDAB, WORK)
CLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: clangb.f:127
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:61
subroutine classq(N, X, INCX, SCALE, SUMSQ)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f:108
Here is the call graph for this function:
Here is the caller graph for this function: