csytrs_aa_2stage()

subroutine csytrs_aa_2stage	(	character	uplo,
		integer	n,
		integer	nrhs,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	tb,
		integer	ltb,
		integer, dimension( * )	ipiv,
		integer, dimension( * )	ipiv2,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		integer	info
	)

CSYTRS_AA_2STAGE

Download CSYTRS_AA_2STAGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CSYTRS_AA_2STAGE solves a system of linear equations A*X = B with a complex
 symmetric matrix A using the factorization A = U**T*T*U or
 A = L*T*L**T computed by CSYTRF_AA_2STAGE.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the details of the factorization are stored as an upper or lower triangular matrix. = 'U': Upper triangular, form is A = U**T*T*U; = 'L': Lower triangular, form is A = L*T*L**T.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) Details of factors computed by CSYTRF_AA_2STAGE.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	TB	TB is COMPLEX array, dimension (LTB) Details of factors computed by CSYTRF_AA_2STAGE.
[in]	LTB	LTB is INTEGER The size of the array TB. LTB >= 4*N.
[in]	IPIV	IPIV is INTEGER array, dimension (N) Details of the interchanges as computed by CSYTRF_AA_2STAGE.
[in]	IPIV2	IPIV2 is INTEGER array, dimension (N) Details of the interchanges as computed by CSYTRF_AA_2STAGE.
[in,out]	B	B is COMPLEX array, dimension (LDB,NRHS) On entry, the right hand side matrix B. On exit, the solution matrix X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 137 of file csytrs_aa_2stage.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            N, NRHS, LDA, LTB, LDB, INFO
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * ), IPIV2( * )
      COMPLEX            A( LDA, * ), TB( * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
      COMPLEX            ONE
      parameter( one  = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            LDTB, NB
      LOGICAL            UPPER
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgbtrs, claswp, ctrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ltb.LT.( 4*n ) ) THEN
         info = -7
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CSYTRS_AA_2STAGE', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
*     Read NB and compute LDTB
*
      nb = int( tb( 1 ) )
      ldtb = ltb/n
*
      IF( upper ) THEN
*
*        Solve A*X = B, where A = U**T*T*U.
*
         IF( n.GT.nb ) THEN
*
*           Pivot, P**T * B -> B
*
            CALL claswp( nrhs, b, ldb, nb+1, n, ipiv, 1 )
*
*           Compute (U**T \ B) -> B    [ (U**T \P**T * B) ]
*
            CALL ctrsm( 'L', 'U', 'T', 'U', n-nb, nrhs, one, a(1, nb+1),
     $                 lda, b(nb+1, 1), ldb)
*
         END IF
*
*        Compute T \ B -> B   [ T \ (U**T \P**T * B) ]
*
         CALL cgbtrs( 'N', n, nb, nb, nrhs, tb, ldtb, ipiv2, b, ldb,
     $               info)
         IF( n.GT.nb ) THEN
*
*           Compute (U \ B) -> B   [ U \ (T \ (U**T \P**T * B) ) ]
*
            CALL ctrsm( 'L', 'U', 'N', 'U', n-nb, nrhs, one, a(1, nb+1),
     $                  lda, b(nb+1, 1), ldb)
*
*           Pivot, P * B -> B  [ P * (U \ (T \ (U**T \P**T * B) )) ]
*
            CALL claswp( nrhs, b, ldb, nb+1, n, ipiv, -1 )
*
         END IF
*
      ELSE
*
*        Solve A*X = B, where A = L*T*L**T.
*
         IF( n.GT.nb ) THEN
*
*           Pivot, P**T * B -> B
*
            CALL claswp( nrhs, b, ldb, nb+1, n, ipiv, 1 )
*
*           Compute (L \ B) -> B    [ (L \P**T * B) ]
*
            CALL ctrsm( 'L', 'L', 'N', 'U', n-nb, nrhs, one, a(nb+1, 1),
     $                 lda, b(nb+1, 1), ldb)
*
         END IF
*
*        Compute T \ B -> B   [ T \ (L \P**T * B) ]
*
         CALL cgbtrs( 'N', n, nb, nb, nrhs, tb, ldtb, ipiv2, b, ldb,
     $               info)
         IF( n.GT.nb ) THEN
*
*           Compute (L**T \ B) -> B   [ L**T \ (T \ (L \P**T * B) ) ]
*
            CALL ctrsm( 'L', 'L', 'T', 'U', n-nb, nrhs, one, a(nb+1, 1),
     $                  lda, b(nb+1, 1), ldb)
*
*           Pivot, P * B -> B  [ P * (L**T \ (T \ (L \P**T * B) )) ]
*
            CALL claswp( nrhs, b, ldb, nb+1, n, ipiv, -1 )
*
         END IF
      END IF
*
      RETURN
*
*     End of CSYTRS_AA_2STAGE
*

Here is the call graph for this function:

Here is the caller graph for this function: